/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <codmod>
#include <fakemeta>

#define CZAS_NOCLIP 10

new const nazwa[]   = "Duch";
new const opis[]    = "Ma 10 sekund przechodzenia przez sciany :D";
new const bronie    = 1<<CSW_M4A1;
new const zdrowie   = 25;
new const kondycja  = 25;
new const inteligencja = 0;
new const wytrzymalosc = 25;

new bool:uzyl[33];

new msg_bartime;

new bool:ma_klase[33];

public plugin_init()
{
	register_plugin(nazwa, "1.0", "QTM_P.");
	
	cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);
	
	register_event("ResetHUD", "ResetHUD", "abe");
	msg_bartime = get_user_msgid("BarTime");
}

public cod_class_enabled(id)
{
	ma_klase[id] = true
	uzyl[id] = false;
}

public cod_class_disabled(id)
{
	ma_klase[id] = false
}

public cod_class_skill_used(id)
{	
	if(!is_user_alive(id))
		return PLUGIN_CONTINUE;
	
	if(uzyl[id])
	{
		client_print(id,print_center,"Mocy tej mozesz uzyc raz na runde!")
		return PLUGIN_CONTINUE;
	}
	
	set_pev(id, pev_movetype, MOVETYPE_NOCLIP);
	set_bartime(id, CZAS_NOCLIP);
	set_task(CZAS_NOCLIP.0, "WylaczNoclip", id);
	uzyl[id] = true;
	
	return PLUGIN_CONTINUE;
}

public ResetHUD(id)
	uzyl[id] = false;

public WylaczNoclip(id)
{
	if(!is_user_connected(id))
		return;
	
	set_pev(id, pev_movetype, MOVETYPE_WALK);
	
	new Float:origin[3];
	
	pev(id, pev_origin, origin);
	
	if (!is_hull_vacant(origin, pev(id, pev_flags) & FL_DUCKING ? HULL_HEAD : HULL_HUMAN, id))
		user_silentkill(id);
}

stock bool:is_hull_vacant(const Float:origin[3], hull,id) 
{
	static tr;
	engfunc(EngFunc_TraceHull, origin, origin, 0, hull, id, tr)
	if (!get_tr2(tr, TR_StartSolid) || !get_tr2(tr, TR_AllSolid))
		return true;
	
	return false;
}

public set_bartime(id, czas)
{
	message_begin(MSG_ONE, msg_bartime, _, id);
	write_short(czas);
	message_end();
}