8 odpowiedzi w tym temacie

[Kamil.s]

Witam. poszukuje 2 pluginów do nowego cod mod. 1 to gdy gracz wpisze /daj to może oddać item wybranej osobie. Drugi to możliwość dodawanie lv graczowi przez admina.

[Milek]

możliwość dodawanie lv graczowi przez admina.

Spoiler

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <codmod>

#define PLUGIN "[COD] Admin Commands"
#define VERSION "0.97"
#define AUTHOR "QTM_Peyote"

#define ACCESS_FLAG ADMIN_RCON

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_concmd("cod_giveperk", "cmd_giveperk", ACCESS_FLAG, "<name> <perk_num> <perk_value>");
	register_concmd("cod_giveperkname", "cmd_giveperkbyname", ACCESS_FLAG, "<name> <perk_name> <perk_value>");
	register_concmd("cod_setlvl", "cmd_setlvl", ACCESS_FLAG, "<name> <ammount>");
	register_concmd("cod_givexp", "cmd_givexp", ACCESS_FLAG, "<name> <ammount>");
}

public cmd_giveperk(id, level, cid)
{
	if(!cmd_access(id, level, cid, 3))
		return PLUGIN_CONTINUE;
	
	new arg[33];
	read_argv(1, arg, 32);
	new target = cmd_target(id, arg, CMDTARGET_ALLOW_SELF);
	
	if(!is_user_connected(target))
		return PLUGIN_CONTINUE;
		
	read_argv(2, arg, 32);
	new perk = str_to_num(arg);
	read_argv(3, arg, 32);
	new perk_value = str_to_num(arg);
	
	cod_set_user_perk(target, perk, perk_value, 1);
	
	return PLUGIN_CONTINUE;
}

public cmd_giveperkbyname(id, level, cid)
{
	if(!cmd_access(id, level, cid, 3))
		return PLUGIN_CONTINUE;
	
	new arg[33];
	read_argv(1, arg, 32);
	new target = cmd_target(id, arg, CMDTARGET_ALLOW_SELF);
	
	if(!is_user_connected(target))
		return PLUGIN_CONTINUE;
		
	read_argv(2, arg, 32);
	remove_quotes(arg);
	new perk = cod_get_perkid(arg);
	read_argv(3, arg, 32);
	new perk_value = str_to_num(arg);
	
	cod_set_user_perk(target, perk, perk_value, 1);
	
	return PLUGIN_CONTINUE;
}

public cmd_setlvl(id, level, cid)
{
	if(!cmd_access(id, level, cid, 3))
		return PLUGIN_CONTINUE;
	
	new arg[33];
	read_argv(1, arg, 32);
	new target = cmd_target(id, arg, CMDTARGET_ALLOW_SELF);
	
	if(!is_user_connected(target))
		return PLUGIN_CONTINUE;
		
	read_argv(2, arg, 32);
	new level = str_to_num(arg);
	
	cod_set_user_xp(target, cod_get_level_xp(level-1));
	
	return PLUGIN_CONTINUE;
}

public cmd_givexp(id, level, cid)
{
	if(!cmd_access(id, level, cid, 3))
		return PLUGIN_CONTINUE;
	
	new arg[33];
	read_argv(1, arg, 32);
	new target = cmd_target(id, arg, CMDTARGET_ALLOW_SELF);

	if(!is_user_connected(target))
		return PLUGIN_CONTINUE;
		
	read_argv(2, arg, 32);
	new xp = str_to_num(arg);
	
	cod_set_user_xp(target, cod_get_user_xp(id)+xp);
	
	return PLUGIN_CONTINUE;
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1045\\ f0\\ fs16 \n\\ par }
*/

gdy gracz wpisze /daj to może oddać item wybranej osobie

Spoiler

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <codmod>

#define PLUGIN "Oddaj Perk"
#define VERSION "1.0"
#define AUTHOR "QTM_Peyote"

new bool:dostal_przedmiot[33];
new oddaj_id[33];

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	register_clcmd("say /oddaj", "OddajPerk");
	register_event("ResetHUD", "cod_perk_changed", "abe");
}

public OddajPerk(id)
{
	new menu = menu_create("Oddaj przedmiot", "OddajPerk_Handle");
	new cb = menu_makecallback("OddajPerk_Callback");
	for(new i=0, n=0; i<=32; i++)
	{
		if(!is_user_connected(i))
			continue;
		oddaj_id[n++] = i;
		new nazwa_gracza[64];
		get_user_name(i, nazwa_gracza, 63)
		menu_additem(menu, nazwa_gracza, "0", 0, cb);
	}
	menu_display(id, menu);
}

public cod_perk_changed(id)
	dostal_przedmiot[id] = false;

public OddajPerk_Handle(id, menu, item)
{
	if(item == MENU_EXIT)
	{
		menu_destroy(menu);
		return PLUGIN_CONTINUE;
	}
	
	if(!is_user_connected(oddaj_id[item]))
	{
		client_print(id, print_chat, "Nie odnaleziono zadanego gracza.");
		return PLUGIN_CONTINUE;
	}
	
	if(dostal_przedmiot[id])
	{
		client_print(id, print_chat, "Musisz poczekac 1 runde.");
		return PLUGIN_CONTINUE;
	}
	
	new wartosc_perku_dajacego;
	new perk_dajacego = cod_get_user_perk(id, wartosc_perku_dajacego);
	
	if(!perk_dajacego)
	{
		client_print(id, print_chat, "Nie masz zadnego perku.");
		return PLUGIN_CONTINUE;
	}
	
	new nazwa_dajacego[64];
	new nazwa_otrzymujacego[64];
	
	get_user_name(id, nazwa_dajacego, 63)
	get_user_name(oddaj_id[item], nazwa_otrzymujacego, 63)
	
	dostal_przedmiot[oddaj_id[item]] = true;
	cod_set_user_perk(oddaj_id[item], perk_dajacego, wartosc_perku_dajacego, 0);
	client_print(id, print_chat, "Przekazales perk graczowi %s.", nazwa_otrzymujacego);
	client_print(oddaj_id[item], print_chat, "Dostales perk od gracza %s.", nazwa_dajacego);
	cod_set_user_perk(id, 0);
	return PLUGIN_CONTINUE;
}

public OddajPerk_Callback(id, menu, item)
{
	if(oddaj_id[item] == id || !cod_get_user_class(oddaj_id[item]) || cod_get_user_perk(oddaj_id[item]))
		return ITEM_DISABLED;
	return ITEM_ENABLED;
}

lap

Użytkownik Milek edytował ten post 01.04.2011 15:55

[Kamil.s]

To na pewno pod nowego coda?

[Milek]

w 100%

[Kamil.s]

dawanie itemów nie działa. Trzeba jakieś moduły odblokowac czy cos?

[Milek]

nie, tylko kompilujesz i dodajesz do plugins-codmod.ini

[Kamil.s]

dodawanie lv bez problemu śmiga ale mam coś nie tak i dawanie itemów nie działa wpisuje /daj i nic się nie dzieje

[A może sma?]

Bo w pluginie jest komenda /oddaj...

Pod

register_clcmd("say /oddaj", "OddajPerk");

Dopisz

register_clcmd("say /daj", "OddajPerk");

i powinno działać na 2 komendy: /oddaj i /daj

Użytkownik kisiel96 edytował ten post 03.04.2011 09:05

[Kamil.s]

-.- ale zawaliłem

Dodano 03 kwiecień 2011 - 10:33:
Ale mi wstyd