#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <engine>
#include <cstrike>
#include <jailbreak>

#define PLUGIN "[JB] Dzieci Wojny"
#define VERSION "1.0"
#define AUTHOR "Cypis"

native cs_set_player_model(id, newmodel[]);
new id_zabawa;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	id_zabawa = jail_register_game("Kaczki");
}

public plugin_precache()
{
	precache_model("models/rpgrocket.mdl"); //wymagane do poprawnego działania set_view
	
	precache_model("models/player/kaczki/kaczki.mdl");
	precache_sound("jb_cypis/kaczki.mp3");
}

public OnLastPrisonerShowWish(id)
{
	if(OnRemoveData()){
		cs_set_player_model(id, "klawisz_cypis");
	}
}

public OnRemoveData()
{
	static day;
	day = jail_get_play_game_id();
	if(day == id_zabawa)
	{
		client_cmd(0, "mp3 stop");
		for(new i=1; i<=MAX; i++)
		{
			if(!is_user_connected(i))
				continue;
			
			set_view(i, CAMERA_NONE);
		}
		return 1;
	}
	return 0;
}

public OnDayStartPre(day, szInfo[256], szInfo2[512], setting[10], gTimeRound)
{	
	static szTime[12];
	if(day == id_zabawa)
	{
		format_time(szTime, 11, "%M:%S", gTimeRound-30);
		formatex(szInfo2, 511, "Zasady:^n%s - Wiezniowie maja czas na schownie sie^n%s - CT szuka i zabija uciekajace kaczki", szTime, szTime);
		szInfo = "Dzisiaj jest Kaczki";
		
		for(new i=1; i<=MAX; i++)
		{
			if(!is_user_connected(i) || !is_user_alive(i) || cs_get_user_team(i) != CS_TEAM_CT)
				continue;
			
			strip_user_weapons(i);
			give_item(i, "weapon_awp");
			cs_set_user_bpammo(i, CSW_AWP, 100)
		}
		
		
		jail_set_prisoners_micro(true, true);
		jail_set_ct_hit_tt(true);
		jail_set_god_ct(true);
		
		setting[0] = 1;
		setting[1] = 1;
		setting[2] = 1;
		setting[4] = 1;
		setting[7] = 2;
	}
}

public OnDayStartPost(day)
{
	if(day == id_zabawa)
	{
		jail_open_cele();
		jail_set_game_hud(30, "Rozpoczecie zabawy za");
		
		jail_set_users_speed(0.1);
	}
}

public OnGameHudEnd()
{
	static day;
	day = jail_get_play_game_id();
	if(day == id_zabawa)
	{
		jail_set_ct_hit_tt(false);
		
		jail_set_users_speed(250.0);
		client_cmd(0, "mp3 play sound/jb_cypis/kaczki.mp3");
	}
}

//stock
stock jail_set_users_speed(Float:speed)
{
	for(new i=1; i<=MAX; i++)
	{
		if(!is_user_alive(i) || !is_user_connected(i))
			continue;
		
		if(get_user_team(i) == 1)
		{
			strip_user_weapons(i);
			cs_set_player_model(i, "kaczki");
			
			set_view(i, CAMERA_3RDPERSON);
		}
		else
			jail_set_user_speed(i, speed);
	}
}