AMXX.pl: Support AMX Mod X i SourceMod

Tutorial dla początkujących
Informacje wstępne
Scripting AMXX


Cel
Nauka tworzenia pluginów AMXX

Wymagania

• Znajomość obsługi AMXX
• Umiejętność programowania
• Podstawowa znajomość Pawna
• Racjonalne tworzenie algorytmów
• Umiejętność korzystania z manuala
• Edytor Pawna wraz z kompilatorem AMXX

Wstęp
Na samym początku zadajmy sobie pytanie: czym są pluginy AMXX i jak działają.

Pluginy AMXX to algorytmy modyfikacji rozgrywki na serwerach HLDS, pisane w języku Pawn,
zrozumiałym dla ludzi i zapisywane pod postacią plików SMA, które w wyniku kompilacji przybierają
postać kodu niezrozumiałego dla człowieka, ale zrozumiałego dla AMXX, zapisywane pod postacią
plików AMXX, które komunikują się z serwerem HLDS poprzez Metamoda:P, zmieniając rozgrywkę.

Istota
Tym samym, plugin komunikuje się z Metamodem:P, a Metamod:P z silnikiem gry (serwerem HLDS).
Musimy pamiętać, że każda wymiana informacji pomiędzy serwerem a silnikiem gry, zużywa liczne
zasoby sprzętowe i należy zadawać możliwie jak najmniej zapytań do silnika gry poprzez Metamoda:P.

Plugins.ini
Plik plugins.ini zawiera listę pluginów, które zostaną załadowane do AMXX i będą wykonywać swoje
algorytmy, komunikując się z serwerem HLDS poprzez MetaModa:P, modyfikując przebieg gry.

Jednak kolejność pluginów wpisanych w pliku plugins.ini nie jest bez znaczenia.
Zwróćmy teraz uwagę na sposób działania AMXX, czyli interakcję z serwerem gry.
AMXX pozwala nam, poprzez MetaModa:P, na następujące operacje:

• Zarejestrowanie danego zdarzenia czy wartości (np. odczytanie liczby pieniędzy danego gracza, czy zaobserwowanie wybuchu bomby)
• Modyfikowanie danego zdarzenia czy wartości (np. zmiana punktów życia danego gracza, czy przedłużenia czasu trwania oślepienia)
• Zablokowanie danego zdarzenia czy usunięcie wartości (np. brak obrażeń od granatów, czy usunięcie limitu posiadanych dolarów)
• Wywołanie danego zdarzenia (np. zabicie gracz, teleportacja gracza na respawn wrogów, czy pozbawienie gracza jego broni)
• Tworzenie danego zdarzenia czy wartości (np. zabicie vipa lub ucieczka terrorystów, czy stworzenie nowych cvarów)

Tym samym, poszczególne pluginy mogą być od siebie zależne, a ich kolejność ma znaczenie.
Należy zatem zwracać uwagę na kolejność pluginów w pliku plugins.ini, przy czym algorytmy
kolejnych pluginów, od góry pliku plugins.ini, wykonywane są proporcjonalnie sekwencyjnie.

Przykładowo, jeśli w pluginie pierwszym od góry pliku plugins.ini, zablokujemy możliwość mówienia,
to w pluginie drugim od góry, nie zostanie zarejestrowane powiedzenie na sayu określonej wartości.
W odwrotnej kolejności tych pluginów w pliku plugins.ini zaś, będzie to z kolei możliwe do wykonania.

AMXMODX
Pierwszą, podstawową biblioteką, jaką będziemy musieli załączyć do naszego pluginu, jest AMXMODX.
W tym celu, dodajemy na samej górze naszego kodu SMA następującą linijkę kodu

#include <amxmodx>

AMXX posiada parę publicznych, predefiniowanych funkcji, a oto one:

plugin_natives
Ta funkcja wywoływana jest jako pierwsza, tuż po załadowaniu pluginu do pamięci AMXX.
W niej należy zainicjować wszelkie natywy do współpracy z innymi pluginami, czyli sprawić,
by możliwa była kompleksowa komunikacja pomiędzy funkcjami poszczególnych pluginów.

Jak już pisałem, funkcje ładowane są kolejno, od góry pliku plugins.ini, tak więc kolejność jest istotna.

plugin_precache
Ta funkcja wywoływana jest po załadowaniu wszytkich pluinów z natywami, lecz jeszcze przed pełnym zainicjowaniem
serwera HLDS i to w niej należy zarejestrować wszelkie wymagane do pobrania przez Użytkowników pliki niestandardowe,
z których będzie korzystał plugin, by powiadomić klienta gry o konieczności pobrania tych plików przed ustaleniem połączenia.

W tej właśnie funkcji należy zarejestrować wszelkie modyfikatory skryptów startowych serwera HLDS, by móc
w nie ingerować, zanim zostaną załadowane i wykonane skrypty startowe, uniemożliwiając ich identyfikację.

plugin_init
Ta funkcja wywoływana jest podczas inicjalizacji pluginu, po pełnym załadowaniu funkcji startowych serwera.
W tej funkcji należy zarejestrować nasz plugin przy użyciu funkcji register_plugin o następujących parametrach

register_plugin(const plugin_name[], const version[], const author[])

Warto zidentyfikować plugin w celu późniejszego testowania stanu pluginu i odnalezienia go na liście pluginów.
Składnia argumentów funkcji nie wymaga chyba większego komentarza, w przypadku wątpliwości zapraszam do manuala.

Przykład
Na tym etapie, potrafimy już stworzyć i zarejestrować pierwszy plugin, nie robiący praktycznie nic.

#include <amxmodx>

public plugin_init(){
	register_plugin("Nauka AMXX", "0.1", "benio101");
}

Przypomnijmy, w pierwszej linijce zaimportowaliśmy wymaganą zawsze dla AMXX, bibliotekę amxmodx.
W trzeciej linijce zainicjowaliśmy publiczną funkcję plugin_init, wykonywaną po pełnym załadowaniu skryptów startowych HLDS.
Przypominam, że funkcja plugin_init winna być funkcją publiczną, inaczej może nie zostać ona wykonana w oczekiwanym momencie.
W czwartej linijce, rejestruję plugin i na tym kończy się działanie naszego testowego pluginu, który praktycznie nie zmienia rozgrywki.

W funkcji plugin_init należy także zarejestrować wszelkie nasłuchiwacze zdarzeń, jak śmierć gracza, czy nowa runda.

plugin_cfg
Ta funkcja wywoływana jest tuż po plugin_init i służy konfiguracji pluginu, m.in. pobraniu zmiennych globalnych z silnika gry,
ustanowieniu połączenia z bazą danych, czy pobrania innych, istotnych danych do współpracy pluginu z zasobami zewnętrznymi.

register_event
Pierwsza z funkcji, którą poznamy, pozwala na przechwycenie wybranych zdarzeń, które dokonywane są na serwerze.
Tutaj odwołuję do niezwykle istotnej strony, na której wypisane są zdarzenia silnika HLDS wraz z argumentami:

Half-Life 1 Game Events

Teraz spróbujemy przechwycić funkcję śmierci, w tym celu musimy zarejestrować w funkcji plugin_init nasłuchiwacz tego zdarzenia

register_event("DeathMsg", "DeathMsg", "a");

Pierwszy parametr, zgodnie z dokumentacją, oznacza nazwę zdarzenia.
Drugi parametr oznacza funkcję publiczną, która będzie wywoływana w momencie wystąpienia tego zdarzenia. Trzeci parametr
wynosi "a", gdyż DeathMsg jest eventem globalnym. Tym samym utworzymy sobie funkcję publiczną DeathMsg i damy zabójcy 200$.

read_data
Jak możemy wyczytać z powyższego linku, DeathMsg posiada cztery argumenty. Nam wystarczy pierwszy argument, czyli id zabójcy.

public DeathMsg(){
	new killer=read_data(1);
}

Funkcja DeathMsg wywoływana jest w momencie wystąpienia zdarzenia śmierci.
Za pomocą funkcji read_data możemy odczytać dany parametr funkcji, ponieważ pierwszy argument
to numer identyfikacyjny zabójcy, ten właśnie numer pobierzemy i zapiszemy do nowo utworzonej zmiennej killer.
Teraz będziemy chcieli nagrodzić zabójcę, przekazując mu dodatkowe 200 dolarów za zabójstwo.
W tym celu, skorzystamy z funkcji z biblioteki cstrike, cs_set_user_money.

Import biblioteki
Aby móc skorzystać z tej funkcji, musimy najpierw zaimportować kolejną bibliotekę,
w tym celu dodajemy do naszego kodu następującą linijkę (najlepiej pod bilioteką amxmodx)

#include <cstrike>

Przypomnijmy, jak powinien wyglądać nasz obecny, pełny kod:

#include <amxmodx>
#include <cstrike>

public plugin_init(){
	register_plugin("Nauka AMXX", "0.1", "benio101");

	register_event("DeathMsg", "DeathMsg", "a");
}

public DeathMsg(){
	new killer=read_data(1);
}

Sprawdzenie obecności gracza
Teraz dochodzimy do niezwykle istotnej rzeczy, którą musisz zapamiętać raz na zawsze!
Operując na jakimkolwiek graczu, upewnij się, że gracz może zostać danej operacji poddany.
W przykładzie, chcemy dodać pieniądze graczowi, jednak zanim to zrobimy, musimy się upewnić,
czy gracz jest jeszcze na naszym serwerze. Zawsze mógł rzucić granat, wyjść z serwera, a opiero po chwili
nastąpi zdarzenie śmierci. Co się stanie przy próbie dodania pieniędzy graczowi, którego nie ma na serwerze?
Na pewno jest to niepotrzebne zapytanie do silnika gry, dużo większe zużycie zasobów sprzętowych, a także stale
powiększające się logi błędów. Na dłuższą metę, takie właśnie błędy skutkują dużymi lagami bądź crashami serwera.

Tym samym, użyjemy funkcji is_user_connected, w celu sprawdzenia, czy gracz jest jeszcze na serwerze.
Pamiętajmy, że aktualnie killer reprezentuje numer identyfikacyjny zabójcy, jednak w różnych funkcjach, możemy różnie
identyfikować poszczególne byty czy zdarzenia. Przy okazji, każdy byt na mapie ma swój własny, unikalny numer identyfikacyjny,
jednakże numerem identyfikacyjnym gracza jest numer z zakresu od 1 do maksymalnej liczby graczy włącznie. Tym samym, numer
bytu, będący większy lub równy 1 i nie większy, niż maksymalna liczba graczy na serwerze, oznacza na pewno gracza. (niekoniecznie online!)

public DeathMsg(){
	new killer=read_data(1);
	if(is_user_connected(killer)){
		// Dodawanie pieniedzy
	}
}

Teraz skorzystamy z natywów biblioteki cstrike i dodamy zabójcy 200 dolarów.

cs_set_user_money(killer, cs_get_user_money(killer) + 200);

Jak można zauważyć, nie mamy wprost funkcji dodającej pieniądze. W związku z tym,
musimy jako drugi parametr funkcji cs_set_user_money podać sumę 200
i obecnej liczby dolarów gracza, pobieranej przy użyciu funkcji cs_get_user_money

Zwracana wartość
W nowo utworzonej funkcji DeathMsg, zwrócimy na końcu odpowiednią wartość.
Dostępne wartości do zwrócenia:

PLUGIN_CONTINUE
Domyślna wartość, przerywająca dalsze wywołanie funkcji, jednak przez każdy inny plugin, a także silnik gry,
zdarzenie zostanie wywołane. Po prostu nic niżej od tego polecenia nie zostanie wywołane w tej danej jednej funkcji.

PLUGIN_HANDLED_MAIN
Dalsze wywołanie funkcji nie będzie możliwe, podobnie, jak w przypadku PLUGIN_CONTINUE, dalej wszystkie
pluginy będą mogły odnotować tę funkcję, jednak event ten zostanie zablokowany dla silnika właściwego gry.

PLUGIN_HANDLED
Dalsze wywoływanie funkcji zostanie przerwane, a ani silnik gry nie odnotuje tego eventu, ani, w przeciwieństwie
do PLUGIN_HANDLED_MAIN, żaden z kolejnych pluginów, wypisanych poniżej od tego obecnego w plugins.ini.

Nam wystarczy PLUGIN_CONTINUE, bowiem nie chcemy blokować śmierci w silniku, ani pozbawiać informacji o śmierci
kolejnych pluginów. Na koniec zmienimy nazwę pluginu na odzwierciedlającą rzeczywiste zastosowanie pluginu. Gotowy kod:

#include <amxmodx>
#include <cstrike>

public plugin_init(){
	register_plugin("Dodatkowe 200 dolarow za zabojstwo", "0.1", "benio101");

	register_event("DeathMsg", "DeathMsg", "a");
}

public DeathMsg(){
	new killer=read_data(1);
	if(is_user_connected(killer)){
		cs_set_user_money(killer, cs_get_user_money(killer) + 200);
	}
	return PLUGIN_CONTINUE;
}

Tym samym, właśnie napisaliśmy swój pierwszy plugin, który daje dodatkowe 200 dolarów za zabójstwo.


Tutorial napisany, choć z drobnym opóźnieniem, z okazji Światowego Dnia Jakości.
Jeśli przypadnie on Wam do gustu, to mogę pokusić się w wolnym czasie o napisanie kolejnych
części, jako kontynuację, z rozwinięciem wątku i coraz bardziej zaawansowanymi przykładami Scriptingu.
Użytkownik benio101 edytował ten post 09.12.2012 03:20
+kot.

Nooo benio postarałeś się oby wiecej takich

Poradnik świetny dla początkujących (lepsze niż dotychczasowe "Mój pierwszy plugin", które w większości polegały na skopiuj ode mnie kod i będzie działać)

Oby więcej takich poradników, prowadzących w tajniki AMXX

W końcu coś porządnego, bardzo dobra robota
Przeczytałem całe i przy okazji literówkę znalazłem:

w tym celu dodajemy do naszego kodu następującą lnijkę (najlepiej pod bilioteką amxmodx)

Świetnie! Jednak Jak dla mnie jeszcze za dużo teorii. Ale idzie to w dobrym kierunku.

Poradnik super. Ja jako nowy uwazam, ze jest dla mnie w 100% zrozumialy. Tylko dlaczego wszedzie jest "MetaModa:P"

Super poradnik. Oby tak dalej

Poradnik super. Ja jako nowy uwazam, ze jest dla mnie w 100% zrozumialy. Tylko dlaczego wszedzie jest "MetaModa:P"

Cytat z wiki

Różnice

MetaMod jest rozwijany przez kodera o pseudonimie willday. Aktualnie wersja 1.19 pojawiła się po MetaMod-P i jest ulepszona niż MetaMod-P, między innymi jest rekomendowana dla użytkówników korzystających z PODBota.
MetaMod-P jest ulepszoną wersją Metamod'a. Posiada funkcję dynamicznego linkowania obiektów i wykrywania modu, posiada kilkanaście innych ulepszeń, które pozwalają mu na pracę z przyszłymi aktualizacjami silnika Half-Life oraz pojawiających się nowych modów. Metamod-P jest rozwijany przez kodera o pseudonimie hullu, evilspy (Jussi Kivilinna).
Co jest takiego specjalnego w MetaMod-P?

• Statycznie przypisane linki do obiektów zostały zastąpione dynamicznymi linkami - dzięki temu nie trzeba aktualizować MetaMod-P jak wychodzą nowe wersje tego samego moda.
• Dodatkowe miejsca na funkcje silnika, przeznaczone na przyszłe aktualizacje silnika Half-Life (raczej mało prawdopodobne bo Valve jest bardziej zainteresowane w Source). Żeby MetaMod-P się zeaktualizował, Valve musiałoby odać ekstra 128 nowych funkcji do silnika Half-Life, a to jest masa.
• Automatycznie wykrywa gamedll dla niezanych/nowych modów, dzięki czemu nie musisz używać metamod-config aby zmusić metamod'a do działania z tymi pluginami.
• Z powodu powyższych zmian nie musisz aktualizować MetaMod-P gdyby wyszły nowe wersje modów gry Half-Life.
• Lepsza wydajność - niższe użycie CPU, niż oryginalnego MetaMod'a.
• Niestety nie posaida paru ulepszeń jakie ma MetaMod 1.19, który pojawił się po MetaMod-P, i brakuje mu kilku funkcji porawionych dla CS 1.5, i nie nadaje się zbytnio właśnie do CS 1.5 (szczególnie z botami).

Aż miło się patrzy na taki poradnik

super poradnik
ja również jako początkujący wszystko zrozumiałem
dzięki

Well done ładnie, przejrzyście, estetycznie.

Przyda się dla "zielonych"

W końcu coś porządnego, zielonym się na pewno przyda i liczymy na dalsze takie poradniki ;D

Czekam na więcej ;]

Bardzo dobry poradnik, w odróżnieniu do innych na tym forum. Wszytsko prosto napisane i dzięki temu poradnikowi w końcu pojołem istotę pluginu i jakie to jest naprawdę proste.

 

Sprawdzenie obecności gracza
Teraz dochodzimy do niezwykle istotnej rzeczy, którą musisz zapamiętać raz na zawsze!
Operując na jakimkolwiek graczu, upewnij się, że gracz może zostać danej operacji poddany.

 

Zwracając uwagę na sens słów, że zanim się wykona operacje na danym graczu trzeba sprawdzić czy on w ogóle jest.

Dlatego moją ciekawość budzi czemu np. przy tej funkcji trzeba sprawdzać czy atakujący jest żywy, przecież na nim żadna operacja nie będzie wykonywana, lecz jego ofiara potem ma rzucić broń.

 

(Wyrzucenie broni - Generator klas)

public plugin_init()
{
(...)
    register_event("Damage", "Damage_Wyrzucenie", "b", "2!=0");
}
(...)
public Damage_Wyrzucenie(id)
{
	new idattacker = get_user_attacker(id);

	if(!is_user_alive(idattacker))
		return;

	if(!ma_klase[idattacker])
		return;

	if(random_num(1, 4) != 1)
		return;

	client_cmd(id, "drop");
}

Spodziewam się mimo wszystko, że ja jestem w błędzie dlatego będę wdzięczny za wytłumaczenie.

Dobra robota,oby więcej takich poradników.

Wracając do mojego pytania i funkcji wyrzucenia broni, według mnie tak byłoby najlepiej, mam rację?

public Damage_Wyrzucenie(id){
	new idattacker = get_user_attacker(id);

	if(ma_klase[idattacker] && random(3)==0 && is_user_alive(idattacker))
	    client_cmd(id, "drop");
}

Patrząc na kod nasuwa się pytanie, czy serwer bardziej obciąży losowanie liczby w random(x), czy zapytanie is_user_alive(id)?

 

//edit:

Taki kod zakładając, że is_user_alive(id) jest w ogóle potrzebne, bo 2 posty wyżej podważyłem konieczność jego użycia.

Użytkownik Lacostii edytował ten post 26.07.2013 01:44

Jeśli chciałbyś optymalizować kod z generatora, co z reguł jest zbyt czasochłonne, to proponowałbym się zająć linijką niżej, mianowicie samym wyrzucaniem broni.

register_event("DeathMsg", "DeathMsg", "a");

 

Nie rozumiem tego.

Jeżeli próbuje napisać plugin dot. rang na zombiemod to wyglądałoby to tak?

 

register_event("RangiZombieMod", "RangiZombiemod", "a");

O co chodzi z tym "a" ?