3 odpowiedzi w tym temacie

[shakerek]

Plugin który umieszczę na samym dole polega na blokodzie granatów HE przez 15 sekund, czyli żaden gracz nie będzie mógł rzucić jeśli nie odczeka danego czasu. Prosił bym o lekką modyfikację tego pluginu aby również do granatów HE zablokować na 15 sekund granaty flashbang

#include <amxmodx>

#include <amxmisc>

#define PLUGIN "Nowy Plugin"

#define VERSION "1.0"

#define AUTHOR "Sn!ff3r"

new Float:gametime

public plugin_init()

{

    register_plugin(PLUGIN, VERSION, AUTHOR)

   

    register_event("CurWeapon","CurWeapon","be", "1=1", "2=4")

   

    register_logevent("Round_Start", 2, "1=Round_Start")

}

public CurWeapon(id)

{

    if(get_gametime() - gametime < 15.0)

    {

	    engclient_cmd(id, "weapon_knife")

	    client_print(id, print_center, "")

    }

}

public Round_Start()

{

    gametime = get_gametime()

   

}

Liczę na szybką pomoc pozdrawiam.

[mierzwi]

#include <amxmodx>



new Float:gametime;



public plugin_init(){

    

    register_event("CurWeapon","CurWeapon","be", "1=1")

    

    register_logevent("Round_Start", 2, "1=Round_Start")

}



public CurWeapon(id)

{

    new bron = get_user_weapon(id, _, _);

    

    if(bron == CSW_HEGRENADE || bron == CSW_FLASHBANG)

        if(get_gametime() - gametime < 15.0){

            engclient_cmd(id, "weapon_knife")

            client_print(id, print_center, "")

        }

}



public Round_Start(){

    gametime = get_gametime()

    

}

[sebul]

#include <amxmodx>



new Float:gametime;



public plugin_init(){

	register_event("CurWeapon","CurWeapon","be", "1=1")

	

	register_logevent("Round_Start", 2, "1=Round_Start")

}



public CurWeapon(id)

{

	new bron = get_user_weapon(id);

	

	if((bron == CSW_HEGRENADE || bron == CSW_FLASHBANG) && get_gametime() - gametime < 15.0)

		engclient_cmd(id, "weapon_knife")

}



public Round_Start()

	gametime = get_gametime()

[MarWit]

#include <amxmodx>
#include <hamsandwich>

new const g_szGrenadeNames[][] =
{
	"weapon_hegrenade",
	"weapon_smokegrenade",
	"weapon_flashbang"
};

new Float:g_fStartTime

public plugin_init() {
	register_plugin("Block Grenades", "0.1", "MarWit")
	register_logevent("Round_Start", 2, "1=Round_Start")

	for(new i=0; i<sizeof(g_szGrenadeNames); i++) {
		register_clcmd(g_szGrenadeNames[i], "BlockGrenade")
		RegisterHam(Ham_Weapon_PrimaryAttack, g_szGrenadeNames[i], "fwd_PrimaryAttack")
	}
}

public Round_Start()
	g_fStartTime = get_gametime()

public fwd_PrimaryAttack(this)
{
	if(get_gametime() - g_fStartTime > 15.0)
		return HAM_IGNORED

	return HAM_SUPERCEDE
}

public BlockGrenade(id)
{
	if(get_gametime() - g_fStartTime > 15.0)
		return PLUGIN_CONTINUE

	return PLUGIN_HANDLED
}

[uwaga=benio101]Ten temat został zamknięty przez moderatora.

Powód: Pomoc udzielona

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.

Z pozdrowieniami,
Zespół AMXX.PL[/uwaga]

Użytkownik benio101 edytował ten post 29.01.2013 06:44