5 odpowiedzi w tym temacie

[Mixtaz]

Mam problem, który dość ciężko mi wyjaśnić ale spróbuję jak mogę. Mam taki kod: 

#include <amxmodx>

new g_Hud;

public plugin_init(){
    register_plugin("Test Switch", "1.0.0", "mixtaz");
    register_clcmd("say /open", "cmdOpen")
    g_Hud=CreateHudSyncObj();
}
public cmdOpen(id){
    new szTime[64];
    get_time("%H:%M:%S", szTime, charsmax(szTime));
    set_hudmessage(218, 165, 32, 0.9, 0.3, 2, 1.0, 7.0, 0.0, 1.0, -1)

    switch(random(3)){
        case 0: {
            client_print(id, print_chat, "Wybrana opcja: A");
            ShowSyncHudMsg(0, g_Hud, "Opcja A - unix stamp: %i", szTime)
        }
        case 1: {
            client_print(id, print_chat, "Wybrana opcja: B");
            ShowSyncHudMsg(0, g_Hud, "Opcja B - unix stamp: %i", szTime)
        }
        case 2: {
            client_print(id, print_chat, "Wybrana opcja: C");
            ShowSyncHudMsg(0, g_Hud, "Opcja C - unix stamp: %i", szTime)
        }
    }
}

Teraz załóżmy, że 3 graczy wpisze te komende i każdy dostanie inny wynik, co się stanie? Wszystko będzie na jednej pozycji zamazane i nie będzie wiadomo o co chodzi. Teraz chciałbym, aby ten los który został wywołany jako pierwszy pojawił się na samej górze a pozostałe trochę niżej. Iście programistyczny pomysł aby postawić ^n na końcu wiadomości też na niewiele się zdał.

 

Mam nadzieję, że dobrze wyjaśniłem (?) - im nowsze tym niżej, im starsze tym wyżej, oczywiście pod warunkiem że wyświetlają się te pozostałe wiadomości.

[Rivit]

Zrób sobie zmienną która Ci trzyma pozycje huda

Spoiler

#include <amxmodx>
#include <engine>
#include <dhudmessage>

#define IsPlayer(%1) (1<=%1<=maxPlayers)

new Float: Yv[33], Float: Ya[33], maxPlayers;

public plugin_init() 
{
	register_plugin("Pokazywanie dmg", "1.0", "Rivit")
	
	register_event("Damage", "on_damage", "b", "2!0", "3=0", "4!0")

      maxPlayers = get_maxplayers()
}

public on_damage(vid)
{
	new aid = get_user_attacker(vid)
	new dmg = read_data(2)
	
      if(aid != vid)
      {
            if(get_user_team(aid) != get_user_team(vid))
            {
                  if(is_user_alive(vid))
                  {
                        set_dhudmessage(255, 0, 0, 0.44, Yv[vid], 0, _, 1.7, _, _, false)
                        show_dhudmessage(vid, "%i", dmg)
                  }
                  
                  if(is_user_alive(aid) && IsPlayer(aid))
                  {
                        set_dhudmessage(0, 100, 200, 0.54, Ya[aid], 0, _, 1.7, _, _, false)
                        show_dhudmessage(aid, "%i", dmg)
                  }
                  
                  show_damage(vid, dmg, 0)
                  CheckPosition(vid, 0)

                  if(IsPlayer(aid))
                  {
                        show_damage(aid, dmg, 1)
                        CheckPosition(aid, 1)
                  }
            }
      }
      else
      {
            set_dhudmessage(255, 110, 0, 0.5, 0.6, 0, _, 1.7, _, _, false)
            show_dhudmessage(aid, "%i", dmg)
            show_damage(vid, dmg, 2)
      }

	return PLUGIN_CONTINUE;
}

show_damage(id, dmg, attacker)
{
	static R, G, B
	static Float: Y_Pos, Float: X_Pos
	
	switch(attacker)
	{
            case 0:
            {
                  R = 255
                  G = 0
                  B = 0
                  Y_Pos = Yv[id]
                  X_Pos = 0.44
            }
            case 1:
            {
                  R = 0
                  G = 100
                  B = 200
                  Y_Pos = Ya[id]
                  X_Pos = 0.54
            }
            case 2:
            {
                  R = 255
                  G = 110
                  B = 0
                  Y_Pos = 0.6
                  X_Pos = 0.5
            }
	}
	
	new Players[32], iNum
	get_players(Players, iNum, "bch")
	
	for(new i = 0, Spectator = 0; i < iNum; i++)
	{
		Spectator = Players[i]	

		if(entity_get_int(Spectator, EV_INT_iuser2) == id)
		{
			set_dhudmessage(R, G, B, X_Pos, Y_Pos, 0, _, 1.7, _, _, false)
			show_dhudmessage(Spectator, "%i", dmg)
            }
	}
}

CheckPosition(id, attacker)
{
      switch(attacker)
      {
            case 0:
            {
                  Yv[id] += 0.04
                  
                  if(Yv[id] >= 0.75)
                        Yv[id] = 0.5
            }
            case 1:
            {
                  Ya[id] += 0.04

                  if(Ya[id] >= 0.75)
                        Ya[id] = 0.5
            }
      }
}

public client_putinserver(id)
{
      Yv[id] = 0.5
      Ya[id] = 0.5
}

 

może z tego coś wyciągniesz też:

https://amxx.pl/topi...dynamiczny-hud/

 

Chyba, że chcesz takie jakby kolejkowanie slotów czy coś, to moge machnąć to bo w sumie nie mam nic do roboty

[Mixtaz]

Okej, jest mały postęp w postaci tego, że HUD w rzeczy samej się przemieszcza w dół (czyli paradoksalne ma dodawaną wartość) co pokażę tu:

#include <amxmodx>

new g_Hud, g_ChannelSlot;

public plugin_init(){
    register_plugin("Test Switch", "1.0.0", "mixtaz");
    register_clcmd("say /open", "cmdOpen");
    g_Hud=CreateHudSyncObj();
}
public cmdOpen(id){
    new szTime[64];
    get_time("%H:%M:%S", szTime, charsmax(szTime));
   
    if (++g_ChannelSlot > 6 || g_ChannelSlot < 3)
	{
		g_ChannelSlot = 3
	}

    new Float:ypos =  0.3 + float(g_ChannelSlot) / 35.0

    set_hudmessage(218, 165, 32, -1.0, ypos, 2, 1.0, 7.0, 0.0, 1.0, -1)

    switch(random(3)){
        case 0: {
            client_print(id, print_chat, "Wybrana opcja: A");
            ShowSyncHudMsg(0, g_Hud, "Opcja A - unix stamp: %s", szTime)
        }
        case 1: {
            client_print(id, print_chat, "Wybrana opcja: B");
            ShowSyncHudMsg(0, g_Hud, "Opcja B - unix stamp: %s", szTime)
        }
        case 2: {
            client_print(id, print_chat, "Wybrana opcja: C");
            ShowSyncHudMsg(0, g_Hud, "Opcja C - unix stamp: %s", szTime)
        }
    }
    return PLUGIN_HANDLED;
}

Ale po wywołaniu kolejnej wiadomości, poprzednia natychmiast znika i trochę niżej pojawia się ta nowsza. A jak wspomniałem - chciałbym żeby wszystkie były w jednym czasie dopóki nie skończy się ich duration time (najchętniej z wykorzystaniem tylko jednego kanału hud).

[Rivit]

To może być problem tego że używasz  ShowSyncHudMsg... daj zamiast tego show_hudmessage albo przerób to na dhudmessage, bo zwykłe hud messages mają tylko 4 kanały wyświetlania

[Mixtaz]

Po zmianie z ShowSyncHudMsg na zwykły hud - wiadomość pokazywała się jak należy, czyli chronologicznie. Dzięki za pomoc.

[Mixtaz]

Usuńcie tą wiadomość please... Lag przeglądarki -.-

Użytkownik Mixtaz edytował ten post 13.09.2018 13:19