5 odpowiedzi w tym temacie

[Black004]

Napisałem taki kod, oczywiście patrzyłem jak inne pluginy są napisane w SQL, wyszło mi takie coś:

 

Spoiler

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>
#include <sqlx>
#include <cstrike>
#include <fun>
#include <colorchat>


new Handle:info, bool:connected;

new nazwa_gracza[33];

enum CVARS
{ 
	host, 
	user, 
	pass, 
	db
};

new g_pCvars[CVARS];

new liczba[33];

public plugin_init() 
{
	register_plugin("TEST", "0.2", "Bl@ck");
	
	g_pCvars[host] = register_cvar("host_sql", 	"xxx");
	g_pCvars[user] = register_cvar("user_sql", 	"xxx", FCVAR_PROTECTED);
	g_pCvars[pass] = register_cvar("password_sql", 	"xxx", FCVAR_PROTECTED);
	g_pCvars[db]   = register_cvar("database_sql",   	"xxx");
	
	register_clcmd("say /test", "test");
	register_clcmd("say /ile", "sprawdz");
}

public plugin_end() SQL_FreeHandle(info);

public test(id) liczba[id]++
public sprawdz(id) 	ColorChat(id, GREEN, "POSIADASZ %d PUNKTOW", liczba[id]);

public plugin_cfg() 
{	
	new szHost[64], szUser[64], szPass[64], szDB[64];
	get_pcvar_string(g_pCvars[host], szHost, charsmax(szHost));
	get_pcvar_string(g_pCvars[user], szUser, charsmax(szUser));
	get_pcvar_string(g_pCvars[pass], szPass, charsmax(szPass));
	get_pcvar_string(g_pCvars[db],   szDB,   charsmax(szDB));
	info = SQL_MakeDbTuple(szHost, szUser, szPass, szDB); 

	new len_full, temp_full[2024]; 
	len_full += formatex(temp_full[len_full], charsmax(temp_full)-len_full, "CREATE TABLE IF NOT EXISTS `TESTOWE` (`name` VARCHAR(48), `liczba` INT(10))");  
	SQL_ThreadQuery(info, "ConnectSql_Handler", temp_full);
}

public ConnectSql_Handler(failstate, Handle:query, error[], errnum, data[], size)
{
	if(failstate != TQUERY_SUCCESS)
	{
		connected = false;
		return PLUGIN_CONTINUE;
	}
	connected = true;
	return PLUGIN_CONTINUE;
}

public client_putinserver(id)
{
	get_user_name(id, nazwa_gracza, 32)
	resetData(id);
	readData(id);
}
public client_disconnect(id)
{
	saveData(id);
	resetData(id);
}

public resetData(id)
{
	liczba[id] = 0
}

public saveData(id)
{
	if(!connected || !is_user_connected(id) || is_user_bot(id) || is_user_hltv(id) || !module_exists("MySQL"))
		return PLUGIN_CONTINUE;

	new len_full, temp_full[2048];

	mysql_escape_string(nazwa_gracza, charsmax(nazwa_gracza));

	len_full += formatex(temp_full[len_full], charsmax(temp_full)-len_full, "UPDATE `TESTOWE` SET `liczba` = '%d' WHERE `name` = '%s'", liczba[id], nazwa_gracza);

	SQL_ThreadQuery(info, "saveDataHandler", temp_full);
	return PLUGIN_CONTINUE;
}

public saveDataHandler(failstate, Handle:query, error[], errnum, data[], size)
{
	if(failstate != TQUERY_SUCCESS)
	{
		return PLUGIN_CONTINUE;
	}
	return PLUGIN_CONTINUE;
}

public readData(id)
{
	if(!connected || !is_user_connected(id) || is_user_bot(id) || is_user_hltv(id) || !module_exists("MySQL"))
		return PLUGIN_CONTINUE;

	new data[1], temp[2048], name[33];
	data[0] = id;

	mysql_escape_string(name, charsmax(name));

	formatex(temp, charsmax(temp), "SELECT * FROM `TESTOWE` WHERE `name` = '%s'", nazwa_gracza);
	SQL_ThreadQuery(info, "readDataHandler", temp, data, sizeof(data));
	return PLUGIN_CONTINUE;
}

public readDataHandler(failstate, Handle:query, error[], errnum, data[], size)
{
	new id = data[0];

	if(failstate != TQUERY_SUCCESS)
	{
		return PLUGIN_CONTINUE;
	}

	if(SQL_MoreResults(query))
	{
		liczba[id] = SQL_ReadResult(query, SQL_FieldNameToNum(query,"liczba"))

	}
	else
	{
		new data[1];
		data[0] = id;

		if(!connected || !is_user_connected(id) || is_user_bot(id) || is_user_hltv(id) || !module_exists("MySQL"))
			return PLUGIN_CONTINUE;

		new temp[2048];
		mysql_escape_string(nazwa_gracza, charsmax(nazwa_gracza));

		format(temp, charsmax(temp), "INSERT INTO `TESTOWE` (name, liczba) VALUES ('%s', '0')", nazwa_gracza); 
		SQL_ThreadQuery(info, "readDataHandler2", temp, data, sizeof(data));
		return PLUGIN_CONTINUE;
	}
	return PLUGIN_CONTINUE;
}
public readDataHandler2(failstate, Handle:query, error[], errnum, data[], size)
{
	if(failstate != TQUERY_SUCCESS)
	{
		log_amx("Wczytywanie dla %s blad %s", nazwa_gracza, error);
		return PLUGIN_CONTINUE;
	}
	return PLUGIN_CONTINUE;
}

stock mysql_escape_string(output[], len)
{
	static const szReplaceIn[][] = { "\\", "\0", "\n", "\r", "\x1a", "'", "^"" };
	static const szReplaceOut[][] = { "\\\\", "\\0", "\\n", "\\r", "\Z", "\'", "\^"" };
	for(new i; i < sizeof szReplaceIn; i++)
		replace_all(output, len, szReplaceIn[i], szReplaceOut[i]);
}

 

Kod ku mojemu zdziwieniu działa, ale czy dałoby się go jakoś go lepiej napisać? Czega mam unikać w robieniu zapisu sql?

 

Czy da się to:

liczba[id] = SQL_ReadResult(query, SQL_FieldNameToNum(query,"liczba"))

Odczytać to jakoś inaczej? W innych pluginach inaczej czasami to się robi w inny sposób. Dobry jest to sposób?

 

Ostanie pytanie, czy da się jakoś bardziej usprawnić ten zapis?

 

Jeszcze jedno, jak zapisać stringa w sql i go odczytać?

Użytkownik Black004 edytował ten post 31.07.2019 18:50

[Robiin]

Jeszcze jedno, jak zapisać stringa w sql i go odczytać?

 

Przecież już zapisujesz - nick. 

// Tworzenie tabeli:
CREATE TABLE IF NOT EXISTS `tableName` (`userName` VARCHAR(33), `someValue` INT(10), `someOtherValue` VARCHAR(33));

// Insertowanie wartości:
INSERT INTO `tableName` (userName, someValue, someOtherValue) VALUES ('abcd', '0', 'efgh');

// Pobieranie wartości:
SELECT * FROM `tableName` WHERE `userName` = 'abcd';

// Aktualizowanie wartości:
UPDATE `tableName` SET `someValue` = '1' WHERE `userName` = 'abcd'; 

Wszystkie zapytania powinny kończyć się średnikiem. Zapytania w kodzie możesz rozbijać na sekcje wieloliniowe poprzez użycie backslasha (\) na końcu linii (niektóre edytory tekstu mogą wywalać błąd, że string nie został zakończony [bo edytor nie znajdzie " na końcu linijki], ale tym się nie przejmuj). Robisz to tak:

format(mysqlRequest, charsmax(mysqlRequest),
						"INSERT INTO `tableName`\
						(userName, someValue, someOtherValue)\
						VALUES ('abcd', '0', 'efgh'");

Możesz odczytywać konkretne wartości zamiast wszystkich:

Odczyt wszystkich rekordów względem wartości 'someValue' jeśli jest >= 0:

SELECT * FROM `tableName` WHERE `someValue` >= '0';

Odczyt konkretej wartości rekordów, których wartość someOtheValue jest równa "efgh":

SELECT `userName` FROM `tableName` WHERE `someOtherValue` = 'efgh';

Ważna jest ta funkcja i to, żebyś wiedział co tak naprawdę robi:

stock mysql_escape_string(output[], len)
{
	static const szReplaceIn[][] = { "\\", "\0", "\n", "\r", "\x1a", "'", "^"" };
	static const szReplaceOut[][] = { "\\\\", "\\0", "\\n", "\\r", "\Z", "\'", "\^"" };
	for(new i; i < sizeof szReplaceIn; i++)
		replace_all(output, len, szReplaceIn[i], szReplaceOut[i]);
}

Jest to zabezpieczenie przed mysql injection.

 

 

Usprawnienie tworzenia tabeli:

CREATE TABLE IF NOT EXISTS `tableNane`
(
    `userName` VARCHAR(33) NOT NULL PRIMARY KEY ,
    `someValue` INT(10) NOT NULL UNSIGNED,
    `someOtherValue` VARCHAR(33) NOT NULL
);

Spoiler

NOT NULL - Each row must contain a value for that column, null values are not allowed
DEFAULT value - Set a default value that is added when no other value is passed
UNSIGNED - Used for number types, limits the stored data to positive numbers and zero
AUTO INCREMENT - MySQL automatically increases the value of the field by 1 each time a new record is added
PRIMARY KEY - Used to uniquely identify the rows in a table. The column with PRIMARY KEY setting is often an ID number, and is often used with AUTO_INCREMENT

Użytkownik aSiorr edytował ten post 31.07.2019 19:57

[Rivit]

mysql_escape_string - tu uważaj, wczoraj poprawiałem błąd takiemu typowi, tu jest to samo.

Chodzi o to, że tam przekazujesz tablice (zawierającą nick) i robisz na niej replace. Replace zamieniające jakiś znak(i) na znak(i) których jest więcej. W takim razie tablica z nickiem powinna być większa! Myśle, że 64 na nick w takim przypadku wystarczy

 

___

!module_exists("MySQL")

zbędne

_____

 

w saveData masz sprawdzanie is_user_connected - generalnie ja bym nie sprawdzał, jak wychodzi no to nie bedzie polaczony (jakies dziwne przypadki mialem z tym)

w readData też bym nie sprawdzał is_user_connected

 

______

	len_full += formatex(temp_full[len_full], charsmax(temp_full)-len_full, "UPDATE `TESTOWE` SET `liczba` = '%d' WHERE `name` = '%s'", liczba[id], nazwa_gracza);

ten formatex też dziwnie robisz, po co Ci to len_full tam?

znaczy jest ok, ale nie wiem po co taki zabieg

 

______

public readDataHandler(failstate, Handle:query, error[], errnum, data[], size)
{
	new id = data[0];

	if(failstate != TQUERY_SUCCESS)
	{
		return PLUGIN_CONTINUE;
	}

tu zawsze fajnie jest sobie error wypisac.  

log_amx(error)

Tu widze ze readDataHandler2 uzyles tego, wiec ok

 

____

		if(!connected || !is_user_connected(id) || is_user_bot(id) || is_user_hltv(id) || !module_exists("MySQL"))
			return PLUGIN_CONTINUE;

drugi raz sprawdzasz to w handlerze od query readDataHandler - w zasadzie to nie ma po co, mozna by sprawdzic tylko czy gracz polączony

 

____

 

edit:

jeszcze nie musisz miec zmiennej connected, mozesz sprawdzac tak:

	if( gSqlTuple == Empty_Handle ) //to znaczy ze sie nie powiodlo łączenie

wypadaloby sprawdzac po uzyciu SQL_MakeDbTuple

 

 

_____

liczba[id] = SQL_ReadResult(query, SQL_FieldNameToNum(query,"liczba"))

generalnie jako drugi parametr mozesz podać numer kolumny, ale nie polecam, używaj tak jak teraz. Jak do bazy bedziesz dodawac kolumny itp to nie bedzie trzeba zmieniac wczytywania

[Toldi]

Ja robię tak i mi działa

 

Zapis

formatex(equip, charsmax(equip), "UPDATE `skins_for_coins` SET `skinid(0-50)`='%s', `skinid(51-100)`='%s', `currentmodel`='%s' WHERE `nick`='%s' ", skins[0], skins[1], currentmodels, PlayerName[id]);

Tablice skins[0]/[1], currentmodels przechowują string.

 

 

Odczyt

SQL_ReadResult(Query, SQL_FieldNameToNum(Query,"skinid(0-50)"), skins[0], charsmax(skins[]) )
SQL_ReadResult(Query, SQL_FieldNameToNum(Query,"skinid(51-100)"), skins[1], charsmax(skins[]) )
SQL_ReadResult(Query, SQL_FieldNameToNum(Query,"currentmodel"), currentmodels, charsmax(currentmodels) )

Z kolumny o nazwie skinid(0-50) wkłada stringa do tablicy skins[0], która jest tworzona w funkcji nie globalnie bo identyczna tablica istnieje już w zapisie, która też jest tworzona w tym że publicu.

[Black004]

Dzięki wszystkim za odpowiedź Teraz w sumie jakby ktoś jeszcze pytał o sql to można jak najbardziej go tu odsyłać, wszystko wyjaśnione. Jeszcze raz dzięki!

[dasiek]

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Pomoc udzielona

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL