elipson

Wstęp↵
Stare menu↵ - przykład↵
Nowe menu↵ - przykłady↵
- Funkcja kontrolna↵ - przykład↵
Przykłady menu na flagę↵
- W starym menu↵
- W nowym menu↵

Wstęp wróć↵
Flagi gracza: wróć↵
W pliku "amxconst.inc"

Spoiler

#define ADMIN_ALL		0	/* everyone */
#define ADMIN_IMMUNITY		(1<<0)	/* flag "a" */
#define ADMIN_RESERVATION	(1<<1)	/* flag "b" */
#define ADMIN_KICK			(1<<2)	/* flag "c" */
#define ADMIN_BAN			(1<<3)	/* flag "d" */
#define ADMIN_SLAY			(1<<4)	/* flag "e" */
#define ADMIN_MAP			(1<<5)	/* flag "f" */
#define ADMIN_CVAR			(1<<6)	/* flag "g" */
#define ADMIN_CFG			(1<<7)	/* flag "h" */
#define ADMIN_CHAT			(1<<8)	/* flag "i" */
#define ADMIN_VOTE			(1<<9)	/* flag "j" */
#define ADMIN_PASSWORD		(1<<10)	/* flag "k" */
#define ADMIN_RCON			(1<<11)	/* flag "l" */
#define ADMIN_LEVEL_A		(1<<12)	/* flag "m" */
#define ADMIN_LEVEL_B		(1<<13)	/* flag "n" */
#define ADMIN_LEVEL_C		(1<<14)	/* flag "o" */
#define ADMIN_LEVEL_D		(1<<15)	/* flag "p" */
#define ADMIN_LEVEL_E		(1<<16)	/* flag "q" */
#define ADMIN_LEVEL_F		(1<<17)	/* flag "r" */
#define ADMIN_LEVEL_G		(1<<18)	/* flag "s" */
#define ADMIN_LEVEL_H		(1<<19)	/* flag "t" */
#define ADMIN_MENU			(1<<20)	/* flag "u" */
#define ADMIN_ADMIN			(1<<24)	/* flag "y" */
#define ADMIN_USER			(1<<25)	/* flag "z" */

Dodatkowo przydatny będzie ten temat -> http://amxx.pl/topic/60353-flagi/

Wywołanie funkcji komendą: wróć↵
Potrzebne/użyte funkcje:

register_clcmd
```
register_clcmd(const client_cmd[], const function[], flags = -1, info[] = "");
```
client_cmd[] - komenda która musi zostać wpisana w konsoli gracza
function[] - nazwa funkcji która zostanie uruchomiona (musi to być funkcja publiczna)
flags - flagi dostępu
info - opis funkcji
lub register_concmd
```
register_concmd(const cmd[], const function[], flags = -1, info[] = "");
```
cmd[] - komenda która musi zostać wpisana w konsoli gracza lub w konsoli serwera
function[] - nazwa funkcji która zostanie uruchomiona (musi to być funkcja publiczna)
flags - flagi dostępu
info - opis funkcji
client_print - do wyświetlenia tekstu u gracza
```
client_print(index, type, const message[], any:...);
```
index - id gracza
type - typ wiadomości

print_chat - wiadomość na czacie
print_center - na środku ekranu
print_console - w konsoli
print_notify - w konsoli w trybie developerskim

message[] - wiadomość
any:... - ciągi formatujące
cmd_access - do sprawdzania praw dostępu do funkcji, która jest wywoływana komendą
```
cmd_access(id, level, cid, num, bool:accesssilent = false);
```
id - indeks gracza wywołującego komendę
level - poziom dostępu
cid - identyfikator komendy
num - ilość parametrów razem z komendą (gdy brak parametrów podajemy 1)
accesssilent - opcjonalny, jeśli podasz true, to komunikaty z błędami nie będą pokazywane

Przykład:

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Komendy"
#define VERSION "0.1"
#define AUTHOR "Sebul"

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("funkcja", "pokazfunkcje"); // funckja pokaże się po wpisaniu "funkcja" w konsoli gracza
	register_clcmd("say /funkcja", "pokazfunkcje"); // funckja pokaże się po wpisaniu "/funckja" na ogólnym czacie (podczas gry) przez gracza lub po wpisaniu "say /funckja" w konsoli gracza
	register_concmd("funkcja2", "pokazfunkcje"); // funckja pokaże się po wpisaniu "funckja2" w konsoli gracza lub w konsoli serwera
	register_clcmd("funkcja3", "pokazfunkcje", ADMIN_IMMUNITY); // funkcja pokaże się po wpisaniu "funkcja3" w konsoli gracza, który ma immunitet (flagę a)
	register_concmd("funkcja4", "pokazfunkcje", ADMIN_KICK, "cos tam"); // funkcja pokaże się po wpisaniu "funkcja4" w konsoli gracza, który ma flagę c lub gdy komenda "funkcja4" zostanie wpisana w konsoli serwera
}

public pokazfunkcje(id, level, cid) {
	if(!cmd_access(id, level, cid, 1))
		return PLUGIN_HANDLED;

	client_print(0, print_chat, "Gracz o id=%i wyswietlil funkcje ^"pokazfunkcje^"", id);

	return PLUGIN_HANDLED;
}

Formatowanie tekstu: wróć↵

^n - nowa linia
^t - odstęp, inaczej tabulator (różniący się od spacji)
\w - dalszy tekst będzie miał kolor biały
\y - dalszy tekst będzie miał kolor zółty
\r - dalszy tekst będzie miał kolor czerwony
\d - dalszy tekst będzie miał kolor szary
\R - dalszy tekst będzie wyrównany do prawej

Do formatowania tekstu (nie tylko w menu), można używać format

lub formatex

dla większej przejrzystości, a szczególnie gdy mamy dużo tekstu do formatowania.

Definicje klawiszy: wróć↵
W pliku "amxconst.inc"

Spoiler

/* Menu keys */
#define MENU_KEY_1		(1<<0)
#define MENU_KEY_2		(1<<1)
#define MENU_KEY_3		(1<<2)
#define MENU_KEY_4		(1<<3)
#define MENU_KEY_5		(1<<4)
#define MENU_KEY_6		(1<<5)
#define MENU_KEY_7		(1<<6)
#define MENU_KEY_8		(1<<7)
#define MENU_KEY_9		(1<<8)
#define MENU_KEY_0		(1<<9)

Użycie switcha: wróć↵
Warto używać, szczególnie gdy w menu (i nie tylko) mamy dużo opcji.
Przykład:

Spoiler

new costam = 1;
switch(costam) {
	case 0: {
		client_print(id, print_chat, "Wartosc zmiennej wynosi 0");
	}
	case 1: {
		client_print(id, print_chat, "Wartosc zmiennej wynosi 1"); // w tym przypadku wyświetli się nam ta wiadomość, gdyż zmienna "costam" ma przypisaną wartość 1
	}
	case 2: {
		client_print(id, print_chat, "Wartosc zmiennej wynosi 2");
	}
	default: {
		client_print(id, print_chat, "Wartosc zmiennej jest inna niz 0, 1 lub 2");
	}
}

Stare menu wróć↵
Do stworzenia starego menu, potrzebujemy:

register_menucmd
```
register_menucmd(menuid, keys, const function[]);
```
menuid - id naszego menu, które tworzy się za pomocą "register_menuid"
keys - jakie klawisze ma rozpoznawać nasze menu, liczba 1023 jest dla wszystkich (od 1 do 0)
function[] - nazwa funkcji w której pokazujemy menu
register_menuid
```
register_menuid(const menu[], outside = 0);
```
menu[] - nazwa menu
outside - zamieniamy na 1, gdy menu jest z innego źródła, np. inny plugin
show_menu
```
show_menu(index, keys, const menu[], time = -1, const title[] = "");
```
index - id gracza
keys - jakie klawisze ma rozpoznawać nasze menu, liczba 1023 jest dla wszystkich (od 1 do 0)
menu[] - treść menu
time - czas (w sekundach) wyświetlania menu, -1 oznacza, że menu zamknie się dopiero, gdy gracz naciśnie jakiś dostępny klawisz
title[] - nazwa menu
Jest jeszcze register_menu, ale ja nigdy z tego nie korzystałem, więc nie będę teraz tej funkcji opisywał.

Przykład:

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Stare Menu"
#define VERSION "0.1"
#define AUTHOR "Sebul"

#define TESTMENU_KEYS MENU_KEY_1|MENU_KEY_2|MENU_KEY_0 // tworzymy stałą z trzema klawiszami: 1, 2 i 0

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "staremenu");

	register_menucmd(register_menuid("Testowe Menu"), TESTMENU_KEYS, "staremenuhandle"); // rejestrujemy menu o nazwie "Testowe Menu" i wykorzystujemy TESTMENU_KEYS
}

public staremenu(id) {
	show_menu(id, TESTMENU_KEYS, "\yWidzisz menu?^n^n\w1. Tak^t2. Nie^n^n0. Wyjdz", -1, "Testowe Menu"); // pokazujemy menu, dostępne tylko trzy klawisze

	return PLUGIN_HANDLED;
}

public staremenuhandle(id, key) { // funkcja posiada dwa parametry, id gracza oraz użyty klawisz
	switch(key) { // używamy switcha, pamiętamy, że klawisz 1 ma wartość 0, a klawisz 2 - 1, itd.
		case 0: {
			client_print(id, print_chat, "Wybrales tak.");
		}
		case 1: {
			client_print(id, print_chat, "Wybrales nie.");
		}
		// nie trzeba robić "case 9:", bo i tak wykona się tylko return na samym dole
	}

	return PLUGIN_HANDLED; // menu się zamknie
}

Nowe menu wróć↵
Do stworzenia nowego menu, potrzebujemy:

menu_create - tworzenie menu oraz jego uchwytu
```
menu_create(const title[], const handler[], ml = 0);
```
title[] - nazwa menu oraz jego nagłówek gdy MPROP_TITLE nie ustawione
handler[] - nazwa funkcji do której będą przekazywane informacje (musi to być funkcja publiczna)
ml - nie trzeba podawać
menu_makecallback - tworzenie funkcji kontrolnej
```
menu_makecallback(const function[]);
```
function[] - nazwa funkcji kontrolnej (musi to być funkcja publiczna), w dalszej części będzie to bardziej opisane
menu_additem - dodawania opcji
```
menu_additem(menu, const name[], const info[] = "", paccess = 0, callback = -1);
```
menu - uchwyt stworzonego wcześniej menu
name[] - nazwa dodawanej opcji
info[] - dodatkowe informacje, które można przekazać do menu
paccess - flagi dostępu do danej opcji, w dalszej części będzie to bardziej opisane
callback - funkcja kontrolna, w dalszej części będzie to bardziej opisane

menu_setprop

- konfiguracja menu

menu_setprop(menu, prop, ...);

menu - uchwyt stworzonego wcześniej menu
prop - opcja z listy (plik "newmenus.inc"):

#define MPROP_PERPAGE	1	/* Liczba opcji na stronę (param1 = liczba, 0=bez stronnicowania, 7=domyślnie oraz maksymalnie) */

#define MPROP_BACKNAME	2		/* Nazwa opcji Back/Wstecz (param1 = tekst) */

#define MPROP_NEXTNAME	3		/* Nazwa opcji Next/Dalej (param1 = tekst) */

#define MPROP_EXITNAME	4		/* Nazwa opcji Exit/Wyjście (param1 = tekst) */

#define MPROP_TITLE		5		/* Nagłówek menu (param1 = tekst) */

#define MPROP_EXIT		6		/* Opcja wyjścia? (param1 = liczba, MEXIT_ALL - zawsze, MEXIT_NEVER - nidgy) */

#define MPROP_NOCOLORS	8		/* Czy usunąć automatyczne kolory(param1 = liczba, 0=domyślnie) */

#define MPROP_NUMBER_COLOR	10	/* Kolor numerów opcji (param1 = tekst, "\r"=domyślny) */

... - wartość wybranej opcji

menu_display - wyświetlenie menu
```
menu_display(id, menu, page = 0);
```
id - id gracza
menu - uchwyt stworzonego wcześniej menu
page - strona w menu, którą ma wyświetlić jako pierwszą
menu_destroy - niszczenie menu
```
menu_destroy(menu);
```
menu - uchwyt stworzonego wcześniej menu
menu_item_getinfo - pobieranie informacji z menu (nie do końca opisane)
```
menu_item_getinfo(menu, item, &access, info[], infolen, name[] = "", namelen = 0, &callback);
```
menu - uchwyt stworzonego wcześniej menu
item - podajemy numer opcji z menu (zaczyna się od 0)
access - flagi dostępu do danej opcji
info[] - dodatkowe informacje danej opcji
infolen - maksymalna długość tablicy info[]
name[] - nazwa danej opcji
namelen - maksymalna długość tablicy name[]
callback - ? (chyba id/uchwyt z funkcji "menu_makecallback")

Przykłady:
Gdy menu jest zawsze takie same dla każdego gracza, wystarczy utworzyć je tylko raz

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Nowe Menu"
#define VERSION "0.1"
#define AUTHOR "Sebul"

new g_testmenu; // tworzymy zmienną globalną, uchwyt dla menu

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "nowemenu");
}

public plugin_cfg() { // tworzymy menu, np. w tej funkcji, bo wykonuje się ona tylko raz na mapę
	g_testmenu = menu_create("Widzisz menu?", "nowemenuhandle");
	menu_additem(g_testmenu, "Tak"); // item = 0
	menu_additem(g_testmenu, "Nie"); // item = 1

	menu_setprop(g_testmenu, MPROP_EXITNAME, "Wyjscie");
}

public nowemenu(id) {
	menu_display(id, g_testmenu);

	return PLUGIN_HANDLED;
}

public nowemenuhandle(id, menu, item) { // funkcja posiada trzy parametry, id gracza, uchwyt menu oraz klawisz/item/opcję, która została wybrana
	if(item == MENU_EXIT) {
		return PLUGIN_HANDLED; // zamykamy menu, generalnie nie trzeba dodawać tutaj tego warunku, ale z przyzwyczajenia ja go tutaj dodaję, zresztą czasami nawet lepiej to robić na samej górze funkcji
	}

	switch(item) { // używamy switcha, pamiętamy, że wartość klawisza/itemu/opcji zaczyna się od 0
		case 0: {
			client_print(id, print_chat, "Wybrales tak.");
		}
		case 1: {
			client_print(id, print_chat, "Wybrales nie.");
		}
	}

	return PLUGIN_HANDLED;
}

Gdy menu zmienia się, czyli nie jest ciągle takie same, wtedy trzeba tworzyć je oraz niszczyć za każdym razem (z wykorzystaniem get_user_team

)

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Nowe Menu"
#define VERSION "0.1"
#define AUTHOR "Sebul"

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "nowemenu");
}

public nowemenu(id) {
	new testmenu = menu_create("Widzisz menu?", "nowemenuhandle");

	if(get_user_team(id) == 1) {
		menu_additem(testmenu, "Tak"); // item = 0
		menu_additem(testmenu, "Nie"); // item = 1
	}
	else {
		menu_additem(testmenu, "Nie"); // item = 0
		menu_additem(testmenu, "Tak"); // item = 1
	}

	menu_setprop(testmenu, MPROP_EXITNAME, "Wyjscie");

	menu_display(id, testmenu);

	return PLUGIN_HANDLED;
}

public nowemenuhandle(id, menu, item) { // funkcja posiada trzy parametry, id gracza, uchwyt menu oraz klawisz/item/opcję, która została wybrana
	if(item == MENU_EXIT) {
		menu_destroy(menu); // niszczymy menu przy wyjściu z niego
		return PLUGIN_HANDLED;
	}

	client_print(id, print_chat, "Wybrales opcje: %i", item);

	menu_destroy(menu); // niszczymy menu przy wybraniu jakiejkolwiek opcji
	return PLUGIN_HANDLED;
}

Przykład wykorzystania menu_item_getinfo

, dodatkowo wykorzystane zostało także: is_user_alive

, is_user_connected

, get_user_name

oraz num_to_str

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Nowe Menu - menu_item_getinfo"
#define VERSION "0.1"
#define AUTHOR "Sebul"

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "nowemenu");
}

public nowemenu(id) {
	new testmenu = menu_create("Lista zywych graczy:", "nowemenuhandle");

	new name[48], tempid[6], i;
	for(i=1; i<=32; ++i) { // pętla for od 1 do 32, bo id graczy zaczyna się od 1, a maksymalna ilość graczy to 32 (lub mniej)
		if(!is_user_alive(i)) // sprawdzamy, czy gracz żyje
			continue;

		get_user_name(i, name, 47); // pobieramy jego nick
		num_to_str(i, tempid, 5); // zamieniamy id żywego gracza na tekst
		menu_additem(testmenu, name, tempid); // dodajemy opcję do menu
	}

	menu_setprop(testmenu, MPROP_BACKNAME, "Wroc");
	menu_setprop(testmenu, MPROP_NEXTNAME, "Dalej");
	menu_setprop(testmenu, MPROP_EXITNAME, "Wyjscie");

	menu_display(id, testmenu);

	return PLUGIN_HANDLED;
}

public nowemenuhandle(id, menu, item) { // funkcja posiada trzy parametry, id gracza, uchwyt menu oraz klawisz/item/opcję, która została wybrana
	if(item == MENU_EXIT) {
		menu_destroy(menu);
		return PLUGIN_HANDLED;
	}

	new data[6], iName[64];
	new access, callback;
	menu_item_getinfo(menu, item, access, data, 5, iName, 63, callback);

	new id2 = str_to_num(data);

	if(!is_user_connected(id2)) {
		client_print(id, print_chat, "Gracza o id=%i, nie ma na serwerze", id2);

		menu_destroy(menu);
		return PLUGIN_HANDLED;
	}

	new name[48]; get_user_name(id2, name, 47);
	client_print(id, print_chat, "Wybrales %s, jego pozycja w menu to %i", name, item);

	/* jeśli po wyświetleniu menu długo nie będziemy wybierać gracza, to może się okazać, że wybranego gracza nie ma już na serwerze,
	a na jego miejscu jest już ktoś inny, aby uniknąć takich przypadków, należy stosować jescze jakieś dodatkowe sprawdzanie */

	menu_destroy(menu);
	return PLUGIN_HANDLED;
}

Funkcja kontrolna: wróć↵
Każda opcja w menu może mieć swoją funkcję kontrolną, która może ją włączyć lub wyłączyć.

Do tworzenia funkcji kontrolnej wykorzystujemy menu_makecallback

.

Przykład:

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Nowe Menu - funkcja kontrolna"
#define VERSION "0.1"
#define AUTHOR "Sebul"

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "nowemenu");
}

public nowemenu(id) {
	new testmenu = menu_create("Jestes zywy?", "nowemenuhandle");
	new menucallback = menu_makecallback("nowemenucallback");

	menu_additem(testmenu, "Tak", _, _, menucallback); // item = 0
	menu_additem(testmenu, "Nie", _, _, menucallback); // item = 1
	menu_additem(testmenu, "Nie wiem", _, _, menucallback); // item = 2

	menu_setprop(testmenu, MPROP_EXITNAME, "Wyjscie");

	menu_display(id, testmenu);

	return PLUGIN_HANDLED;
}

public nowemenucallback(id, menu, item) { // funkcja kontolna także ma trzy parametry, id gracza, uchwyt menu oraz klawisz/item/opcję, która została wybrana
	if(item == 0 && !is_user_alive(id)) // jeśli item = 0 (opcja "tak") i gracz nie żyje, to nie będzie mógł tego wybrać
		return ITEM_DISABLED;
	else if(item == 1 && is_user_alive(id)) // jeśli item = 1 (opcja "nie") i gracz żyje, to nie będzie mógł tego wybrać
		return ITEM_DISABLED;

	return ITEM_ENABLED;
}

public nowemenuhandle(id, menu, item) { // funkcja posiada trzy parametry, id gracza, uchwyt menu oraz klawisz/item/opcję, która została wybrana
	if(item == MENU_EXIT) {
		menu_destroy(menu);
		return PLUGIN_HANDLED;
	}

	switch(item) { // używamy switcha, pamiętamy, że wartość klawisza/itemu/opcji zaczyna się od 0
		case 0: {
			client_print(id, print_chat, "Wybrales tak.");
		}
		case 1: {
			client_print(id, print_chat, "Wybrales nie.");
		}
		case 2: {
			client_print(id, print_chat, "Wybrales nie wiem.");
		}
	}

	menu_destroy(menu);
	return PLUGIN_HANDLED;
}

Przykłady menu na flagę wróć↵
Zarówno w starym menu, jak i nowym można ograniczać dostęp albo do całego menu, albo do poszczególnych opcji w menu. Poniżej będzie to pokazane w obu stylach menu.
W starym menu wróć↵
Blokowanie całego menu, gdy można je wywołać tylko poprzez komendę

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Stare Menu - flagi"
#define VERSION "0.1"
#define AUTHOR "Sebul"

#define TESTMENU_KEYS MENU_KEY_1|MENU_KEY_2|MENU_KEY_0

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "staremenu", ADMIN_BAN); // tylko admin będzie mógl użyć tej komendy oraz wyświetlić menu

	register_menucmd(register_menuid("Testowe Menu"), TESTMENU_KEYS, "staremenuhandle");
}

public staremenu(id) {
	if(!cmd_access(id, level, cid, 1)) // sprawdzamy, czy dana osoba posiada uprawnienia
		return PLUGIN_HANDLED;

	show_menu(id, TESTMENU_KEYS, "\yWidzisz menu?^n^n\w1. Tak^t2. Nie^n^n0. Wyjdz", -1, "Testowe Menu");

	return PLUGIN_HANDLED;
}

public staremenuhandle(id, key) {
	switch(key) {
		case 0: {
			client_print(id, print_chat, "Wybrales tak.");
		}
		case 1: {
			client_print(id, print_chat, "Wybrales nie.");
		}
	}

	return PLUGIN_HANDLED;
}

Blokowanie całego menu, gdy można je wywołać nie tylko poprzez komendę, np. menu wyświetla się także przy spawnie

Spoiler

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>

#define PLUGIN "Stare Menu - flagi"
#define VERSION "0.1"
#define AUTHOR "Sebul"

#define TESTMENU_KEYS MENU_KEY_1|MENU_KEY_2|MENU_KEY_0

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "staremenu");

	RegisterHam(Ham_Spawn, "player", "Spawn", 1);

	register_menucmd(register_menuid("Testowe Menu"), TESTMENU_KEYS, "staremenuhandle");
}

public Spawn(id) {
	if(!is_user_alive(id))
		return;

	staremenu(id);
}

public staremenu(id) {
	if(!(get_user_flags(id) & ADMIN_BAN)) // sprawdzamy, czy dana osoba posiada uprawnienia
		return PLUGIN_HANDLED;

	show_menu(id, TESTMENU_KEYS, "\yWidzisz menu?^n^n\w1. Tak^t2. Nie^n^n0. Wyjdz", -1, "Testowe Menu");

	return PLUGIN_HANDLED;
}

public staremenuhandle(id, key) {
	switch(key) {
		case 0: {
			client_print(id, print_chat, "Wybrales tak.");
		}
		case 1: {
			client_print(id, print_chat, "Wybrales nie.");
		}
	}

	return PLUGIN_HANDLED;
}

Blokowanie opcji w menu po wciśnięciu klawisza (czyli bez blokowania klawiszy)

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Stare Menu - flagi"
#define VERSION "0.1"
#define AUTHOR "Sebul"

#define TESTMENU_KEYS MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_0

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "staremenu");

	register_menucmd(register_menuid("Testowe Menu"), TESTMENU_KEYS, "staremenuhandle");
}

public staremenu(id) {
	show_menu(id, TESTMENU_KEYS, "\yKim jestes?^n^n\w1. Graczem^n2. Adminem^n3. Mam immunitet^n^n0. Wyjdz", -1, "Testowe Menu");

	return PLUGIN_HANDLED;
}

public staremenuhandle(id, key) {
	switch(key) {
		case 0: {
			client_print(id, print_chat, "Jestes graczem."); // dostępne dla każdego
		}
		case 1: {
			if(get_user_flags(id) & ADMIN_BAN) // tylko dla admina
				client_print(id, print_chat, "Jestes adminem.");
		}
		case 2: {
			if(get_user_flags(id) & ADMIN_IMMUNITY) // tylko dla admina z flagą a
				client_print(id, print_chat, "Posiadasz immunitet.");
		}
	}

	return PLUGIN_HANDLED;
}

Blokowanie opcji w menu przed wciśnięciem klawisza (czyli z blokowaniem klawiszy)

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Stare Menu - flagi"
#define VERSION "0.1"
#define AUTHOR "Sebul"

#define TESTMENU_KEYS MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_0

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "staremenu");

	register_menucmd(register_menuid("Testowe Menu"), TESTMENU_KEYS, "staremenuhandle");
}

public staremenu(id) {
	new klawisze = TESTMENU_KEYS;

	if(!(get_user_flags(id) & ADMIN_BAN))
		klawisze &= ~MENU_KEY_2; // jeśli gracz nie ma flagi admina, to wyłącza klawisz 2 (opcję 2)

	if(!(get_user_flags(id) & ADMIN_IMMUNITY))
		klawisze &= ~MENU_KEY_3; // jeśli gracz nie ma immunitetu, to wyłącza klawisz 3 (opcję 3)

	show_menu(id, klawisze, "\yKim jestes?^n^n\w1. Graczem^n2. Adminem^n3. Mam immunitet^n^n0. Wyjdz", -1, "Testowe Menu");

	return PLUGIN_HANDLED;
}

public staremenuhandle(id, key) {
	switch(key) {
		case 0: {
			client_print(id, print_chat, "Jestes graczem."); // dostępne dla każdego
		}
		case 1: {
			client_print(id, print_chat, "Jestes adminem."); // tutaj nie trzeba już sprawdzać, czy gracz posiada flagę admina
		}
		case 2: {
			client_print(id, print_chat, "Posiadasz immunitet."); // tutaj nie trzeba już sprawdzać, czy gracz posiada immunitet
		}
	}

	return PLUGIN_HANDLED;
}

W nowym menu wróć↵
Blokowanie całego menu, gdy można je wywołać tylko poprzez komendę

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Nowe Menu - flagi"
#define VERSION "0.1"
#define AUTHOR "Sebul"

new g_testmenu;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "nowemenu", ADMIN_BAN); // tylko admin będzie mógl użyć tej komendy oraz wyświetlić menu
}

public plugin_cfg() {
	g_testmenu = menu_create("Widzisz menu?", "nowemenuhandle");
	menu_additem(g_testmenu, "Tak"); // item = 0
	menu_additem(g_testmenu, "Nie"); // item = 1

	menu_setprop(g_testmenu, MPROP_EXITNAME, "Wyjscie");
}

public nowemenu(id) {
	if(!cmd_access(id, level, cid, 1)) // sprawdzamy, czy dana osoba posiada uprawnienia
		return PLUGIN_HANDLED;

	menu_display(id, g_testmenu);

	return PLUGIN_HANDLED;
}

public nowemenuhandle(id, menu, item) {
	if(item == MENU_EXIT) {
		return PLUGIN_HANDLED;
	}

	switch(item) {
		case 0: {
			client_print(id, print_chat, "Wybrales tak.");
		}
		case 1: {
			client_print(id, print_chat, "Wybrales nie.");
		}
	}

	return PLUGIN_HANDLED;
}

Blokowanie całego menu, gdy można je wywołać nie tylko poprzez komendę, np. menu wyświetla się także przy spawnie

Spoiler

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>

#define PLUGIN "Nowe Menu - flagi"
#define VERSION "0.1"
#define AUTHOR "Sebul"

new g_testmenu;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "nowemenu");

	RegisterHam(Ham_Spawn, "player", "Spawn", 1);
}

public plugin_cfg() {
	g_testmenu = menu_create("Widzisz menu?", "nowemenuhandle");
	menu_additem(g_testmenu, "Tak"); // item = 0
	menu_additem(g_testmenu, "Nie"); // item = 1

	menu_setprop(g_testmenu, MPROP_EXITNAME, "Wyjscie");
}

public Spawn(id) {
	if(!is_user_alive(id))
		return;

	nowemenu(id);
}

public nowemenu(id) {
	if(!(get_user_flags(id) & ADMIN_BAN)) // sprawdzamy, czy dana osoba posiada uprawnienia
		return PLUGIN_HANDLED;

	menu_display(id, g_testmenu);

	return PLUGIN_HANDLED;
}

public nowemenuhandle(id, menu, item) {
	if(item == MENU_EXIT) {
		return PLUGIN_HANDLED;
	}

	switch(item) {
		case 0: {
			client_print(id, print_chat, "Wybrales tak.");
		}
		case 1: {
			client_print(id, print_chat, "Wybrales nie.");
		}
	}

	return PLUGIN_HANDLED;
}

Blokowanie opcji w menu po wciśnięciu klawisza

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Nowe Menu - flagi"
#define VERSION "0.1"
#define AUTHOR "Sebul"

new g_testmenu;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "nowemenu");
}

public plugin_cfg() {
	g_testmenu = menu_create("Kim jestes?", "nowemenuhandle");
	menu_additem(g_testmenu, "Graczem"); // item = 0
	menu_additem(g_testmenu, "Adminem"); // item = 1
	menu_additem(g_testmenu, "Mam immunitet"); // item = 2

	menu_setprop(g_testmenu, MPROP_EXITNAME, "Wyjscie");
}

public nowemenu(id) {
	menu_display(id, g_testmenu);

	return PLUGIN_HANDLED;
}

public nowemenuhandle(id, menu, item) {
	if(item == MENU_EXIT) {
		return PLUGIN_HANDLED;
	}

	switch(item) {
		case 0: {
			client_print(id, print_chat, "Jestes graczem."); // dostępne dla każdego
		}
		case 1: {
			if(get_user_flags(id) & ADMIN_BAN) // tylko dla admina
				client_print(id, print_chat, "Jestes adminem.");
		}
		case 2: {
			if(get_user_flags(id) & ADMIN_IMMUNITY) // tylko dla admina z flagą a
				client_print(id, print_chat, "Posiadasz immunitet.");
		}
	}

	return PLUGIN_HANDLED;
}

Blokowanie opcji w menu przed wciśnięciem klawisza

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Nowe Menu - flagi"
#define VERSION "0.1"
#define AUTHOR "Sebul"

new g_testmenu;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_clcmd("say /menu", "nowemenu");
}

public plugin_cfg() {
	g_testmenu = menu_create("Kim jestes?", "nowemenuhandle");
	menu_additem(g_testmenu, "Graczem"); // item 0 dla każdego
	menu_additem(g_testmenu, "Adminem", _, ADMIN_BAN); // ustawia item 1 tylko dla adminów
	menu_additem(g_testmenu, "Mam immunitet", _, ADMIN_IMMUNITY); // ustawia item 2 tylko dla graczy z immunitetem

	menu_setprop(g_testmenu, MPROP_EXITNAME, "Wyjscie");
}

public nowemenu(id) {
	menu_display(id, g_testmenu);

	return PLUGIN_HANDLED;
}

public nowemenuhandle(id, menu, item) {
	if(item == MENU_EXIT) {
		return PLUGIN_HANDLED;
	}

	switch(item) {
		case 0: {
			client_print(id, print_chat, "Jestes graczem."); // dostępne dla każdego
		}
		case 1: {
			client_print(id, print_chat, "Jestes adminem."); // tutaj nie trzeba już sprawdzać, czy gracz posiada flagę admina
		}
		case 2: {
			client_print(id, print_chat, "Posiadasz immunitet."); // tutaj nie trzeba już sprawdzać, czy gracz posiada immunitet
		}
	}

	return PLUGIN_HANDLED;
}

Można jeszcze daną opcję dodawać na flagę przy użyciu menu_makecallback

, ale nie warto tego używać do takich rzeczy, skoro są lepsze i szybsze sposoby (te które wymieniłem wyżej).

Paczka pluginów użytych w tym poradniku:

tworzenie_menu.rar 281,57 KB 206 Ilość pobrań

No i tym sposobem doszliśmy do końca ;]
Wróć na początek↵

Kod LaTeX

Witamy w Nieoficjalnym polskim support'cie AMX Mod X

Statystyki

Kontakt

Narzędzia użytkownika

Znajomi

Ostatnio byli

#489840 Tworzenie menu - przykłady

Kod LaTeX

Witamy w Nieoficjalnym polskim support'cie AMX Mod X

elipson

Statystyki

Kontakt

Narzędzia użytkownika

Znajomi

Ostatnio byli

#489840 Tworzenie menu - przykłady

Logowanie