10 odpowiedzi w tym temacie

[Onyke]

W tym poradniku pokażę jak zrobić nowe klasy do DiabloMOD Core by DarkGL.
Nie jest to nic trudnego ale w temacie z modem pojawiło się już pytanie dotyczące tworzenia nowych klas.

Klasa w tym poradniku będzie mieć następujące moce:

• zadaje dodatkowe obrażenia
• otrzymuje mniejsze obrażenia
• posiada mniejszą grawitację
• posiada mniejszą widoczność
• posiada większą prędkość
• za zabicie odnawia sobie HP
• na nożu odnawia sobie HP

Czyli w skrócie przedstawię przykładowe użycie tych forwardów i natywów:

diablo_damage_class_do(iVictim,iAttacker,&Float:fDamage);
diablo_damage_class_taken(iVictim,iAttacker,&Float:fDamage);
diablo_set_user_grav(id,Float:fGrav);
diablo_set_user_render(id, fx = kRenderFxNone, r = 255, g = 255, b = 255, render = kRenderNormal, amount = 16 , Float:fTime = 0.0 )
diablo_add_speed(id,Float:fAmount);
diablo_add_hp(id,iHp);
diablo_death(iKiller , killerClass , iVictim , victimClass );
Float:diablo_cast_time(id,Float:standardTime );
diablo_call_cast(id);

Nie wiedziałem w jakiej postaci napisać ten poradnik więc postanowiłem zrobić w postaci komentów w kodzie klasy.
Przykładowa klasa (Wersja z komentami):

Spoiler

/* Script generated by Pawn Studio */

#include <amxmodx>
#include <amxmisc>
#include <diablo_nowe.inc> /*Plik z ktorego sa wczytywane natywy i forwardy*/

#define PLUGIN "Poradnik"
#define AUTHOR "Onyke"
#define VERSION "1.0"

new bool:bKlasa[33]
public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    diablo_register_class("Nazwa klasy",120,"Opis",FLAG_ALL, "Frakcja")
    /*
    * Nazwa klasy - tutaj podajemy nazwe klasy
    * 120 - Ilosc bazowego HP
    * Opis - Tutaj podajemy opis klasy, jesli nie chcesz miec opisu to zostawiasz puste cudzyslowia
    * FLAG_ALL - Tutaj mozemy ustawic klase zeby byla premium. np ADMIN_LEVEL_H, jesli chcesz zeby klasa byla dostepna dla kazdego to zostawiasz FLAG_ALL
    * Frakcja - Do jakiej frakcji ma nalezec klasa
    *
    * Jesli chcesz zrobic klase np bez opisu, frakcji oraz nie ma byc ona premium to mozesz dodac krotsza linijke, ktora wyglada tak:
    * diablo_register_class("Nazwa Klasy",HP)
    * Jesli chcesz zrobic klase bez opisu, premium i bez frakcji to linijka ma wygladac np tak:
    * diablo_register_class("Nazwa Klasy",HP,"",ADMIN_LEVEL_H)
    */
}
public diablo_class_enabled(id){
    /* Wykonuje sie po wybraniu klasy.
    * Tutaj ustawiamy rozne zmienne oraz obowiazkowo ustawiamy bKlasa na true */
    bKlasa[id] = true;
}
public diablo_class_disabled(id){
    /* Wykonuje sie po zmienieniu klasy oraz rozlaczeniu z serwerem
    * Tutaj zerujemy rozne zmienne oraz obowiazkowo ustawiamy bKlasa na false */
    bKlasa[id] = false;
}
public diablo_clean_data(id){
    /*Czyszczenie wewnetrznych zmiennych klasy
    * Wykonuje sie przy starcie rundy, rozlaczeniu z serwerem, smierci oraz przy zmienieniu klasy*/
    diablo_reset_grav(id) /*Resetujemy grawitacje*/
    diablo_render_cancel(id) /*Resetujemy render. Mozemy tez zrobic to tak:
    * diablo_set_user_render(id,.render = kRenderTransAlpha,.amount = 255)
    * Czyli ustawic na standardowa wartosc 255*/
    diablo_reset_speed(id) /*Resetujemy predkosc*/
}
public diablo_set_data(id){
    /*Ustawianie wewnetrznych zmiennych klasy
    * Wykonuje sie po wybraniu klasy oraz przy spawnie*/
    diablo_set_user_grav(id,0.60); /*Ustawiamy grawitacje. 0.60 wynosi 480 poniewaz 60 procent z 800 (standardowa grawitacja) to wlasnie 480*/
    diablo_set_user_render(id,.render = kRenderTransAlpha,.amount = 31) /*Ustawiamy render na 31*/
    diablo_add_speed(id,24.00) /*Dodajemy 24 PKT Speeda*/
}
public diablo_death(iKiller,killerClass,iVictim,victimClass){
    /*Wykonuje sie co kazde zabojstwo
    * iKiller - ID zabojcty
    * killerClass - Klasa zabojcy[*]
    * iVictim - ID ofiary
    * victimClass - Klasa ofiary[*]
    * [*] - 0 to brak klasy, oraz o ile dobrze zauwazylem to klasa pierwsza w plugins-diablomod.ini bedzie miala 1, druga 2 itp
    * */
    if(get_user_team(iVictim) != get_user_team(iKiller)){ /*Sprawdzenie czy ofiara i zabojca sa w innych druzynach*/
        if(bKlasa[iKiller]){ /*Sprawdzenie czy mamy klase*/
            diablo_add_hp(iKiller,10) /*Odnowienie 10 HP*/
        }
    }
}
public diablo_damage_class_do(iVictim,iAttacker,&Float:fDamage){
    /*Wykonuje sie gdy ZADAJEMY obrazenia
    * iVictim - ID ofiary
    * iAttacker - ID atakujacego (nasze)
    * &Float:fDamage - obrazenia
    * */
    if(get_user_team(iVictim) != get_user_team(iAttacker)){ /*Sprawdzenie czy ofiara i atakujacy sa w innych druzynach*/
        fDamage += 10.0 /*Zadajemy dodatkowe 10 DMG*/
    }
}
public diablo_damage_class_taken(iVictim,iAttacker,&Float:fDamage){
    /*Wykonuje sie gdy OTRZYMUJEMY obrazenia
    * iVictim - ID ofiary (nasze)
    * iAttacker - ID atakujacego
    * &Float:fDamage - obrazenia
    * */
    if(get_user_team(iVictim) != get_user_team(iAttacker)){/*Sprawdzenie czy ofiara i atakujacy sa w innych druzynach*/
        fDamage -= 10.0 /*Redukujemy 10 DMG (otrzymujemy obrazenia o 10 mniejsze)*/
    }
}
public Float:diablo_cast_time(id,Float:standardTime){
    /*Tutaj ustawiamy czas ladowania na nozu
    * standardTime jest to podstawowy czas ladowania na nozu ktory standardowo wynosi: 5.0-(float(getUserInt( id ))/30.0)*/
    return standardTime * 2.0;
    /*W tym przypadku czas ladowania bedzie 2x wiekszy niz standardowy. Mozemy tez ustawic konkretny czas ladowania robiac tak:
    * return 3.0
    * Wtedy czas ladowania bedzie wynosil 3 sekundy*/
}
public diablo_call_cast(id){
    /*Wykona sie po zaladowaniu przez nas noza. Tutaj dajemy bonusy za zaladowanie*/
    diablo_add_hp( id , 100 ); /*Odnowienie 100 HP*/
    show_hudmessage(id, "Zregenerowales sobie 100 HP") /*Informacja w HUD*/
}

Przykładowa klasa (Wersja bez komentów):

Spoiler

* Script generated by Pawn Studio */

#include <amxmodx>
#include <amxmisc>
#include <diablo_nowe.inc>

#define PLUGIN "Poradnik"
#define AUTHOR "Onyke"
#define VERSION "1.0"

new bool:bKlasa[33]
public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    diablo_register_class("Nazwa klasy",120,"Opis",FLAG_ALL, "Frakcja")
}
public diablo_class_enabled(id){
    bKlasa[id] = true;
}
public diablo_class_disabled(id){
    bKlasa[id] = false;
}
public diablo_clean_data(id){
    diablo_reset_grav(id)
    diablo_render_cancel(id)
    diablo_reset_speed(id)
}
public diablo_set_data(id){
    diablo_set_user_grav(id,0.60);
    diablo_set_user_render(id,.render = kRenderTransAlpha,.amount = 31)
    diablo_add_speed(id,24.00)
}
public diablo_death(iKiller,killerClass,iVictim,victimClass){
    if(get_user_team(iVictim) != get_user_team(iKiller)){
        if(bKlasa[iKiller]){
            diablo_add_hp(iKiller,10)
        }
    }
}
public diablo_damage_class_do(iVictim,iAttacker,&Float:fDamage){
    if(bKlasa[iAttacker]){
        if(get_user_team(iVictim) != get_user_team(iAttacker)){
            fDamage += 10.0
        }
    }
}
public diablo_damage_class_taken(iVictim,iAttacker,&Float:fDamage){
    if(bKlasa[iVictim]){
        if(get_user_team(iVictim) != get_user_team(iAttacker)){
            fDamage -= 10.0
        }
    }
}
public Float:diablo_cast_time(id,Float:standardTime){
    return standardTime * 2.0;
}
public diablo_call_cast(id){
    diablo_add_hp( id , 100 );
    show_hudmessage(id, "Zregenerowales sobie 100 HP")
}

Oba przykłady klas zamieszczam także do załącznika!

Jeśli macie jakieś pytania dotyczące tworzenia klas zadawajcie je w tym temacie! (Nie pisać na PW, tam udzielam jedynie pomocy odpłatnej)

Załączone pliki

•  Wersja_Z_Komentami.sma   4,33 KB  214 Ilość pobrań
    Wersja_Z_Komentami.amxx
•  Wersja_Bez_Komentow.sma   1,41 KB  225 Ilość pobrań
    Wersja_Bez_Komentow.amxx

Użytkownik Onyke edytował ten post 09.12.2012 18:14

[sNH.]

Good

[nPaul]

Wielki + dzięki ze to zrobiłeś i to jak szybko
A jak by wyglądała klasa która DODAJE sobie 100hp na nożu ?
bo całkowicie i tak tego nie rozumiem muszę powoli całe przetrawić od podstaw.

Użytkownik Paulstudio edytował ten post 08.12.2012 23:34

[Onyke]

Wielki + dzięki ze to zrobiłeś i to jak szybko
A jak by wyglądała klasa która DODAJE sobie 100hp na nożu ?

Dodaje w sensie powiększa się jej maksymalny limit HP o 100?

[nPaul]

Tak że ma przykładowo 50hp na start laduje na nożu 100 i może mieć maksymalnie 1000.

[DarkGL]

Nie musisz sprawdzać czy gracz ma klasę w forwardach diablo_damage_class_do/taken forwardy te są wysyłane do pluginu klasy tylko jeśli przy do attacker ma klasę i przy taken jeśli ofiara ma dana klasę

[Onyke]

Tak że ma przykładowo 50hp na start laduje na nożu 100 i może mieć maksymalnie 1000.

Zrobiłem, że klasa na początku rundy ma 50 HP, jej maksymalna wartość HP to 1000, a na nożu odnawia sobie po 100HP (o coś takiego chodziło?)

Spoiler

/* Script generated by Pawn Studio */

#include <amxmodx>
#include <amxmisc>
#include <diablo_nowe.inc>

#define PLUGIN "Poradnik"
#define AUTHOR "Onyke"
#define VERSION "1.0"

new bool:bKlasa[33]
public plugin_init()
{
register_plugin(PLUGIN, VERSION, AUTHOR)
diablo_register_class("Nazwa klasy",50,"<br>Opis",FLAG_ALL, "Frakcja")
}
public diablo_class_enabled(id){
bKlasa[id] = true;
}
public diablo_class_disabled(id){
bKlasa[id] = false;
}
public diablo_clean_data(id){
diablo_reset_grav(id)
diablo_render_cancel(id)
diablo_reset_speed(id)
}
public diablo_set_data(id){
diablo_set_user_grav(id,0.60);
diablo_set_user_render(id,.render = kRenderTransAlpha,.amount = 31)
diablo_add_speed(id,24.00)
diablo_add_max_hp(id,950)
}
public diablo_death(iKiller,killerClass,iVictim,victimClass){
if(get_user_team(iVictim) != get_user_team(iKiller)){
if(bKlasa[iKiller]){
diablo_add_hp(iKiller,10)
}
}
}
public diablo_damage_class_do(iVictim,iAttacker,&Float:fDamage){
if(get_user_team(iVictim) != get_user_team(iAttacker)){
fDamage += 10.0
}
}
public diablo_damage_class_taken(iVictim,iAttacker,&Float:fDamage){
if(get_user_team(iVictim) != get_user_team(iAttacker)){
fDamage -= 10.0
}
}
public Float:diablo_cast_time(id,Float:standardTime){
return standardTime * 2.0;
}
public diablo_call_cast(id){
diablo_add_hp(id,100)
show_hudmessage(id, "Zregenerowales sobie 100 HP")
}

Załączone pliki

•  hapek.sma   1,43 KB  188 Ilość pobrań
    hapek.amxx

[Fili:P]

Szkoda że nie dałeś znać bo jak pewnie widzisz też zrobiłem poradnik Tak to byśmy zrobili razem, ale no nic

[nPaul]

Zrobiłem, że klasa na początku rundy ma 50 HP, jej maksymalna wartość HP to 1000, a na nożu odnawia sobie po 100HP (o coś takiego chodziło?)
Spoiler

tak o to mi chodziło a jak można zrobić by przykladowo hapek na 80int ladował się w ciągu 1sec potem 80++ też 1sec chodzi mi dokładniej o Maksymalne ładowanie ( prędkość ) przy 'x' Inteligencji

[DarkGL]

No i tak jeszcze dodatkowo nie musimy sobie zapisywać czy gracz ma daną klasę możemy to sprawdzać za pomocą natywu diablo_is_class_from(id);
id to id gracza
zwraca nam czy klasa gracza to klasa z tego właśnie pluginu ( true/false )

Użytkownik DarkGL edytował ten post 09.12.2012 20:47

[ChesterMu]

Witam, mozecie mi powiedziec czemu po zmianie mapy nie wyswietla panelu z klasami?, dopiero po wyjsciu i ponownym wejsciu na serwer pokazuje sie panel.