15 odpowiedzi w tym temacie

[radzioro17]

Witam,tak jak w temacie szukam pluginu,który odtwarza dźwięki przy strzale do swoich,

szukam też pluginu,który odtwarza dźwięk jak ktoś z tej samej drużyny nas oślepi.

pozdrawiam radzioro17

[Wielkie Jol]

Przy biciu swojego:

 

#include <amxmodx>
#include <fun>
#include <hamsandwich>

#define PLUGIN "Dzwiek przy biciu swojego"
#define VERSION "1.0"
#define AUTHOR "Wielkie Jol"

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    RegisterHam(Ham_TakeDamage, "player", "player_damage")
    
}

public plugin_precache()
    precache_sound("misc/dzwiek_bicia_swojego");

public player_damage(this, idinflictor, idattacker, Float:damage, damagebits) {
    if(!is_user_alive(this) || !is_user_alive(idattacker))
        return;
    if(get_user_team(this) == get_user_team(idattacker))
        client_cmd(idattacker, "mp3 play sound/misc/dzwiek_bicia_swojego.mp3")
        
}

[radzioro17]

Dzięki za plugin,dało by rade ten plugin przerobić aby odtwarzał 4 dźwięki,które by sobie wybrał losowo?

[Wielkie Jol]

#include <amxmodx>
#include <fun>
#include <hamsandwich>

#define PLUGIN "Dzwieki przy biciu swojego"
#define VERSION "1.0"
#define AUTHOR "Wielkie Jol"
new MAX_FF;
new gFRIENDLYFIRE
new dzwieki_friendlyfire[][] = {
    "misc/dzwiek1FF.mp3",
    "misc/dzwiek2FF.mp3",
    "misc/dzwiek3FF.mp3",
    "misc/dzwiek4FF.mp3"
}
public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    RegisterHam(Ham_TakeDamage, "player", "player_damage")
    gFRIENDLYFIRE = register_cvar("amx_frendlyfajer", "1");
}

public plugin_cfg()
    if(get_pcvar_num(gFRIENDLYFIRE) == 1)
    MAX_FF = sizeof dzwieki_friendlyfire


public plugin_precache(){
    if(get_pcvar_num(gFRIENDLYFIRE) == 1){
        for(new i=1; i<=MAX_FF; i++)
            precache_sound(dzwieki_friendlyfire[i])
    }
}

public player_damage(this, idinflictor, idattacker, Float:damage, damagebits) {
    new losowy = random_num(1, MAX_FF)
    if(!is_user_alive(this) || !is_user_alive(idattacker))
        return;
    if(get_user_team(this) == get_user_team(idattacker))
        client_cmd(idattacker, "mp3 play sound/%s.mp3", dzwieki_friendlyfire[losowy])
    
}

[radzioro17]

Plugin nie działa mi ,po restarcie serwera pliki (dzwięki) się nie pobierają,tak jak by nie było pluginu.

Użytkownik radzioro17 edytował ten post 06.02.2014 19:21

[Wielkie Jol]

A spróbuj tak:

#include <amxmodx>
#include <fun>
#include <hamsandwich>

#define PLUGIN "Dzwieki przy biciu swojego"
#define VERSION "1.0"
#define AUTHOR "Wielkie Jol"
new MAX_FF;
new dzwieki_friendlyfire[][] = {
    "misc/dzwiek1FF.mp3",
    "misc/dzwiek2FF.mp3",
    "misc/dzwiek3FF.mp3",
    "misc/dzwiek4FF.mp3"
}
public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    RegisterHam(Ham_TakeDamage, "player", "player_damage")
}

public plugin_cfg()
    MAX_FF = sizeof dzwieki_friendlyfire


public plugin_precache(){
    for(new i=1; i<=MAX_FF; i++)
        precache_sound(dzwieki_friendlyfire[i])
}

public player_damage(this, idinflictor, idattacker, Float:damage, damagebits) {
    new losowy = random_num(1, MAX_FF)
    if(!is_user_alive(this) || !is_user_alive(idattacker))
        return;
    if(get_user_team(this) == get_user_team(idattacker))
        client_cmd(idattacker, "mp3 play sound/%s.mp3", dzwieki_friendlyfire[losowy])
    
}

[sebul]

Żaden z tych pluginów, gdzie jest kilka dźwięków nie ma prawa działać, bo "plugin_precache" wykonuje się przed "plugin_cfg", dodatkowo po co coś ma być losowane przed warunkiem, który może być spełniony? Losowanie należy dać w tym samym momencie co odtwarzanie dźwięku.

[radzioro17]

Nie idzie teraz skomplikować

[Wielkie Jol]

Po radach Sebula powinno działać

#include <amxmodx>
#include <fun>
#include <hamsandwich>

#define PLUGIN "Dzwieki przy biciu swojego"
#define VERSION "1.0"
#define AUTHOR "Wielkie Jol"
new dzwieki_friendlyfire[][] = {
    "misc/dzwiek1FF.mp3",
    "misc/dzwiek2FF.mp3",
    "misc/dzwiek3FF.mp3",
    "misc/dzwiek4FF.mp3"
}
public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    RegisterHam(Ham_TakeDamage, "player", "player_damage")
}

public plugin_precache(){
    for(new i=1; i<sizeof dzwieki_friendlyfire; i++)
        precache_sound(dzwieki_friendlyfire[i])
}

public player_damage(this, idinflictor, idattacker, Float:damage, damagebits) {
    if(!is_user_alive(this) || !is_user_alive(idattacker))
        return;
    if(get_user_team(this) == get_user_team(idattacker)){
        new losowy = random_num(1, sizeof dzwieki_friendlyfire)
        client_cmd(idattacker, "mp3 play sound/%s.mp3", dzwieki_friendlyfire[losowy])
    }
}

 

 

[radzioro17]

Teraz dźwięki się pobierały,ale taki error wyskakuje w konsoli serwa

L 02/06/2014 - 22:16:20: [AMXX] Run time error 4 (plugin "testowy2.amxx") - debug not enabled!
L 02/06/2014 - 22:16:20: [AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes).
L 02/06/2014 - 22:17:28: [AMXX] Run time error 4 (plugin "testowy2.amxx") - debug not enabled!
L 02/06/2014 - 22:17:28: [AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes).

[sebul]

Widzę, że jednak jest jeszcze parę rzeczy źle zrobionych, ja bym to zrobił tak

#include <amxmodx>
#include <hamsandwich>

#define PLUGIN "Dzwieki przy biciu swojego"
#define VERSION "1.0"
#define AUTHOR "Wielkie Jol"

new const dzwieki_friendlyfire[][] = {
    "misc/dzwiek1FF.mp3",
    "misc/dzwiek2FF.mp3",
    "misc/dzwiek3FF.mp3",
    "misc/dzwiek4FF.mp3"
}
new g_ile;

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR);
    RegisterHam(Ham_TakeDamage, "player", "player_damage", 1); // post, bo nic nie zmieniamy, więc jak dla mnie powinno się dać post
}

public plugin_precache() {
    g_ile = sizeof(dzwieki_friendlyfire);
    for(new i=0; i<g_ile; ++i) // indeksowanie zaczyna się od 0
        precache_sound(dzwieki_friendlyfire[i]);
}

public player_damage(this, idinflictor, idattacker, Float:damage, damagebits) {
    if(!is_user_connected(this) || !is_user_connected(idattacker)) // po zabiciu granatem, zabójca nie koniecznie musi być żywy
        return HAM_IGNORED;

    if(get_user_team(this) == get_user_team(idattacker))
        client_cmd(idattacker, "mp3 play sound/%s.mp3", dzwieki_friendlyfire[random(g_ile)]); // wcześniej były losowane wartości ze złego przedziału, ze względu na to, że indeksowanie jest od 0

    return HAM_IGNORED;
}

[radzioro17]

Przetestowałem dziś ten plugin,i ładnie dźwięki się pobrały,ale nie odtwarza,ani żaden error nie wyskakuje,w czym może być problem?

[Mathew1910]

Fajne i przydatne.

 

[sebul]

Przetestowałem dziś ten plugin,i ładnie dźwięki się pobrały,ale nie odtwarza,ani żaden error nie wyskakuje,w czym może być problem?

Wydawało mi się, że to poprawiłem, ale jak widać w poście jest źle. Musisz to

client_cmd(idattacker, "mp3 play sound/%s.mp3", dzwieki_friendlyfire[random(g_ile)]);

zamienić na

client_cmd(idattacker, "mp3 play sound/%s", dzwieki_friendlyfire[random(g_ile)]);

[radzioro17]

Teraz działa dzięki

[sebul]

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Pomoc udzielona

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL