Robiin

enum _:DAMAGE_DATA
{
    DD_GRENADE,
    DD_AWP
}

new user_damage[33][DAMAGE_DATA];

public OnDamage(victim, inflictor, attacker, Float:damage, damagebits)
{
    // Just return if team damage or attacker is not connected. 
    if(!is_user_connected(attacker) || get_user_team(attacker) == get_user_team(victim))
    {
        return HAM_IGNORED;
    }
    
    new weapon_id = get_user_weapon(attacker);
    new enum_weapon = -1;
    
    // Get custom enum id by weapon. 
    switch(weapon_id)
    {
        case CSW_AWP: enum_weapon = DD_AWP;
        case CSW_HEGRENADE:
        {
            if(damagebits & (1 << 24))
            {
                enum_weapon = DD_GRENADE;
            }
        }
    }
    
    // None of the weapons we care about.
    if(enum_weapon == -1)
    {
        return HAM_IGNORED;
    }

    // Update the damage.
    user_damage[attacker][enum_weapon] += floatround(damage);

    return HAM_IGNORED;
} 

#include <amxmodx>

#define AUTHOR "Robin - amxx.pl/user/60210-wicked/"

#define MAX_STR_LEN 25

// Nasza struktura danych.
// Nie musi być w enumie, ale tak wygląda ładniej i wygodniej się z tym pracuje.
enum _:MyStruct (+= 1)
{
    INT_VALUE,
    STR_VALUE[MAX_STR_LEN + 1]
};

new Array:array;

public plugin_init()
{
    register_plugin("", "v1.0", AUTHOR);

    // Tworzymy tablicę z naszą strukturą.
    array = ArrayCreate(MyStruct, 1);

    // Dodajemy przykładowe dane. (z posta, który napisałeś)
    add_dummy_record(array, 23, "Nazwa");
    add_dummy_record(array, 5, "Inna nazwa");
    add_dummy_record(array, 1, "costam");
    add_dummy_record(array, 7, "test");
    add_dummy_record(array, 11, "testcos");
    add_dummy_record(array, 12, "cosiktam");

    // Wypisujemy przed.
    print_array(array, "PRE");

    // Sortujemy.
    ArraySort(array, "sort_function");

    // Wypisujemy po.
    print_array(array, "POST");
}

public add_dummy_record(Array:a, int, const str[])
{
    new data[MyStruct];

    data[INT_VALUE] = int;
    copy(data[STR_VALUE], MAX_STR_LEN, str);

    ArrayPushArray(a, data);
}

public sort_function(Array:array, a, b)
{
    new data[2][MyStruct];

    ArrayGetArray(array, a, data[0]);
    ArrayGetArray(array, b, data[1]);

    // Sortujemy względem 'INT_VALUE'.
    if(data[0][INT_VALUE] > data[1][INT_VALUE]) return -1;
    if(data[0][INT_VALUE] < data[1][INT_VALUE]) return 1;

    return 0;
}

public print_array(Array:array, const prefix[])
{
    new data[MyStruct];

    for(new i = 0; i < ArraySize(array); i++)
    {
        ArrayGetArray(array, i, data);

        log_amx("%s: ^"%s^" - %i", prefix, data[STR_VALUE], data[INT_VALUE]);
    }
}  

L 05/20/2022 - 18:37:11: [arrays.amxx] PRE: "Nazwa" - 23
L 05/20/2022 - 18:37:11: [arrays.amxx] PRE: "Inna nazwa" - 5
L 05/20/2022 - 18:37:11: [arrays.amxx] PRE: "costam" - 1
L 05/20/2022 - 18:37:11: [arrays.amxx] PRE: "test" - 7
L 05/20/2022 - 18:37:11: [arrays.amxx] PRE: "testcos" - 11
L 05/20/2022 - 18:37:11: [arrays.amxx] PRE: "cosiktam" - 12

L 05/20/2022 - 18:37:11: [arrays.amxx] POST: "Nazwa" - 23
L 05/20/2022 - 18:37:11: [arrays.amxx] POST: "cosiktam" - 12
L 05/20/2022 - 18:37:11: [arrays.amxx] POST: "testcos" - 11
L 05/20/2022 - 18:37:11: [arrays.amxx] POST: "test" - 7
L 05/20/2022 - 18:37:11: [arrays.amxx] POST: "Inna nazwa" - 5
L 05/20/2022 - 18:37:11: [arrays.amxx] POST: "costam" - 1 

#include <amxmodx>

#define AUTHOR "Robin - amxx.pl/user/60210-wicked/"

public plugin_init()
{
    register_plugin("Count occurences of substring", "v1.0", AUTHOR);

    new source[50] = "AMXX";
    new searched = 'X';

    new c = count_occurences(source, searched);
  
    log_amx("Found %i occurences of ^"%c^" in ^"%s^"", c, searched, source);
}

count_occurences(const source[], needle)
{
    new count;

    for(new i = 0; i < strlen(source); i++)
    {
        if(source[i] == needle)
        {
            count++;
        }
    }

    return count;
} 

#include <amxmodx>

#define AUTHOR "Robin - amxx.pl/user/60210-wicked/"

#define MAX_MESSAGE_SIZE 32
#define DEBUG_MODE

public plugin_init()
{
    register_plugin("Hud message receiver", "v1.0", AUTHOR);
}

public plugin_natives()
{
    register_native("add_message", "handle_add_message", 0);
}

// add_message(const message[])
public handle_add_message(plugin, params)
{
    if(params != 1)
    {
        return 1;
    }

    new msg[MAX_MESSAGE_SIZE + 1];

    get_string(1, msg, charsmax(msg));

    #if defined DEBUG_MODE
        log_amx("Received message: ^"%s^"", msg);
    #endif

    return 0;
} 

#include <amxmodx>

#define AUTHOR "Robin - amxx.pl/user/60210-wicked/"

native add_message(const message[]);

public plugin_init()
{
    register_plugin("Hud message sender", "v1.0", AUTHOR);

    new hello[16] = "Hello";

    add_message(hello);
    add_message("World!");
}

#include <amxmodx>
#include <common>

#define AUTHOR "Wicked - amxx.pl/user/60210-wicked/"

#define TASK_DISPLAY_FEED 1337
#define MAX_HUD_LEN 128

static const CONFIG_PATH[] = "feed/feed.cfg";

enum _:FeedMessageEnumerator (+= 1)
{
    FM_MESSAGE[MAX_HUD_LEN],
    FM_ID
};


new Array:feed_messages[MAX_PLAYERS],

    displayed_messages,

    hud_object;

public plugin_init()
{
    register_plugin("Hud feed", "v1.0", AUTHOR);

    hud_object = CreateHudSyncObj();

    create_cvar("feed_max_len", "128");
    create_cvar("feed_max_messages", "5");
    create_cvar("feed_display_time", "2.0");
    create_cvar("feed_hold_time", "2.0");
    create_cvar("feed_refresh_rate", "1.0");

    create_cvar("feed_brightness", "0.2");
    create_cvar("feed_r", "20");
    create_cvar("feed_g", "20");
    create_cvar("feed_b", "20");

    create_cvar("feed_x", "-1.0");
    create_cvar("feed_y", "0.85");

    exec_config();

    register_clcmd("say /test_feed", "test_feed");
}

public test_feed(index)
{
    static const Chars[] = "qwertyuiopasdfghjklmnbvcxz";

    new msg[30];
    
    ForRange(i, 0, 10)
    {
        formatex(msg, charsmax(msg), "%i. ", i + 1);

        ForRange(j, 0, random_num(10, 20))
        {
            add(msg, charsmax(msg), fmt("%c", Chars[random(sizeof(Chars) - 1)]));
        }

        add_to_feed(index, msg);

        // log(LOG_DEBUG, "Adding message to user (%i) feed: %s", index, msg);
    }
}

public client_putinserver(index)
{
    if(!is_valid_player(index))
    {
        return;
    }

    feed_messages[index] = ArrayCreate(FeedMessageEnumerator, 1);
    // log(LOG_DEBUG, "Creating array of feed messages for user %i", index);
}

public client_disconnected(index)
{
    if(!is_valid_player(index) || feed_messages[index] == Invalid_Array)
    {
        return;
    }

    ArrayDestroy(feed_messages[index]);
    // log(LOG_DEBUG, "Destroying array of feed messages for user %i", index);
}

public plugin_natives()
{
    register_native("add_user_feed", "native_add_feed", 0);
}

// native add_user_feed(index, const message[]);
public native_add_feed(plugin, params)
{
    if(!valid_params(params, 2, "add_user_feed"))
    {
        return 0;
    }

    new index = get_param(1);

    if(!is_valid_player(index))
    {
        return 0;
    }

    new msg[MAX_HUD_LEN];

    get_string(1, msg, charsmax(msg));
    add_to_feed(index, msg);

    // log(LOG_DEBUG, "Adding feed message for user %i: %s", index, msg);

    return 1;
}

add_to_feed(index, const message[])
{
    if(!strlen(message) || !is_valid_player(index))
    {
        return 0;
    }

    new data[FeedMessageEnumerator],
        Float:time = get_cvar_float("feed_display_time"),
        max = get_cvar_num("feed_max_messsages"),
        size = ArraySize(feed_messages[index]);

    // If currently there are max or more messages displayed, add a delay to the new ones.
    if(size >= max)
    {
        new place = size - max + 1;
        
        time *= place; 
    }

    copy(data[FM_MESSAGE], MAX_HUD_LEN - 1, message);
    data[FM_ID] = displayed_messages++;

    // Add new message.
    ArrayPushArray(feed_messages[index], data);

    // Set task to remove the message from feed after it is displayed.
    set_task(time, "remove_from_feed", index);

    new task = TASK_DISPLAY_FEED + index;

    // Show hud if it isn't there yet.
    if(!task_exists(task))
    {
        new Float:refresh = get_cvar_float("feed_refresh_rate");

        set_task(refresh, "show_feed", task, .flags = "b");
        // log(LOG_DEBUG, "Setting up feed message task: (User: %i) (Time: %0.2f)", index, refresh);
    }

    return 1;
}

public remove_from_feed(index)
{
    if(!is_valid_player(index) || !ArraySize(feed_messages[index]))
    {
        return;
    }

    // Remove first (oldest) message.
    ArrayDeleteItem(feed_messages[index], 0);
    // log(LOG_DEBUG, "Removing oldest message from user %i", index);
}

// public remove_from_feed(data[])
// {
//     new index = data[0];

//     if(!is_valid_player(index))
//     {
//         return;
//     }

//     new id = data[1],
//         array_id = -1,
//         data[FeedMessageEnumerator];

//     ForDynamicArray(i, feed_messages[index])
//     {
//         ArrayGetArray(feed_messages[index], i, data);

//         if(data[FM_ID] == id)
//         {
//             array_id = i;
//             break;
//         }
//     }

//     if(array_id != -1)
//     {
//         ArrayDeleteItem(feed_messages[index], array_id);
//        // log(LOG_DEBUG, "Removing message of %i from feed of user %i", array_id, index);
//     }
// }

public show_feed(task)
{
    new index = task - TASK_DISPLAY_FEED;

    // No messages or players on the server.
    if(!ArraySize(feed_messages[index]) || !is_valid_player(index))
    {
        return;
    }

    new msg[MAX_HUD_LEN],
        message[MAX_HUD_LEN];

    ForDynamicArray(i, feed_messages[index])
    {
        // Limit amount of displayed messages.
        if(i >= get_cvar_num("feed_max_messages"))
        {
            break;
        }

        ArrayGetString(feed_messages[index], i, msg, charsmax(msg));

        // Format feed with oldest (first to disappear) on the bottom and newest on the top.
        format(message, charsmax(message), "%s^n%s", msg, message);
    }

    new Float:br = get_cvar_float("feed_brightness"),
        r = clamp(floatround(get_cvar_num("feed_r") * br), 0, 255),
        g = clamp(floatround(get_cvar_num("feed_g") * br), 0, 255),
        b = clamp(floatround(get_cvar_num("feed_b") * br), 0, 255),
        Float:x = get_cvar_float("feed_x"),
        Float:y = get_cvar_float("feed_y"),
        Float:refresh = get_cvar_float("feed_refresh_rate");

    // Show the feed.
    set_hudmessage(r, g, b, x, y, 0, 0.0, refresh, 0.0, 0.0);
    ShowSyncHudMsg(index, hud_object, message);
}

exec_config()
{
	new path[64];

	get_localinfo("amxx_configsdir", path, charsmax(path));

	server_cmd("exec %s/%s", path, CONFIG_PATH);
	server_exec();
}

bool:is_valid_player(index)
{
    return is_user_connected(index) && !is_user_hltv(index) && !is_user_bot(index);
} 

public sprawdz()
{
    new tt_count = ilosc_tt2();
    
    if(!tt_count)
    {
        for(new i = 1; i < MAX_PLAYERS; i++)
        {    
            if(is_user_alive(i))
            {
                user_silentkill(i);
            }
        }
        
        scrim_print(0, "^x01 Ostatni szukajacy ^x03%s^x01 opuscil gre.", terro);
 
        switch(ilosc_ct())
        {
            case 0..8: ilosc_tt = 1;
            case 9..15: ilosc_tt = 2;
            case 16..23: ilosc_tt = 3;
            case 24..32: ilosc_tt = 4;
        }
 
        drawPlayer();            
    }
}

#include <amxmodx>

#define AUTHOR "Wicked - amxx.pl/user/60210-wicked/"

#define MAX_TEAM_NAME 64
#define MAX_WEAPON_MODEL 128

enum _:WEAPON_MODEL_DATA
{
  WMD_V[MAX_WEAPON_MODEL],
  WMD_P[MAX_WEAPON_MODEL],
  WMD_W[MAX_WEAPON_MODEL]
};

enum _:BOXING_TEAM_DATA
{
  BTD_NAME[MAX_TEAM_NAME],
  BTD_GLOVES[WEAPON_MODEL_DATA]
};

new Array:boxing_teams;

public plugin_init()
{
    register_plugin("", "v1.0", AUTHOR);

    boxing_teams = initialize_teams();

    add_team("Team one", "v_model.mdl", "p_model.mdl", "w_model.mdl");
    add_team("Team two", "v_model2.mdl", "p_model2.mdl", "w_model2.mdl");
}

Array:initialize_teams()
{
    return ArrayCreate(BOXING_TEAM_DATA, 1);
}

add_team(const name[], const v[], const p[], const w[])
{
    new team[BOXING_TEAM_DATA];

    copy(team[BTD_NAME], BTD_NAME - 1, name);
    copy(team[BTD_GLOVES][WMD_V], WMD_V - 1, v);
    copy(team[BTD_GLOVES][WMD_P], WMD_P - 1, p);
    copy(team[BTD_GLOVES][WMD_W], WMD_W - 1, w);

    log_amx("Adding: Team=^"%s^" V=^"%s^" P=^"%s^" W=^"%s^"",
        team[BTD_NAME],
        team[BTD_GLOVES][WMD_V],
        team[BTD_GLOVES][WMD_P],
        team[BTD_GLOVES][WMD_W]);

    ArrayPushArray(boxing_teams, team);
}