esticire

new vault_keynum[512];
new num_keynum = fvault_get_keynum(g_vault, vault_keynum);

nie zrozumiałeś dokumentacji, 

/** 
 * Retrieves a key number specified by its name
 * 
 * @param vaultname    Vault name to look in
 * @param key        Key name to search for
 * @return        Returns key number on success, -1 on failure
 */
fvault_get_keynum(const vaultname[], const key[]) 

gdzie key[] to w naszym przypadku sid gracza i zwraca pozycje tego wpisu w pliku, do pobierania całkowitej ilości wpisów używasz 

fvault_size(const vaultname[]) 

patrząc na kod nie rozumiem po co chcesz zapisywać wszystkich do pamięci podręcznej, skoro sprawdzanie gracza w zapisie w trakcie wchodzenia nie wpływa zupełnie na wydajność

g_bStayBlocked[player] = true;
formatex(g_blocked_sids[player], charsmax(g_blocked_sids[]), "%s", sid);
formatex(g_blocked_names[player], charsmax(g_blocked_names[]), "%s", nick);

zresetować te wartości przy wychodzeniu i sprawdzać, ustawiać na wchodzeniu client_putinserver albo client_authorized

w twoim kodzie: na rozpoczęciu mapy (nawet przy zmianie mapy może nikogo wtedy nie być na serwerze, bo się z nim łączą dopiero), chcesz odczytać wszystkie wpisy z zapisu, sprawdzasz czy są gracze którzy tam widnieją, zupełnie bez sensu, masz odpowiednie eventy do takiego sprawdzania, przykłady tego co chciałeś zrobić jak byk widnieją na stronie biblioteki fvault, wystarczy poczytać

// How to find all keys within a vault:

new const vaultname[] = "myvault";

new total = fvault_size(vaultname);

new key[32], data[64];
for( new i = 0; i < total; i++ )
{
    fvault_get_keyname(vaultname, i, key, sizeof(key) - 1);
    fvault_get_data(vaultname, key, data, sizeof(data) - 1);
    
    server_print("Key: %s | Data: %s", key, data);
}


// More efficient method to find all keys within a vault:

new const vaultname[] = "myvault";

new Array:keys = ArrayCreate(64);
new Array:datas = ArrayCreate(512);

new total = fvault_load(vaultname, keys, datas);

new key[64], data[512];
for( new i = 0; i < total; i++ )
{
    ArrayGetString(keys, i, key, 31);
    ArrayGetString(datas, i, data, 511);
    
    server_print("Key: %s | Data: %s", key, data);
}

mam nadzieje że wytłumaczyłem

nie lepiej użyć biblioteki fvault? https://forums.allie...ead.php?t=76453

coś mniej więcej takiego by było, nie testowane

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <hamsandwich>
#include <fun>
#include <fvault>

#define PLUGIN "AMX Stay"
#define VERSION "1.0"
#define AUTHOR "mT[1]g"

new bool:g_bStayBlocked[33];
new Float:g_fMaxSpeed[33];
new const g_vault[] = "blocked_sids";

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR);

    register_concmd("amx_stay", "cmd_amx_stay", ADMIN_BAN, "<nick/steamid> - Zatrzymaj/odblokuj gracza");
    register_concmd("amx_stay_remove", "cmd_amx_stay_remove", ADMIN_BAN, "<SID> - Usuń SID z blokady");

    RegisterHam(Ham_Spawn, "player", "client_spawn", 1);

    register_forward(FM_CmdStart, "on_cmd_start", 1);
}

public cmd_amx_stay(id, level, cid) {
    if (!(get_user_flags(id) & ADMIN_BAN)) {
        client_print(id, print_console, "[AMX Stay] Nie masz uprawnień do użycia tej komendy.");
        return PLUGIN_HANDLED;
    }

    if (read_argc() < 2) {
        client_print(id, print_console, "[AMX Stay] UĹĽycie: amx_stay <nick/steamid>");
        return PLUGIN_HANDLED;
    }

    new arg[32];
    read_argv(1, arg, charsmax(arg));

    new target = FindTarget(arg);

    if (!target) {
        client_print(id, print_console, "[AMX Stay] Nie znaleziono gracza o nicku/SteamID: %s", arg);
        return PLUGIN_HANDLED;
    }

    if (get_user_flags(target) & ADMIN_BAN) {
        client_print(id, print_console, "[AMX Stay] Nie możesz użyć tej komendy na adminie.");
        return PLUGIN_HANDLED;
    }

    if (g_bStayBlocked[target]) {
        g_bStayBlocked[target] = false;
        set_user_maxspeed(target, g_fMaxSpeed[target]);
        new target_name[32];
        get_user_name(target, target_name, charsmax(target_name));
        client_print(id, print_console, "[AMX Stay] Odblokowano gracza %s.", target_name);
        return PLUGIN_HANDLED;
    }

    new authid[22];
    get_user_authid(target, authid, 21);
    fvault_set_data(g_vault, authid, "1");
    g_bStayBlocked[target] = true;
    g_fMaxSpeed[target] = get_user_maxspeed(target);
    set_user_maxspeed(target, 0.1);

    new target_name[32];
    get_user_name(target, target_name, charsmax(target_name));

    new message[64];
    formatex(message, charsmax(message), "[AMX Stay] Zatrzymano gracza %s.", target_name);
    client_print(id, print_console, message);

    return PLUGIN_HANDLED;
}

public client_authorized(id, const authid[]){
	if(fvault_get_keynum(g_vault, authid)!=-1){
		g_bStayBlocked[id] = true;
		g_fMaxSpeed[id] = get_user_maxspeed(id);
	}
}

public cmd_amx_stay_remove(id, level, cid) {
    if (!(get_user_flags(id) & ADMIN_BAN)) {
        client_print(id, print_console, "[AMX Stay] Nie masz uprawnień do użycia tej komendy.");
        return PLUGIN_HANDLED;
    }
 
    if (read_argc() < 2) {
        client_print(id, print_console, "[AMX Stay] Użycie: amx_stay_remove <SID>");
        return PLUGIN_HANDLED;
    }
    
    new arg[32];
    read_argv(1, arg, charsmax(arg));
    if (fvault_get_keynum(g_vault, arg)==-1) {
        client_print(id, print_console, "[AMX Stay] SID %s nie został znaleziony w blokadzie.", arg);
        return PLUGIN_HANDLED;
    }
 
    fvault_remove_key(g_vault, arg);
    client_print(id, print_console, "[AMX Stay] SID %s został usunięty z blokady.", arg);
    return PLUGIN_HANDLED;
}

public client_disconnect(id) {
    g_bStayBlocked[id] = false;
    g_fMaxSpeed[id] = 0.1;
}

public client_spawn(id) {
    if (g_bStayBlocked[id]) {
        set_user_maxspeed(id, 0.1);
    }
}

public on_cmd_start(id, uc_handle, seed) {
    if (!g_bStayBlocked[id]) {
        return FMRES_IGNORED;
    }

    set_user_maxspeed(id, 0.1);

    static uc_cmd;
    uc_cmd = get_uc(uc_handle, UC_Buttons);
    set_uc(uc_handle, UC_Buttons, uc_cmd & ~(IN_ATTACK | IN_ATTACK2 | IN_FORWARD | IN_BACK | IN_MOVELEFT | IN_MOVERIGHT | IN_JUMP | IN_USE));

    return FMRES_SUPERCEDE;
}

FindTarget(szKey[]) {
    new iTarget;

    trim(szKey);
    remove_quotes(szKey);

    if (szKey[0] == '#' && (iTarget = find_player("kh", szKey[1]))) {
        return iTarget;
    }

    if ((iTarget = find_player("bhl", szKey))) {
        return iTarget;
    }

    if ((iTarget = find_player("ch", szKey))) {
        return iTarget;
    }

    return 0;
}