3 odpowiedzi w tym temacie

[sebul]

Witam. Czy ktoś mógłby edytować ten plugin tak, żeby w konsoli po wpisaniu amx_ip wyświetlał się także sid graczy...?

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define VERSION "1.0"
#define AUTHOR "Sn!ff3r"

#define MAX_WORD_NUM 128

new ips[MAX_WORD_NUM][10]
new len[MAX_WORD_NUM]
new num

public plugin_init() {
    register_concmd("amx_ip","ShowIP");

    new ipnum = read_wordfile();
    new pluginname[33];
    formatex(pluginname, 32, "IP (%d zakresow)", ipnum);

    register_plugin(pluginname, VERSION, AUTHOR);
} 

public read_wordfile() {
    new line, filename[] = "addons/amxmodx/configs/zmienne.ini";

    if(!file_exists(filename))
        set_fail_state("Plik z zakresami nie istnieje");

    while(num < MAX_WORD_NUM && read_file(filename, line++, ips[num], 9, len[num]))
        if(ips[num][0] != ';') num++;

    return num
}

public is_dynamic_ip(ip[]) {
    for(new x = 0; x < num; ++x)
        if(equal(ip,ips[x]))
        return true;
    return false;
}

public is_steam(auth[]) {
    if(contain(auth, "STEAM_0:0:") != -1 || contain(auth, "STEAM_0:1:") != -1)
        return true;
    return false;
}

public ShowIP(id) {
    new szIP[16], szName[33], szAuth[25], tempIP[16], tempIP1[6], tempIP2[6];
    new Players[32], pnum;

    get_players( Players , pnum , "c");
    console_print(id , "^nLista graczy:");

    for(new i = 0; i < pnum; i++) {
        get_user_ip(Players[i],szIP , 15 , 1);
        get_user_name(Players[i] , szName , 32);
        get_user_authid(Players[i], szAuth, 24);

        copy(tempIP, 15, szIP);
        while(contain(tempIP, ".") > -1)
            replace(tempIP, 15, ".", " ");

        parse(tempIP, tempIP1, 5, tempIP2, 5);
        formatex(tempIP, 9, "%s.%s", tempIP1, tempIP2);

        console_print(id , " %s - %s - %s%s", szName, is_steam(szAuth) ? "STEAM" : "NonSteam", szIP, is_dynamic_ip(tempIP) ? " - Zmienne IP" : "");
    }
    console_print(id , "^n");

    return PLUGIN_HANDLED;
}

[camilost]

console_print(id , " %s - %s - %s%s", szName, is_steam(szAuth) ? "STEAM" : "NonSteam", szIP, is_dynamic_ip(tempIP) ? " - Zmienne IP" : "");

Zamień na:

console_print(id , " %s - %s (%s) - %s%s", szName, is_steam(szAuth) ? "STEAM" : "NonSteam", szAuth, szIP, is_dynamic_ip(tempIP) ? " - Zmienne IP" : "");

Powiedz czy taki efekt chcesz : P

[sebul]

Nie wiedziałem, że to takie proste... Dzięki, dalej już sobie poradziłem, znaczy ustawiłem wygląd tej listy taki jak chciałem, aż tak tępy nie jestem Można zamknąć.

[Adminek AMXX.PL]

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Wyjaśnione

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL