Panda

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define PLUGIN "SpeedSpeed"
#define VERSION "1.0"
#define AUTHOR "R3X"

new gfwUpdate;

new const Float:gfCSSpeeds[]={
	000.0,
	250.0, 000.0, 260.0, 250.0, 240.0,
	250.0, 250.0, 240.0, 250.0, 250.0,               
	250.0, 250.0, 210.0, 240.0, 240.0,    
	250.0, 250.0, 210.0, 250.0, 220.0,              
	230.0, 230.0, 250.0, 210.0, 250.0,            
	250.0, 235.0, 221.0, 250.0, 245.0
}

new giUserWeapon[33];
new Float:gfUserSpeed[33];
new Float:gfOffset[33];
new bool:freezetime = true

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);
	register_logevent("PoczatekRundy", 2, "1=Round_Start")
	register_event("HLTV", "NowaRunda", "a", "1=0", "2=0")
	register_event("CurWeapon", "eventCurWeapon", "be", "1=1");
	
	gfwUpdate = CreateMultiForward("speed_update", ET_CONTINUE, FP_CELL, FP_CELL);
}
public plugin_natives(){
	register_library("SpeedSpeed");
	
	register_native("add_user_speed", "_add_user_speed");
	register_native("update_user_speed", "_update_user_speed");
}

public eventCurWeapon(id){
	if(!freezetime){
		new wid = read_data(2);
		giUserWeapon[id] = wid;
		updateSpeed(id, wid);
	}
}

public updateSpeed(id, wid){
	gfUserSpeed[id] = gfCSSpeeds[wid];
	
	gfOffset[id] = 0.0;
	
	new ret;
	ExecuteForward(gfwUpdate, ret, id, wid);

	if(ret == 0)
		gfUserSpeed[id] += gfOffset[id];
		
	__set_user_speed(id, gfUserSpeed[id]);
}
stock __set_user_speed(id, Float:fSpeed = -1.0){
	if(fSpeed < 0.0){
		new wid = get_user_weapon(id);
		fSpeed = gfCSSpeeds[wid];
	}
	
	set_pev(id, pev_maxspeed, fSpeed);
	client_cmd(id, "cl_forwardspeed %.1f", fSpeed);
	client_cmd(id, "cl_backspeed %.1f", fSpeed);
	client_cmd(id, "cl_sidespeed %.1f", fSpeed);
}
public _add_user_speed(plugin, params){
	if(params < 2){
		log_error(10, "Bad parameter number");
		return 0;
	}
	new id = get_param(1);
	if(!is_user_connected(id))
		return 0;
	new Float:fOffset = get_param_f(2);
	gfOffset[id] += fOffset;
	return 1;
}
public _update_user_speed(plugin, params){
	if(params < 1){
		log_error(10, "Bad parameter number");
		return 0;
	}
	new id = get_param(1);
	if(!is_user_connected(id))
		return 0;
	updateSpeed(id, giUserWeapon[id]);
	return 1;
}

public PoczatekRundy()
	freezetime = false

public NowaRunda()
	freezetime = true