2 odpowiedzi w tym temacie

[loxian]

Chciałem znaleźć taki plugin który by slayował TT jak nie podlozy pak lub paka zostanie rozbrojona , lub jak CT nie uratuje hostów, ale na servie mam alt_end_round_sounds.amxx , a plugin ten:

#include <amxmodx>
#include <amxmisc>
#include <csx>

#define PLUGIN "Anti TeamPlay Slay"
#define VERSION "1.0"
#define AUTHOR "Sn!ff3r"

#define T 1
#define CT 2

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_event("SendAudio","end_round","a","2=%!MRAD_terwin","2=%!MRAD_ctwin")
}
public end_round()
{
    new audio[32]
    read_data(2,audio,31)

    if(contain(audio,"terwin") != -1)
        slay(CT)
            else slay(T)
}

public slay(team)
{
    new players[32], inum
    get_players(players,inum,"a")
    for(new i = 0; i <= inum; ++i)
        if(get_user_team(i) == team && is_user_alive(i))
    {
        user_kill(i)
        client_print(i,print_chat,"!!! Wykonuj cele mapy !!!")
        set_hudmessage(255, 0, 0, -1.0, 0.3, 0, 6.0, 5.0)
        show_hudmessage(i, "!!! Wykonuj cele mapy !!!")       
    }
}

w funkcji end_round oczytuje jaka muza została odegrana ( "terrorist łin " albo " konterterrorist łin")

a u mnie tego nei ma... i nie działa mi on...

plax przeróbka...

[R3X]

Nie wymaga cstrike ani csx, ale działa tylko z Counter Strike`iem

#include <amxmodx>

#define PLUGIN "Anti TeamPlay Slay"
#define VERSION "1.0"
#define AUTHOR "Sn!ff3r"

#define T 1
#define CT 2

new g_score[2];

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_event("TeamScore","end_round","a");
	register_event( "TextMsg", "Restore", "a", "2&#Game_will_restart_in" );
	register_event("TextMsg", "Restore", "a", "2&#Game_C")
}
public Restore()
{
	g_score[0]=0;
	g_score[1]=0;
}
public end_round()
{
	new teamname[3],score;
	read_data(1,teamname,2);
	score=read_data(2);
	if(equal(teamname,"CT"))
	{
		if(g_score[CT-1]!=score)
		{
			slay(T);
		}
		g_score[CT-1]=score;
	}
	else 
	{
		if(g_score[T-1]!=score)
		{
			slay(CT);
		}
		g_score[T-1]=score;
	}
}

public slay(team)
{
	new Players[32], playerCount;
	get_players(Players, playerCount);
	for (new i=0; i<playerCount; i++) {
		new id = Players[i]; 
		if(get_user_team(id)==team && is_user_alive(id))
		{
			user_kill(id)
			client_print(id,print_chat,"!!! Wykonuj cele mapy !!!")
			set_hudmessage(255, 0, 0, -1.0, 0.3, 0, 6.0, 5.0)
			show_hudmessage(id, "!!! Wykonuj cele mapy !!!")      
		}
	}
}

[loxian]

podaj mi swój adres a przyjde i cie uściskam !!! DZIĘKI WIELKIE!!!



//nie trzeba wystarczy dać POMÓGŁ..