7 odpowiedzi w tym temacie

[^^DeeD^^]

Jak zrobic blokadę w menu , że gracz może tylko raz wybrać opcję w menu np:
Menu broni:
AK
M4

AWP

 

wszedl w AK dostał go i przy nastepnym razie wyswietlenia komendy np /bronie to opcja AK będzie zablokowana? 

 

[Robiin]

Spoiler

#include <amxmodx>

#define AUTHOR "Wicked - amxx.pl/user/60210-wicked/"

#define ForArray(%1,%2) for(new %1 = 0; %1 < sizeof %2; %1++)

static const MenuItems[][] =
{
    "AK",
    "M4",
    "AWP",
    "USP"
};

new last_choice[33];

public plugin_init()
{
    register_plugin("x", "v0.1", AUTHOR);

    register_clcmd("say /menu", "example_menu");
}

public example_menu(index)
{
    new menu_index = menu_create("", "example_menu_handler"),
        callback = menu_makecallback("handle_item_lock");

    ForArray(i, MenuItems)
    {
        menu_additem(menu_index, MenuItems[i], _, _, callback);
    }

    menu_display(index, menu_index);

    return PLUGIN_HANDLED;
}

public example_menu_handler(index, menu_index, item)
{
    menu_destroy(menu_index);

    if(item == MENU_EXIT)
    {
        return PLUGIN_HANDLED;
    }

    client_print(index, print_chat, "Wybrales opcje %s.", MenuItems[item]);

    return PLUGIN_HANDLED;
}

public handle_item_lock(index, menu_index, item)
{
    if(item == last_choice[index])
    {
        return ITEM_DISABLED;
    }

    return ITEM_ENABLED;
} 

[^^DeeD^^]

Okej działa , a jeżeli chciałbym dodać blokowanie więcej niż jednego itemu to co muszę dodać?

[Robiin]

A na jakiej zasadzie ma blokować? Chciałeś tylko ostatni wybrany.

[^^DeeD^^]

Dobra powiedzmy jest tak

Mam glowne menu powiedzmy Menu Nagród w case 0 (item 0 czyli po nacisnieciu klawisza 1)wywoluje mi kolejne menu i tam powiedzmy jest wybierz nagrode

i w tym menu są itemy:

new blokowaniev2 = menu_makecallback("blokowaniev2")

menu_additem ( easymenu, "Nagroda 10 zabojstw", "",0, blokowaniev2)

menu_additem (easymenu, "Nagroda 20 zabojstw", "", 0, blokowaniev2)

 

i powiedzmy ze gracz wybrał "Nagroda 10 zabojstw" dostał + 10 fragów i drugi raz po prostu już nie może zdobyć tej nagrody czyli po prostu zablokować ten item

Jak zrobi inna misje to bedzie mogl wybrac "Nagroda 20 zabojstw" dostaje + 20 fragów i już jej również nie może drugi raz zdobyc ( zablokować item)

[Robiin]

Spoiler

#include <amxmodx>

#define AUTHOR "Wicked - amxx.pl/user/60210-wicked/"

#define ForArray(%1,%2) for(new %1 = 0; %1 < sizeof %2; %1++)

static const MenuItems[][] =
{
    "AK",
    "M4",
    "AWP",
    "USP"
};

new bool:user_choices[33][sizeof(MenuItems)];

public plugin_init()
{
    register_plugin("x", "v0.1", AUTHOR);

    register_clcmd("say /menu", "example_menu");
}

public example_menu(index)
{
    new menu_index = menu_create("", "example_menu_handler"),
        callback = menu_makecallback("handle_item_lock");

    ForArray(i, MenuItems)
    {
        menu_additem(menu_index, MenuItems[i], _, _, callback);
    }

    menu_display(index, menu_index);

    return PLUGIN_HANDLED;
}

public example_menu_handler(index, menu_index, item)
{
    menu_destroy(menu_index);

    if(item == MENU_EXIT)
    {
        return PLUGIN_HANDLED;
    }

    client_print(index, print_chat, "Wybrales opcje %s.", MenuItems[item]);

    user_choices[index][item] = true;

    return PLUGIN_HANDLED;
}

public handle_item_lock(index, menu_index, item)
{
    if(user_choices[index][item])
    {
        return ITEM_DISABLED;
    }

    return ITEM_ENABLED;
} 

 

Kwestia zapisu na kolejne mapy to najprostszy nvault.

[^^DeeD^^]

Poszła repka , dzięki za pomoc

Można zamknąć.

[dasiek]

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Pomoc udzielona

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL