5 odpowiedzi w tym temacie

[Gol D. Hermes]

Witam, prosiłbym, aby ktoś podał mi link, bądź też napisał plugin:

1. Hejk nie zadaje obrażeń rzucającemu
2. Flash wybucha szybciej i mocniej razi, niż zwykły flash. ( mogą być tu cvary )

Dodam, że to jest do serwera zombie.

Pozdrawiam.

//Zakladam 2 temat, tak jak mi rozkazano

[R3X]

1.

Spoiler

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>

#define PLUGIN "Hejk nie rani ciebie"
#define VERSION "1.0"
#define AUTHOR "R3X"


public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    RegisterHam(Ham_TakeDamage, "player", "fwTakeDamage");
}

public fwTakeDamage(this, idindicator, idattacker, Float:fDamage, damagebits)
{
    if(damagebits&(1<<24)) //atak z he
    {
        if(this == idattacker)
            return HAM_SUPERCEDE;
    }
    return HAM_IGNORED;
}

2. tylko opóźnienie na cvar

mp_flashbang_delay 1.0

to 'mocniej razi' musisz doprecyzować

Spoiler

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define PLUGIN "Flash Extended"
#define VERSION "1.0"
#define AUTHOR "R3X"

new gcvarFlashDelay;

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_forward(FM_SetModel, "fwSetModel", 1);
    //register_message(get_user_msgid("ScreenFade"), "msgScreenFade");
    
    gcvarFlashDelay = register_cvar("mp_flashbang_delay", "1.0");
}

public fwSetModel(ent, const szModel[])
{
    static szClass[32];
    pev(ent, pev_classname, szClass, 31);
    
    if(equal(szClass, "grenade") && equal(szModel, "models/w_flashbang.mdl"))
    {
        new Float:fDelay = get_gametime() + get_pcvar_float(gcvarFlashDelay);
        set_pev(ent, pev_dmgtime, fDelay);
        set_pev(ent, pev_nextthink, fDelay);
    }
}

[Gol D. Hermes]

dzięki, jestes wielki, z tym 'mocniej razi' chodzi mi o to, ze dluzej trzyma, ciezej sie odwrocic od niego, wiesz, zeby przed zombie dalo rade uciec


//edit
sprawdzilem hejka, dziala elegancko tak jak chcialem

Użytkownik Gol D. Hermes edytował ten post 29.09.2011 18:57

[R3X]

2.
czas flasha można ustawić cvarem (jako mnożnik czasu)

mp_flashbang_extend 1.0

dodatkowo minimalny poziom przeźroczystości to 230

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define PLUGIN "Flash Extended"
#define VERSION "1.1"
#define AUTHOR "R3X"

new gcvarFlashDelay;
new gcvarFlashExtend;

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_forward(FM_SetModel, "fwSetModel", 1);
    register_message(get_user_msgid("ScreenFade"), "msgScreenFade");
    
    gcvarFlashDelay = register_cvar("mp_flashbang_delay", "1.0");
    gcvarFlashExtend = register_cvar("mp_flashbang_extend", "1.2");
}

public fwSetModel(ent, const szModel[])
{
    static szClass[32];
    pev(ent, pev_classname, szClass, 31);
    
    if(equal(szClass, "grenade") && equal(szModel, "models/w_flashbang.mdl"))
    {
        new Float:fDelay = get_gametime() + get_pcvar_float(gcvarFlashDelay);
        set_pev(ent, pev_dmgtime, fDelay);
        set_pev(ent, pev_nextthink, fDelay);
    }
}

public msgScreenFade(msg_type, msg_id, id)
{
    if(!is_user_connected(id))
        return PLUGIN_CONTINUE;
        

    if(get_msg_arg_int(4) == 255 &&  get_msg_arg_int(5) == 255 && get_msg_arg_int(6) == 255)
    {
        new duration = get_msg_arg_int(1);
        new holdtime = get_msg_arg_int(2);
        
        
        duration = floatround( float(duration) * get_pcvar_float(gcvarFlashExtend) );
        holdtime = floatround( float(holdtime) * get_pcvar_float(gcvarFlashExtend) );
        
        set_msg_arg_int(1, ARG_SHORT, duration);
        set_msg_arg_int(2, ARG_SHORT, holdtime);
        
        
        if(get_msg_arg_int(7) < 255)
        {
            set_msg_arg_int(7, ARG_BYTE, 230);
        }
    }
    return PLUGIN_CONTINUE;
}

[Gol D. Hermes]

dziala, dzięki wielkie, + dla Cb

[Onyke]

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Pomoc udzielona

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL