AMXX.pl: Support AMX Mod X i SourceMod

Witam, szukam pluginu na jailbreaka, chodzi o to aby pod /stolice losowało kraj i pierwsza osoba która wpisze poprawną stolicę wygrywa

 

Napisz do mnie na PW, mogę ci podesłać coś co mam ale zapomniałem już jak to działało.

Trzymaj powinno działać.

Aby dodać nowy kraj dodajesz nową linijkę

new const writeCapital[ALL_CAPITAL][2][] = {
	 { "Polska", 	"Warszawa" }
	,{ "Francja", 	"Paryz" }
	,{ "Niemcy", 	"Berlin" }
};

Oraz wpisujesz liczbę ile jest krajów 

#define ALL_CAPITAL 3

Tutaj kod oraz nie zapomnij abyś sobie coś dodał za nagrodę pod linijką 72 masz funkcję. 

#include <amxmodx>
#include <amxmisc>
 
#pragma semicolon 1

new const PLUGIN[]	= 	"xyz";
new const VERSION[]	= 	"1.0";
new const AUTHOR[]	= 	"KoRrNiK - amxx.pl/user/69614-korrnik/";

enum _:capital { RANDOM_ID, bool:RANDOM_ON }
new serverCapital[capital];

#define ALL_CAPITAL 3
new const writeCapital[ALL_CAPITAL][2][] = {
	 { "Polska", 	"Warszawa" }
	,{ "Francja", 	"Paryz" }
	,{ "Niemcy", 	"Berlin" }
};	
 
public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	register_clcmd("say", "cmdSay");
}

public cmdSay(id){
	if(!is_user_connected(id)) return PLUGIN_HANDLED;
	
	new szMessage[124];
	read_args(szMessage, sizeof( szMessage ) - 1); 
	remove_quotes(szMessage);
	
	if(szMessage[0] == '/'){
		if(equal(szMessage, "/stolica")){
			functionRandomCapital(id);
			return PLUGIN_HANDLED;
		}
		return PLUGIN_CONTINUE;
	}
	
	if(serverCapital[RANDOM_ON]){	
		if(equali(szMessage, writeCapital[serverCapital[RANDOM_ID]][1])){
	
			new nameUser[33];
			get_user_name(id, nameUser, sizeof(nameUser) - 1);
			
			client_print_color(0, id, "^4[%s]^1 Pierwszy przepisal:^3 %s^1 stolice kraju:^3 %s", writeCapital[serverCapital[RANDOM_ID]][1], nameUser, writeCapital[serverCapital[RANDOM_ID]][0]);
			awardCapital(id);
			serverCapital[RANDOM_ON] = false;
			
			return PLUGIN_CONTINUE;
		}
		return PLUGIN_CONTINUE;
	}		
	return PLUGIN_HANDLED;
}

public functionRandomCapital(id){
	if(!has_flag(id, "a")) return;
	if(serverCapital[RANDOM_ON]){
		client_print_color(id, id, "^4[*]^1 Aktualnie jest wylosowana stolica:^3 %s^1 do przepisania!", writeCapital[serverCapital[RANDOM_ID]][0]);
		client_print_color(id, id, "^4[*]^1 Przepisz ja na chacie aby ponownie odpalic losowanie!");
		return;
	}
	serverCapital[RANDOM_ON] = true;
	serverCapital[RANDOM_ID] = random(ALL_CAPITAL);
	client_print_color(0, 0, "^4[*]^1 Wylosowany kraj:^3 %s^4 |^1 Jaka to stolica??", writeCapital[serverCapital[RANDOM_ID]][0]);
	client_print_color(0, 0, "^4[*]^1 Napisz na chacie jako^4 pierwszy^1 aby otrzymac nagrode!");
}

public awardCapital(id){
	/* 
	
	- TUTAJ DODAJESZ CO MA DOSTAC ZA PRZEPISANIE JAKO PIERWSZY. 
	
	*/
}

Dziękować mistrzuniu! Fajny pluginek, szkoda ze nie wyświetla się też wiadomość jaka stolica/kraj na środku u góry ekranu

Możesz to sobie łatwo zmienić za pomocą https://amxx.pl/doku...37/client_print

Kurde, powiem ci, że plugin w pewnym momencie się zorientowałem ale przez niego nie działa zwykły say(po wylaczeniu pluginu smiga), normalnie komendy dzialaja i chat tt/ct a zwykly ogolny say nie ;/

Linijka 

return PLUGIN_HANDLED;

zmień na 

return PLUGIN_CONTINUE;

dziękować, śmiga

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Pomoc udzielona

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL