Opis

Pobiera określony cvar klienta (ex_interp, rate, name itd.)

Składnia

query_client_cvar(id, const cvar[], const resultFunc[], paramlen=0, const params[])

Typ

Notatki

id - index gracza
cvar - nazwa cvaru
resultFunc - funkcja która zostanie uruchomiona (musi to być nazwa funkcji publicznej)
paramlen - rozmiar tablicy z parametrami dodatkowymi
params - tablica z dodatkowymi argumentami przesłanymi do funkcji resultFunc

Funkcja publiczna będzie zawierała owe argumenty:

id - index gracza

cvar - nazwa cvaru

value - pobrana wartość cvar'u z gracza

param - przesłane dodatkowe argumenty // opcjonalnie

Przykład

#include < amxmodx >

public plugin_init()
	register_plugin("Przyklad", "1.0", "query_client_cvar")

public client_putinserver(id)
{
	set_task(7.0,"SprawdzajGo",id) // gracz weszedł na serwer i musimy mu sprawdzić interp
	set_task(60.0,"SprawdzajGo",id, .flags="b") // a potem co minute będziemy mu sprawdzać interp
}
	
public SprawdzajGo(id)
	if(!is_user_bot(id)) // jesli gracz jest botem to dalsza czynność się nie wykona
		query_client_cvar(id,"ex_interp","interp") // sprawdzamy jaki gracz ma interp

public interp(id,const cvar[],const value[])
{
	if(!strcmp(value, "0.01", 1)) // sprawdzamy czy interp gracza to 0.01
	{
		client_print(id, print_chat, "Masz prawidlowy Interp! Milej Zabawy!") // informujemy na czacie o prawidłowym interpie
	}
	else
	{
		client_print(id, print_chat, "Twoj Interp jest nieprawidlowy! Wroc innym razem!") // a tu o nieprawidłowym
		kickuj(id) // i wykonamy dalszą czynność na graczu o złym interpie
	}
}

public kickuj(id)
{
	server_cmd("amx_kick #%d ^"Zmien ex_interp (czytaj w konsoli)^"",get_user_userid(id)) // wyrzucamy gracza z serwera (kick)
	
//drukujemy wiadomosc graczowi w konsoli
	console_print(id,"---------------------------------------")
	console_print(id,"[Interp] Interp dozwolony na tym serwerze to 0.01")
	console_print(id,"[Interp] Aby zmienic swoj interp na dozwolony na tym serwerze wpisz w consoli gry:")
	console_print(id,"[Interp] ex_interp ^"wartosc^"");
	console_print(id,"---------------------------------------")
//
}

public client_disconnect(id)
	if(task_exists(id))
		remove_task(id) // gdy gracz wyjdzie z serwera usuwamy z niego taska sprawdzającego interpu
				// aby nie było nie przyjemnych errorów