Opis

set_task(Float:time, const function[], id=0, parameter[]="", len=0, flags[]="", repeat=0)

• time - czas (w sekundach), po jakim zostanie wywołana funkcja function.
• function - publiczna funkcja, która zostanie wywołana po upływie określonego czasu.
• id - unikalny identyfikator zadania, przydzielany automatycznie, jeśli parametr wynosi 0.
• parameter - tablica z dodatkowymi argumentami przesłanymi do funkcji function.
• len - rozmiar tablicy z parametram dodatkowymi.
• flags - opcjonalne flagi zadania:
  • a - Powtarza zadanie określoną liczbę razy.
  • b - Powtarza zadanie w nieskończoność.
  • c - Wykonuje zadanie tuż po końcu mapy.
  • d - Wykonuje zadanie tuż przed końcem mapy.
• repeat - określa, ile razy ma zostać wykonany task w przypadku flagi "a".

public plugin_init(){
	set_task(10.0, "interp", .flags="b") // powtarzaj co 10 sekund wykonywanie funkcji interp
}

public interp(){
	client_cmd(0, "ex_interp 0.01") // ustawiaj wszystkim graczom interp na 0.01 co 10 sekund
}

public plugin_init(){
	set_task(60.0, "koniecMapy", .flags="d") // wykonaj funkcję koniecMapy minutę przed końcem mapy
}

public koniecMapy(){
	client_print(0, print_chat, "Pozostała tylko minuta do końca mapy!") // poinformuj o zbliżającym się końcu mapy
}

public plugin_init(){
	RegisterHam(Ham_Killed, "player", "HamKilledPost", 1); // rejestruje zabicie gracza
}

public HamKilledPost(victim){ // wykonuje się po zabiciu gracza o identyfikatorze victim
	new data[1]; // tworzymy tablicę do przesłania dodatkowego parametru
	data[0]=victim; // wpisujemy jedyny dodatkowy parametr, identyfikator zabitego gracza, do tablicy
	set_task(3.0, "ressurect", .parameter=data, .len=1); // wywołamy funkcję ressurect po 3 sekundach
}

public ressurect(data[]){
	new victim=data[0]; // pobieramy identyfikator zabitego gracza z tablicy parameter
	if(is_user_connected(victim) && !is_user_alive(victim)){ // sprawdzamy, czy gracz dalej jest na serwerze i czy dalej nie żyje
		ExecuteHamB(Ham_CS_RoundRespawn, victim); // respawnujemy gracza po 3 sekundach od jego śmierci
	}
}

Składnia

set_task()

Typ