4 odpowiedzi w tym temacie

[WitKu]

Witam serdecznie. Gdzieeeeś mi migła tak wtyczka migła przed oczami i niestety nie pamiętam gdzie Więc piszę tutaj Szukam wtyczki która za zabójstwo z noża daje HP (np. +30) i dodatkowo 2 fragi. Dziękuje za każa odpowiedź. Pozdrawiam serdecznie

[MrStrajker]

Tutaj masz dodatkowe fragi:

#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <cstrike>

#define PLUGIN "Knife Double Frags"
#define VERSION "0.3"
#define AUTHOR "Rul4"

new 
toggle,getmoney,sounds,frags;

new pun_list[][] =
{
	"%s has sliced %s^nand stole %s bucks!!!",
	"%s has given %s a taste of his cold steel!!!^n(he took %s from him)",
	"%s rules! %s bows to his mighty skills ^nand surrenders %s from his purse."
};

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	register_event("DeathMsg","hook_death","a");
	toggle = register_cvar("kdf_enabled","1");
	sounds = register_cvar("kdf_sounds","1");
	frags = register_cvar("kdf_frags","1");
	getmoney = register_cvar("kdf_stealmoney","1");
	
}

public plugin_precache()
{
	precache_sound("misc/humiliation.wav");
}

public hook_death()
{
	if(get_pcvar_num(toggle) != 1)
		return PLUGIN_HANDLED;
	new amount = 0;
	new killer = read_data(1);
	new victim = read_data(2);
	new kname[32]; get_user_name(killer,kname,31);
	new vname[32]; get_user_name(victim,vname,31);
	new weapon[24];
	new namount[32];
	read_data(4,weapon,23);
	
	if(weapon[0] == 'k' && get_user_team(killer) != get_user_team(victim))
	{
		inc_frag(killer);
		if(get_pcvar_num(getmoney) == 1)
		{
			amount = cs_get_user_money(victim)*random(5)/4;
			stealmoney(victim, killer, amount);
		}
		num_to_str(amount, namount, 32);
		
		set_hudmessage(255, 127, 42, 0.5, -1.0, 0, 6.0, 7.0);
		show_hudmessage(0,pun_list[random(sizeof pun_list)],kname,vname,namount);
		if(bsounds(sounds)) client_cmd(0,"spk misc/humiliation");
	}

	return PLUGIN_HANDLED;
}

inc_frag(index)
{
	if(!is_user_connected(index)) return;	
	set_user_frags(index,get_user_frags(index)+get_pcvar_num(frags));
}

stealmoney(victim, killer, amount)
{
	if(!is_user_connected(victim) || !is_user_connected(killer)) return;
	cs_set_user_money(killer,cs_get_user_money(killer)+amount);
	cs_set_user_money(victim,cs_get_user_money(victim)-amount);
}

bool: bsounds(pcvar)
{
	if(get_pcvar_num(pcvar) == 1)
		return true;
	return false;
}

A tutaj życie:

#include <amxmodx>
#include <fun>
#include <cstrike>


public plugin_init() {
        register_event("DeathMsg", "DeathMsg", "a");
}
public DeathMsg(){
        new iKiller = read_data(1);
        new iVictim = read_data(2);
        
        if(cs_get_user_team(iVictim) == cs_get_user_team(iKiller))
        {
                return PLUGIN_HANDLED
        }
        if(is_user_alive(iKiller))
        {
                set_user_health(iKiller, min( 100, get_user_health(iKiller) + 20) )
        }
}

[Boski Z Polski]

#include <amxmodx>
#include <amxmisc>
#include <fun>

#define PLUGIN "Zabicie z noza"
#define VERSION "1.0.0"
#define AUTHOR "Boski Z Polski"

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	register_event("DeathMsg", "DeathMsg", "a");
}

public DeathMsg()
{
	new kid = read_data(1);
	
	if(is_user_alive(kid) && get_user_weapon(kid) == CSW_KNIFE)
	{
		set_user_frags(kid, get_user_frags(kid) + 1);
		set_user_health(kid, get_user_health(kid) + 30);
	}
}

[WitKu]

Boski Z Polski, mogłem się spodziewać że ty odpiszesz. Oczywiście plugin którego sukałem to ten i działa ładnie ) Dziękuje za pomoc. Można zamknąć. + leci

[dasiek]

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Pomoc udzielona

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL