3 odpowiedzi w tym temacie

[Cycu7172]

Witam,
Mam problem z przerobieniem Klas, proszę o pomoc:

1.Snajper Weteran[Premium] - nie działa 1/2 z AWP
2.Cichy Komandos[Premium] - proszę o poprawę kodu, aby nie było go słychać jak chodzi (nie było słychać jego kroków); 1/1 z noża nie działa

Pliki .sma podaję w załącznikach.

PS: Proszę o nie usuwanie tematu, w razie błędów proszę o zmiany lub informację.

Edit: Snajper'a już ogarnąłem. Proszę o poprawę Cichego Komandos'a.

Proszę o pilną pomoc...

Załączone pliki

•  codclass_snajperweteran.sma   1,52 KB  44 Ilość pobrań
    codclass_snajperweteran.amxx
•  codclass_cichykomandos.sma   2,22 KB  40 Ilość pobrań
    codclass_cichykomandos.amxx

Użytkownik Cycu7172 edytował ten post 28.11.2011 19:58

[radim]

Trzymaj Snajpera. I mówię Ci, że 1/x z broni w generatorze na amxx.pl nie działa.

#include <amxmodx>
#include <amxmisc>
#include <codmod>
#include <engine>
#include <hamsandwich>
#include <cstrike>
#include <fun>

#define DMG_BULLET (1<<1)
		
new const nazwa[]   = "Snajper Weteran [Premium]";
new const opis[]	= "1/2 z AWP, Deagle, HE, Zmniejszona Widzialnosc";
new const bronie	= (1<<CSW_HEGRENADE)|(1<<CSW_AWP)|(1<<CSW_DEAGLE);
new const zdrowie   = 40;
new const kondycja  = 30;
new const inteligencja = 0;
new const wytrzymalosc = 0;
	
new bool:ma_klase[33];

public plugin_init()
{
	register_plugin(nazwa, "1.0", "amxx.pl");

	cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);
  
	RegisterHam(Ham_TakeDamage, "player", "TakeDamage");

}

public cod_class_enabled(id)
{
	if(!(get_user_flags(id) & ADMIN_LEVEL_H))
	{
		client_print(id, print_chat, "[Snajper Weteran [Premium]] Nie masz uprawnien, aby uzywac tej klasy.")
		return COD_STOP;
	}

	set_rendering(id,kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 150);
	give_item(id, "weapon_hegrenade");
	ma_klase[id] = true;
  
	return COD_CONTINUE;
}

public cod_class_disabled(id)
{
	set_rendering(id,kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 255);
		ma_klase[id] = false;

}

public TakeDamage(this, idinflictor, idattacker, Float:damage, damagebits)
{
	if(!is_user_connected(idattacker))
		return HAM_IGNORED;
	
	if(!ma_klase[idattacker])
		return HAM_IGNORED;
	
	if(damagebits & DMG_BULLET)
	{
		new weapon = get_user_weapon(idattacker);
			
		if(weapon == CSW_AWP && random_num(1,2) == 1)
			cod_inflict_damage(idattacker, this, float(get_user_health(this))-damage+1.0, 0.0, idinflictor, damagebits);	
	}
	
	return HAM_IGNORED;
}

Oraz CichyKomandos.

#include <amxmodx>
#include <amxmisc>
#include <codmod>
#include <engine>
#include <fun>
#include <fakemeta>
#include <hamsandwich>
#include <cstrike>

#define DMG_BULLET (1<<1)
		
new const nazwa[]   = "Cichy Komandos [Premium]";
new const opis[]	= "1/1 z Noza, Deagle, Niewidzialnosc przy kucaniu na nozu";
new const bronie	= (1<<CSW_DEAGLE);
new const zdrowie   = 40;
new const kondycja  = 40;
new const inteligencja = 0;
new const wytrzymalosc = 0;
	
new ostatnio_prawym[33];

new bool:ma_klase[33];

public plugin_init()
{
	register_plugin(nazwa, "1.0", "amxx.pl");

	cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);

	register_forward(FM_PlayerPreThink, "fwPrethink_Niewidzialnosc", 1);

	RegisterHam(Ham_TakeDamage, "player", "TakeDamage");

}

public cod_class_enabled(id)
{
	if(!(get_user_flags(id) & ADMIN_LEVEL_H))
	{
		client_print(id, print_chat, "[Cichy Komandos [Premium]] Nie masz uprawnien, aby uzywac tej klasy.")
		return COD_STOP;
	}
	set_user_footsteps(id, 1);
	ma_klase[id] = true;
  
	return COD_CONTINUE;
}

public cod_class_disabled(id)
{
	set_rendering(id,kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 255);
	set_user_footsteps(id, 0);
		ma_klase[id] = false;
}


//Przy kucaniu
public fwPrethink_Niewidzialnosc(id)
{
	if(!ma_klase[id])
		return;

	new button = get_user_button(id);
	if( button & IN_DUCK && get_user_weapon(id) == CSW_KNIFE)
	{
		set_rendering(id,kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 10);
	}
	else
	{
		set_rendering(id,kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 255);
	}
}

public TakeDamage(this, idinflictor, idattacker, Float:damage, damagebits)
{
	if(!is_user_connected(idattacker))
		return HAM_IGNORED;
	
	if(!ma_klase[idattacker])
		return HAM_IGNORED;
	
	if(damagebits & DMG_BULLET)
	{
		new weapon = get_user_weapon(idattacker);
		
		if(weapon == CSW_KNIFE && damage > 20.0)
			cod_inflict_damage(idattacker, this, float(get_user_health(this))-damage+1.0, 0.0, idinflictor, damagebits);
	}
	
	return HAM_IGNORED;
}

Użytkownik radim edytował ten post 29.11.2011 17:17

[Cycu7172]

zaraz sprawdzę i napiszę czy działa

Wszystko działa jak należy Dzięki
Temat do zamknięcia

[Goliath]

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Pomoc udzielona

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL