TaocziNN

/*
CHANGELOG:
* 1.0.0 - pierwsze wydanie
* 1.0.1 - naprawa: kopiowanie monet z jednego nicku na drugi
* 1.0.2 - dodanie: natywow
* 1.0.3 - dodanie: typu zapisu
* 1.0.4 - naprawa: dostawanie monet za wpisanie kill w konsoli (Podziekowania dla Szybcioor za wykrycie i dla Goliath za zalatanie :])
* 1.0.5 - dodanie: nowe eventy za ktore zdobywa sie monety
* 1.0.6 - dodanie: cvaru - wlacznie/wylaczenie monet za TeamKill
* 1.0.7 - naprawa: brak monet za zabicie
* 1.0.8 - naprawa: brak monet za uratowanie/zabicie hosta
* 1.1.0 - naprawa: zbyt maly rozmiar tablicy
		- naprawa: problem z pobieraniem cvaru cod_savetype 
		- optymalizacja kodu
* 1.1.1 - dodanie: cvaru - ustawia minimalna ilosc graczy na serwerze, od ktorej mozliwe jest zdobywanie monet
*/
 
#include <amxmodx>
#include <amxmisc>
#include <nvault>
 
#define PLUGIN	"System Monet"
#define AUTHOR	"kisiel96"
#define VERSION	"1.1.1"
 
#define TASK_SHOW_COINS 666
#define VIP ADMIN_LEVEL_G
 
enum events { kill = 0, kill_hs};
 
new player_auth[33][64];
new player_coins[33];
new bool:player_vip[33];
 
new sync_hud_obj;
 
new pcvar_coins[events];
new pcvar_coins_vip[events];
new cvar_coins[events];
new cvar_coins_vip[events];
 
new pcvar_coins_minplayers;
new pcvar_coins_ff;
new cvar_coins_minplayers;
new cvar_coins_ff;
 
new pcvar_savetype;
new vault;
 
public plugin_init()
{	
	register_plugin(PLUGIN, VERSION, AUTHOR);
 
	register_event("DeathMsg", "EnemyKilled", "a");
	register_event("ResetHUD", "ResetHUD", "abe");
 
	sync_hud_obj = CreateHudSyncObj();
 
	pcvar_coins_ff						= 	register_cvar("cod_coins_friendlyfire", "0");
 
	pcvar_coins[kill]					= 	register_cvar("cod_coins_kill", "1");
	pcvar_coins_vip[kill] 				= 	register_cvar("cod_coins_kill_vip", "2");
	pcvar_coins[kill_hs] 				= 	register_cvar("cod_coins_kill_hs", "2");
	pcvar_coins_vip[kill_hs] 			= 	register_cvar("cod_coins_kill_hs_vip", "3");
 
	pcvar_coins_minplayers				= 	register_cvar("cod_coins_minplayers", "2");
 
	pcvar_savetype 						= 	register_cvar("blanty_save", "1");
 
	vault = nvault_open("monety");
	if(vault == INVALID_HANDLE)
		set_fail_state("Nie mozna otworzyc pliku");
}
 
public plugin_natives()
{
	register_native("cod_get_user_coins", "GetCoins", 1);
	register_native("cod_set_user_coins", "SetCoins", 1);
}	
 
public client_authorized(id)
{
	RemoveCoins(id);
 
	switch(pcvar_savetype)
	{
		case 1: get_user_name(id, player_auth[id], 63);
		case 2: get_user_authid(id, player_auth[id], 63);
		case 3: get_user_ip(id, player_auth[id], 63);
	}
 
	if(get_user_flags(id) & VIP)
		player_vip[id] = true;
	else 
		player_vip[id] = false;
 
	LoadCoins(id);
}
 
public client_connect(id)
	LoadCoins(id);
 
public client_disconnect(id)
{
	SaveCoins(id);
	RemoveCoins(id)
}
 
public plugin_end()
	nvault_close(vault);
 
// /----------- //
// |RESET MONET| //
// -----------/ //
 
public RemoveCoins(id)
{
	player_coins[id] = 0;
	player_vip[id] = false;
}
 
// /-------------- //
// |ZLICZNIE MONET| //
// --------------/ //
 
public EnemyKilled()
{
	cvar_coins_minplayers = get_pcvar_num(pcvar_coins_minplayers);
	if(get_playersnum() < cvar_coins_minplayers)
		return;
 
	new kid = read_data(1);
	new vid = read_data(2);
	new hs = read_data(3);
 
	if(kid == vid)
		return;
 
	cvar_coins_ff = get_pcvar_num(pcvar_coins_ff) 
 
	if(cvar_coins_ff == 0 && get_user_team(kid) == get_user_team(vid))
		return;
 
	cvar_coins[kill] = get_pcvar_num(pcvar_coins[kill]);
	cvar_coins_vip[kill] = get_pcvar_num(pcvar_coins_vip[kill]);
	cvar_coins[kill_hs] = get_pcvar_num(pcvar_coins[kill_hs]);
	cvar_coins_vip[kill_hs] = get_pcvar_num(pcvar_coins_vip[kill_hs]);
 
	if(get_user_team(kid) == 1) {
		if(player_vip[kid]) {
			if(hs)
				player_coins[kid] += cvar_coins_vip[kill_hs];
			else
				player_coins[kid] += cvar_coins_vip[kill];
		}
		else {
			if(hs)
				player_coins[kid] += cvar_coins[kill_hs];
			else
				player_coins[kid] += cvar_coins[kill];
		}
	}
}
 
// /--- //
// |HUD| //
// ---/ //
 
public ShowCoins(id)
{
	id -= TASK_SHOW_COINS;
 
	set_hudmessage(0, 255, 0, 0.01, 0.16, 0, 0.0, 0.3, 0.0, 0.0);
	ShowSyncHudMsg(id, sync_hud_obj, "Blanty: %i", player_coins[id]);
}
 
public ResetHUD(id)
{
	if(!is_user_alive(id))	{
		if(get_user_team(id) == 1) {
			remove_task(id + TASK_SHOW_COINS);
			return;
		}
	}
	else {
		if(get_user_team(id) == 1) {
			if(!task_exists(id+TASK_SHOW_COINS)) {
				set_task(0.1, "ShowCoins", id + TASK_SHOW_COINS, _, _, "b");
			}
		}
	}
}
 
// /------ //
// |NATYWY| //
// ------/ //
 
public SetCoins(id, wartosc)
{
	player_coins[id] = wartosc
}
 
public GetCoins(id)
	return player_coins[id];
 
// /------ //
// |NVAULT| //
// ------/ //
 
public SaveCoins(id)
{
	new vaultkey[64], vaultdata[256];
	formatex(vaultkey, 63, "%s-player_coins", player_auth[id]);
	formatex(vaultdata, 255, "%d#", player_coins[id]);
	nvault_set(vault, vaultkey, vaultdata);
 
	return;
}
 
public LoadCoins(id)
{
	new vaultkey[64], vaultdata[256];
	formatex(vaultkey, 63, "%s-player_coins", player_auth[id]);
	formatex(vaultdata, 255, "%d#", player_coins[id]);
	nvault_get(vault, vaultkey, vaultdata,255);
 
	replace_all(vaultdata, 255, "#", " ");
 
	new temp_player_coins[33];
	parse(vaultdata, temp_player_coins, 32);
 
	player_coins[id] = str_to_num(temp_player_coins);
 
	return;
}