17 odpowiedzi w tym temacie

[LEMO]

Witam mam serwer codmod 

na nonsteam chat normalnie działa

ale na steam podczas pisania wyswietla się s1:s2

ten błąd występuje u wszystkich graczy na steam ponieważ dostawałem już skargi od graczy steam 

nonsteamy normalnie piszą i widzą chat

[Black004]

Temat poruszany wiele razy:

https://amxx.pl/topi...-generator-vip/

[LEMO]

Temat poruszany wiele razy:

https://amxx.pl/topi...-generator-vip/

Tak tak tak jeszcze jakieś pomysły?

Myslisz że jestem taki głupi i nic nie sprawdzałem? 

NIE DZIAŁA  

 

dodam jeszcze że na steam nie działa admin

 

Kod sma vipa:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta_util>
#include <fakemeta>
#include <fun>
#include <codmod>
#include <hamsandwich>
#include <engine>
#include <cstrike>

#define THE_VIP ADMIN_LEVEL_H

#define MONEY_F 115
new cod_vkillhp, cod_vgranaty, cod_vhsxp, cod_vhshp;

static const COLOR[] = "^x04"

new maxplayers
new gmsgSayText

/* STOKI */

stock fm_set_user_money(index, money, flash = 1)
{
	set_pdata_int(index, MONEY_F, money)
	message_begin(MSG_ONE, get_user_msgid("Money"), _, index);
	write_long(money);
	write_byte(flash ? 1 : 0);
	message_end();
}

/* END OF STOKI */

public plugin_init() 
{
	register_plugin("ProCodVIP", "1.0", "0x?");
	RegisterHam(Ham_Spawn, "player", "fwHamPlayerSpawnPost", 1);
	if( find_ent_by_class(-1, "func_bomb_target") > 0 || find_ent_by_class(-1, "info_bomb_target") > 0 )
	RegisterHam(Ham_Spawn, "player", "Ham__CBasePlayer_Spawn__Post", true)
	
	register_clcmd("say /vip","admin_motd",0,"- Shows the MOTD.")

	register_clcmd("say", "handle_say")
	gmsgSayText = get_user_msgid("SayText")

	maxplayers = get_maxplayers()

	
	/*================CVARY======================*/
	
	//VIP ma dostawac wszystkie granaty w ilosci 2 (1he, 1flash, 1smoke) 0nie 1tak
	cod_vgranaty = register_cvar("cod_vgranaty","1");
	//Dodatkowa ilosc doswiadczenia za zabicie innego gracza headshootem:
	cod_vhsxp = register_cvar("cod_vhsxp","50");
	//Dodatkowa ilosc zycia za zabicie innego gracza headshootem:
	cod_vhshp = register_cvar("cod_vhshp","20");
	//Dodatkowa ilosc zycia za zabicie innego gracza:
	cod_vkillhp = register_cvar("cod_vkillhp","15");
	
	/*==============KONIEC CVARÓW===============*/
}
public fwHamPlayerSpawnPost(id){
	
	if (is_user_connected(id) && is_user_alive(id) && get_user_flags(id) & THE_VIP) 
	{
		new granaty = get_pcvar_num(cod_vgranaty)		
		if (granaty == 1)
		{
			cod_give_weapon(id, CSW_HEGRENADE);
			cod_give_weapon(id, CSW_FLASHBANG);
			cod_give_weapon(id, CSW_FLASHBANG);
			cod_give_weapon(id, CSW_SMOKEGRENADE);
		}
	}
}
public client_death(killer, victim, wpnindex, hitplace, TK)
{ 	
	if (is_user_alive(killer) && (get_user_flags(killer) & THE_VIP))
	{
		new nr_hp = get_pcvar_num(cod_vkillhp)
		set_user_health(killer, get_user_health(killer) + nr_hp);
		if(hitplace == HIT_HEAD)
		{
			new hs_xp = get_pcvar_num(cod_vhsxp)
			new hs_hp = get_pcvar_num(cod_vhshp)
			cod_set_user_xp(killer, cod_get_user_xp(killer) + hs_xp);
			set_user_health(killer, get_user_health(killer) + hs_hp);
		}
	}	
}

public admin_motd(id,level,cid) {

	if (!cmd_access(id,level,cid,1))
	return PLUGIN_CONTINUE
	
	show_motd(id,"vip.txt",".:: Cod EvolutioN ::.")
	return PLUGIN_CONTINUE   
}

public handle_say(id)
{
	new said[192]
	read_args(said,192)
	if(( containi(said, "who") != -1 && containi(said, "admin") != -1) || contain(said, "/vips") != -1)
		set_task(0.1,"print_viplist", id)
	return PLUGIN_CONTINUE
}

public print_viplist(user) 
{
	new adminnames[33][32]
	new message[256]
	new id, count, x, len
	
	for(id = 1 ; id <= maxplayers ; id++)
		if(is_user_connected(id))
			if(get_user_flags(id) & ADMIN_LEVEL_H)
				get_user_name(id, adminnames[count++], 31)

	len = format(message, 255, "%sConnected VIPS: ",COLOR)
	if(count > 0) {
		for(x = 0 ; x < count ; x++) {
			len += format(message[len], 255-len, "%s%s ", adminnames[x], x < (count-1) ? ", ":"")
			if(len > 96 ) {
				print_message(user, message)
				len = format(message, 255, "%s ",COLOR)
			}
		}
		print_message(user, message)
	}
	else {
		len += format(message[len], 255-len, "No online VIP.")
		print_message(user, message)
	}
}

print_message(id, msg[])
{
	message_begin(MSG_ONE, gmsgSayText, {0,0,0}, id)
	write_byte(id)
	write_string(msg)
	message_end()
}

public Ham__CBasePlayer_Spawn__Post( id )
    if( is_user_alive(id) && cs_get_user_team(id) == CS_TEAM_CT && get_user_flags(id) & THE_VIP )
        cs_set_user_defuse(id, 1)

Użytkownik SulDooR edytował ten post 02.06.2018 13:26

[Ces't La Vie]

Dodaj to w plugins.ini lub w pliku konfiguracyjnym ktory odpowiada za odpalanie pluginów w taki sposob aby najpierw byla wczytywana modyfikacja vipa czyli:

 

nazwa_vipa_blabla.amxx

łatka.amxx

Załączone pliki

•  ChatFix_SteamUpdate2017.sma   1,35 KB  44 Ilość pobrań
    ChatFix_SteamUpdate2017.amxx

Użytkownik Ces't La Vie edytował ten post 02.06.2018 22:10

[LEMO]

coss to dało admin działa i na usay mozna pisac ale na say nie

[LEMO]

dobra poradziłem sobie dziękówka

[LEMO]

a jednak nie co zrobic prefixy cod.amxx wywoluja blad s1 s2 a potrzebuje ich na serwer?

[Tojaocb]

ehh 

 

z tego 

https://amxx.pl/topi...alizacji/page-2

 

dokładniej 

 

 chatpoprawka.rar   3,45 KB  53 Ilość pobrań

 

wgraj tylko ten plug powinno być oki 

[LEMO]

No niestety po tym jak dopisałem prefix_cod s1 s2 dalej występuje 

[_McHappy]

Przeanalizuj kod z tego postu https://amxx.pl/topi...ji/#entry741017(jeśli korzystasz z prefix'ów DarkGL'a - w innym wypadku, podrzuć kod tego pluginu).

[LEMO]

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <codmod>

#define PLUGIN "Prefix for COD"
#define VERSION "1.0"
#define AUTHOR "WebQ"

new pCvarPrefixy;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_message(get_user_msgid("SayText"),"handleSayText");
	
	pCvarPrefixy	=	register_cvar("cod_prefix","1");
}

public handleSayText(msgId,msgDest,msgEnt){
	new id = get_msg_arg_int(1);
	
	if(!is_user_connected(id))      return PLUGIN_CONTINUE;
	
	new szTmp[256],szTmp2[256],szTmp3[256];
	get_msg_arg_string(2,szTmp, charsmax( szTmp ) )
	
	new szPrefix[64]
	
	switch(get_pcvar_num(pCvarPrefixy)){
		case 1:{
			cod_get_class_name(cod_get_user_class(id),szTmp3,charsmax( szTmp3 ))
			formatex(szPrefix,charsmax( szPrefix ),"^x04[%s]",szTmp3);
		}
		case 2:{
			formatex(szPrefix,charsmax( szPrefix ),"^x04[%d]",cod_get_user_level(id));
		}
		case 3:{
			cod_get_class_name(cod_get_user_class(id),szTmp3,charsmax( szTmp3 ))
			formatex(szPrefix,charsmax( szPrefix ),"^x04[%s - %d]",szTmp3,cod_get_user_level(id));
		}
	}
	
	if(!equal(szTmp,"#Cstrike_Chat_All")){
		add(szTmp2,charsmax(szTmp2),szPrefix);
		add(szTmp2,charsmax(szTmp2)," ");
		add(szTmp2,charsmax(szTmp2),szTmp);
	}
	else{
		add(szTmp2,charsmax(szTmp2),szPrefix);
		add(szTmp2,charsmax(szTmp2),"^x03 %s1^x01 :  %s2");
	}
	
	set_msg_arg_string(2,szTmp2);
	
	return PLUGIN_CONTINUE;
}

Nie wiem czyje to ja to miałem w paczce.

A tamto co wysłałeś to nie rozumiem . Jak dla mnie za dużo tego

[_McHappy]

Czy plugin, o którym wspomniał kolega w tym poście jest umieszczony pod pluginem prefix'ów COD'a na liście pluginów (plugins.ini / plugins-codmod.ini) ?

Jeżeli nie - popraw to - powinno rozwiązać problem.

 

Ostatecznie, jeżeli poprzednie też zawiedzie - łap załatany kod pluginu prefixów:

Spoiler

#include <amxmodx>
#include <amxmisc>
#include <codmod>

#define PLUGIN "Prefix for COD | Prefixes fix"
#define VERSION "1.1"
#define AUTHOR "AMXX.pl"

new pCvarPrefixy;

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_message(get_user_msgid("SayText"),"handleSayText");
    
    pCvarPrefixy    =    register_cvar("cod_prefix","1");
}

public handleSayText(msgId,msgDest,msgEnt){    

    new id = get_msg_arg_int(1);
    
    if(!is_user_connected(id))      return PLUGIN_CONTINUE;
    
    new szTmp[192], szTmp2[192], szTmp3[64];
    get_msg_arg_string(2, szTmp, charsmax(szTmp));
    
    new szPrefix[64];    
    switch(get_pcvar_num(pCvarPrefixy)){
        case 1:{
            cod_get_class_name(cod_get_user_class(id),szTmp3,charsmax( szTmp3 ))
            formatex(szPrefix,charsmax( szPrefix ),"^x04[%s]",szTmp3);
        }
        case 2:{
            formatex(szPrefix,charsmax( szPrefix ),"^x04[%d]",cod_get_user_level(id));
        }
        case 3:{
            cod_get_class_name(cod_get_user_class(id),szTmp3,charsmax( szTmp3 ))
            formatex(szPrefix,charsmax( szPrefix ),"^x04[%s - %d]",szTmp3,cod_get_user_level(id));
        }
    }
    
    if(!equal(szTmp,"#Cstrike_Chat_All")){
        add(szTmp2, charsmax(szTmp2), "^x01");
        add(szTmp2, charsmax(szTmp2), szPrefix);
        add(szTmp2, charsmax(szTmp2), " ");
        add(szTmp2, charsmax(szTmp2), szTmp);
    }
    else{
        new szPlayerName[64];
        get_user_name(id, szPlayerName, charsmax(szPlayerName));
        
        get_msg_arg_string(4, szTmp, charsmax(szTmp));
        set_msg_arg_string(4, "");
    
        add(szTmp2, charsmax(szTmp2), "^x01");
        add(szTmp2, charsmax(szTmp2), szPrefix);
        add(szTmp2, charsmax(szTmp2), "^x03 ");
        add(szTmp2, charsmax(szTmp2), szPlayerName);
        add(szTmp2, charsmax(szTmp2), "^x01 :  ");
        add(szTmp2, charsmax(szTmp2), szTmp)
    }
    
    set_msg_arg_string(2, szTmp2);
    
    return PLUGIN_CONTINUE;
}

[LEMO]

działa już wszystko admin,chat itp ale dalej nie ma prefixu klasy jest tylko lvl

[_McHappy]

Sprawdź w konsoli, jaką wartość przyjmuje cvar 'cod_prefix' (powinna wynosić 3 w pożądanym przez Ciebie przypadku).

[LEMO]

jest na 2 jak to zmienić

 

[_McHappy]

Wpisz w konsoli:

cod_prefix 3

[LEMO]

robiłem już tak ale działa tylko raz po restarcie serwera ustawia sie na 2

 

[_McHappy]

Dopisz tę komendę do pliku codmod.cfg i sprawdź, czy nie ma tego wpisu w pliku amxx.cfg - jeśli jest, to go wykasuj (wystarczy, że będzie dodany do wcześniej wymienionego pliku konfiguracji cod'a).

Użytkownik _McHappy edytował ten post 09.06.2018 22:57