17 odpowiedzi w tym temacie

[KariiO]

Jak mogę zapisać zmienne które przechowują litery (nazwa[id]) i liczby (ilosc[id]) do pliku np. depozyt.txt , a w danym momencie po prostu to odczytać ?

[DarkGL]

Dokumentacja AMXX.pl: Core >> file
i
str_to_num - odczyt liczby (kownertuje string na liczbe)
num_to_str - zapis liczby (konwertuje liczbe na string)

[KariiO]

Nie znam się na zapisywaniu różnych rzeczy do plików więc jakby co z góry sorry.

Wiec załóżmy że wcześniej utworzyłem plik tekstowy w cstrike o BAZAR i chciałbym do niego zapisać:

	new ilosc_pieniedzy[32], nazwa_gracza[32][128]
	nazwa[id] = str_to_num(nazwa_gracza);
	ilosc[id] = str_to_num(ilosc_pieniedzy);

write_file("BAZAR.txt", "Nazwa gracza: %i Ilosc pieniedzy: %s",nazwa[id],ilosc[id]);//linia 0

Czy to starczy?

[R3X]

zamiast czy starczy zapytaj czy się kompiluje, od razu podpowiadam, że nie

dane zapisywane w write_file() muszą być sformatowane wcześniej; formatex

[KariiO]

Tak to ma wyglądać czy nie ?

formatex(nazwa_gracza[0] ,sizeof(nazwa_gracza) - 1 ,Nie wiem co tutaj...)
formatex(ilosc_pieniedzy[0] ,=sizeof(ilosc_pieniedzy) - 1 ,Nie wiem co tutaj...)

[R3X]

nie tak

static szLine[64];
formatex(szLine, charsmax(63), "Nick = %s, kasa = %d", nazwa_gracza[0], str_to_num(ilosc_pieniedzy[0]));
write_file("Bazar.txt", szLine);

[KariiO]

Ok dzięki za to.

Zapiszę mi to wszystko w jednej linijce ?

I jeszcze jakbym mógł sprawdzić ile jest lini w tym pliku tekstowym (ilość linijek potrzebna mi jest do pętli w menu )

[R3X]

file_size

i ustaw dobrą flagę

flag
0 - zwraca długość w bajtach
1 - zwraca ilość linii
2 - zwraca 1, jeśli plik zakończony jest znakiem nowej linii

[KariiO]

Ok.

Czy to menu które będzie dodawało co linie jedną opcje w menu zadziała : ?

public XXX(id)
{
	if(is_user_bot(id)) return PLUGIN_CONTINUE;
	
	iSize = file_size("Bzar.txt", 1);

	new text[512]
	new menu = menu_create("Menu :","YYY")
	
	menu_setprop(menu, MPROP_EXITNAME, "Wyjdz");
	menu_setprop(menu, MPROP_BACKNAME, "Poprzednia strona");
	menu_setprop(menu, MPROP_NEXTNAME, "Nastepna strona");

	for(new i=0;i<iSize;i++)
	{   
			formatex(text, 511,"Nick: %s Ilosc: %i",nazwa[i], ilosc[i])
			menu_additem(menu,text)
	}
	menu_display(id,menu,0)
	return PLUGIN_CONTINUE;
}

public YYY(id,menu,item) 
{
	if(item == MENU_EXIT){
		menu_destroy(menu);
		return PLUGIN_CONTINUE;
	}
	switch(item) 
	{ 
	case 0: 
		{	
			Tutaj chcialbym bo to 1. linia zeby z niej odejmowalo ilosc[id] z kasy. Czyli wybieram pierwsza opcje o odejmuje mi ilosc[id] z kasy.		
		}
	case 1: 
		{	
			To samo tylko tutaj juz z drugiej lini.	
		}
	
	menu_destroy(menu);
	return PLUGIN_CONTINUE;
}

Tylko mam jeszcze wątpliwości co do tworzenia case 0 , case 1 itd...bo ja nie bd. wiedział ile ich jest wiec chyba tez bd. trzeba petle...
Wcześniej przed wyświetleniem menu bd. trzeba odczytać tez z pliku chyba ?

[R3X]

no musisz przeczytać zawartość pliku: albo read_file() aż do momentu kiedy zwróci 0, albo

new fp=fopen("Bazar.txt", "rt");

while(!feof(fp)){
    fgets(fp, szLine, 63);
}

case`y są w porządku, ale nie zamknąłeś switch{ }
wystarczy że item >= 0 i wtedy możesz użyć write_file(plik, linia, item)


Dlaczego nie użyjesz nvault?

[KariiO]

Tzn. case'y właśnie wydaję mi się że są źle bo co będzie jeżeli będą 4 opcje a case'y tylko na 3 ?
Po prostu nie bd. wiedział ile jest opcji...

A jeżeli mam nick mogę jakoś sprawdzić czy dany gracz jest na serwerze i np. ustawić mu xxx[id]=1 ?

Myślałem że z nvault więcej roboty

Użytkownik KariiO edytował ten post 07.08.2011 15:26

[R3X]

Jest funkcja od szukania graczy

new player = find_player ( "a", "KariiO") ;
if(player){
    xxx[player] = 10000;
}

[KariiO]

W public client_disconnect(id) chciałbym zrobić że jeżeli gracz się rozłącza a w Bazar.txt jest jego nick to usuwa całą linie z tym nickiem przykład:

Nazwa:przyklad1 Ilosc:przyklad1
Nazwa:przyklad2 Ilosc:przyklad2  // <- całą tą linie ma usunąć...

Wraz z enterem bo nie chciałbym takiego efektu:

Nazwa:przyklad1 Ilosc:przyklad1

[R3X]

Hmm jeżeli po wyjściu gracza tracone mają być wszystkie informacje o nim to ja się zastanawiam jaki sens ma przechowywanie ich w pliku? RAM jest o wiele szybszy i możesz zrobić zwyczajne tablice na te dane

[KariiO]

Może opiszę co to ma być:
Przykładowo mam przedmiot wystawiam go na bazar za konkretną ceną. W tym momencie przechowuję nick swój w celu wyrzucenia mi tego itemu po wylicytowaniu go przez kogoś innego na bazarze + dania mi kasy za wylicytowanie go , cenę aby wyświetlało w menu , i id przedmiotu aby po prostu dać go osobie która go wylicytowała)
Menu ma być żeby można było licytować.

[R3X]

Łatwiej to zrobić z użyciem zwykłych tablic. Jak chcesz mieć te aukcje zapisywane co mapę to serializuj je w pliku przy każdej operacji dodaj/usuń. Do serializacji możesz użyć fwrite_blocks i fread_blocks.
W ten sposób w tablicy możesz robić co chcesz,a dane będą automatycznie przenoszone na nową mapę.

Dołączam tę nieco wolniejszą, ale przystępniejszą (bo tekstową) wersję serializacji

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Test serializacji"
#define VERSION "1.0"
#define AUTHOR "R3X"

new gszDane[3][32];
new giDlugosc = 0;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	
	register_concmd("dodaj", "cmdDodaj");
	register_concmd("usun", "cmdUsun");
	register_concmd("lista", "cmdLista");
}

public cmdDodaj(id){
	if(giDlugosc >= sizeof(gszDane)){
		console_print(id, "Wiecej sie nie miesci");
		return PLUGIN_HANDLED;
	}
	read_argv(1, gszDane[giDlugosc], 31);
	console_print(id, "Dane [%s] dodane!", gszDane[giDlugosc]);
	giDlugosc++;
	
	cmdLista(id);
	return PLUGIN_HANDLED;
}
public cmdUsun(id){
	new szNum[12];
	read_argv(1, szNum, 11);
	
	new iNum = str_to_num(szNum);
	
	if(iNum >=0 && iNum <giDlugosc){
		console_print(id, "Dane [%s] usuniete!", gszDane[iNum]);
		
		for(new i=iNum, iNum = giDlugosc-1; i<iNum; i++){
			gszDane[i] = gszDane[i+1];
		}
		giDlugosc--;
	}
	
	cmdLista(id);
	return PLUGIN_HANDLED;
}
public cmdLista(id){
	console_print(id, "");
	for(new i=0;i<giDlugosc; i++)
		console_print(id, "[%d] ^"%s^"",i, gszDane[i]);
		
	return PLUGIN_HANDLED;
}

//Wczytaj
public plugin_cfg(){
	new fp = fopen("Bazar.txt", "rt");
	if(!fp)
		return;
		
	while(!feof(fp)){
		if(giDlugosc >= sizeof(gszDane)) break;
		
		if(fgets(fp, gszDane[giDlugosc], 31)){
			trim(gszDane[giDlugosc]);
			giDlugosc++;
		}
	}
	fclose(fp);
}

//Zapisz
public plugin_end(){
	new fp = fopen("Bazar.txt", "wt");
	if(!fp)
		return;
		
	for(new i=0;i<giDlugosc; i++){
		fprintf(fp, "%s^n", gszDane[i]);
	}
	fclose(fp);
}

[KariiO]

Łatwiej to zrobić z użyciem zwykłych tablic. Jak chcesz mieć te aukcje zapisywane co mapę to serializuj je w pliku przy każdej operacji dodaj/usuń. Do serializacji możesz użyć fwrite_blocks i fread_blocks.
W ten sposób w tablicy możesz robić co chcesz,a dane będą automatycznie przenoszone na nową mapę.

Dołączam tę nieco wolniejszą, ale przystępniejszą (bo tekstową) wersję serializacji

Spoiler

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Test serializacji"
#define VERSION "1.0"
#define AUTHOR "R3X"

new gszDane[3][32];
new giDlugosc = 0;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	
	register_concmd("dodaj", "cmdDodaj");
	register_concmd("usun", "cmdUsun");
	register_concmd("lista", "cmdLista");
}

public cmdDodaj(id){
	if(giDlugosc >= sizeof(gszDane)){
		console_print(id, "Wiecej sie nie miesci");
		return PLUGIN_HANDLED;
	}
	read_argv(1, gszDane[giDlugosc], 31);
	console_print(id, "Dane [%s] dodane!", gszDane[giDlugosc]);
	giDlugosc++;
	
	cmdLista(id);
	return PLUGIN_HANDLED;
}
public cmdUsun(id){
	new szNum[12];
	read_argv(1, szNum, 11);
	
	new iNum = str_to_num(szNum);
	
	if(iNum >=0 && iNum <giDlugosc){
		console_print(id, "Dane [%s] usuniete!", gszDane[iNum]);
		
		for(new i=iNum, iNum = giDlugosc-1; i<iNum; i++){
			gszDane[i] = gszDane[i+1];
		}
		giDlugosc--;
	}
	
	cmdLista(id);
	return PLUGIN_HANDLED;
}
public cmdLista(id){
	console_print(id, "");
	for(new i=0;i<giDlugosc; i++)
		console_print(id, "[%d] ^"%s^"",i, gszDane[i]);
		
	return PLUGIN_HANDLED;
}

//Wczytaj
public plugin_cfg(){
	new fp = fopen("Bazar.txt", "rt");
	if(!fp)
		return;
		
	while(!feof(fp)){
		if(giDlugosc >= sizeof(gszDane)) break;
		
		if(fgets(fp, gszDane[giDlugosc], 31)){
			trim(gszDane[giDlugosc]);
			giDlugosc++;
		}
	}
	fclose(fp);
}

//Zapisz
public plugin_end(){
	new fp = fopen("Bazar.txt", "wt");
	if(!fp)
		return;
		
	for(new i=0;i<giDlugosc; i++){
		fprintf(fp, "%s^n", gszDane[i]);
	}
	fclose(fp);
}

Dzięki wielkie , nie wiedziałem że można tak zrobić
Wielki +

Bd. miał czas zobaczę czy się w tym odnajdę

[Adminek AMXX.PL]

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Rozwiązane

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL