AMXX.pl: Support AMX Mod X i SourceMod

Witam. Mam prośbę o plugin ma działać on na zasadzie . Normalnie jest gra ale jest 5 lub 10 % ze w którejś rundzie będzie wylosowana epidemia radioaktywna czyli N.p Na czacie pisze : O nie ! Mapa jest zarażona epidemią uwaga ! i ma to działać na zasadzie kiedy jest epidemia Tracisz co 1 sec 1 hp ( fajnie by było żeby był znaczek radio aktywny ale nie musi być )
Proszę aby w next rundzie już tego nie było .
Za pomoc i próbę pomocy +

O i takie zabezpieczenie muszą być przynajmniej 2 osoby na serwerze .

Testuj sobie:

#include <amxmodx>
#include <fakemeta>

#define EPID 1698

new StatusIcon;

public plugin_init() {
	register_plugin("Epidemia", "0.1a", "byCZEK");
	
	register_event("HLTV", "event_HLTV", "a", "1=0", "2=0");
	
	StatusIcon = get_user_msgid("StatusIcon");
}

public client_disconnect(id) remove_task(EPID + id);

public event_HLTV() {
	new players[32], num, bool: runda = false;
	get_players(players, num, "a");
	
	if(num >= 2 && random_num(1, 10) == 1) runda = true;
	
	for(new i = 0; i < num; i++) {
		new id = players[i];
		
		if(runda) {
			client_print(id, print_chat, "O nie ! Mapa jest zarazona epidemia uwaga !");
			set_task(1.0, "zabierz_hp", EPID + id, _, _, "b");
		} else {
			remove_task(EPID + id);
			ikona(id, 0);
		}
	}
		
	return PLUGIN_CONTINUE;
}

public zabierz_hp(taskid) {
	new id = taskid - EPID;
	new hp = pev(id, pev_health);
	
	if(hp > 1) {
		set_pev(id, pev_health, float(hp - 1));
		ikona(id, 1);
	} else {
		remove_task(EPID + id);
		user_silentkill(id);
		ikona(id, 0);
	}
}

ikona(id, typ) {
	message_begin(MSG_ONE_UNRELIABLE, StatusIcon, _, id);
	write_byte(typ); 
	write_string("dmg_bio");
	write_byte(0);
	write_byte(255);
	write_byte(0);
	message_end();
}

Sprawdzę plusik leci za pomoc +