Skocz do zawartości

Witamy w Nieoficjalnym polskim support'cie AMX Mod X

Witamy w Nieoficjalnym polskim support'cie AMX Mod X, jak w większości społeczności internetowych musisz się zarejestrować aby móc odpowiadać lub zakładać nowe tematy, ale nie bój się to jest prosty proces w którym wymagamy minimalnych informacji.
  • Rozpoczynaj nowe tematy i odpowiedaj na inne
  • Zapisz się do tematów i for, aby otrzymywać automatyczne uaktualnienia
  • Dodawaj wydarzenia do kalendarza społecznościowego
  • Stwórz swój własny profil i zdobywaj nowych znajomych
  • Zdobywaj nowe doświadczenia

Dołączona grafika Dołączona grafika
Guest Message by DevFuse
 

Zdjęcie

[SZUKAM] Prefixy dla graczy TOP3

Temat rozp. NacpanyKsiaze, 16.07.2017 14:39

  • Nie możesz napisać tematu
  • Zaloguj się, aby dodać odpowiedź
2 odpowiedzi w tym temacie

#1 NacpanyKsiaze

    Zaawansowany

  • Użytkownik

Reputacja: 27
Życzliwy

  • Postów:118
  • GG:
  • Imię:Szymon
  • Lokalizacja:Świętno
Offline

Napisano 16.07.2017 14:39

Witam,

Pamiętam że kiedyś widziałem na jakimś serwerze plugin który graczom z TOP3 dodawał prefix na czacie, np:

 

[TOP 1] NICK

[TOP 2] NICK

[TOP 3] NICK

 

Czy wie ktoś może czy jest takowy plugin dostępny w internecie do pobrania czy też będzie trzeba samemu napisać?

 

Pozdrawiam,

Szymek.


  • +
  • -
  • 0

#2 heniu1111

    Ja zjadłem ciastko ^^

  • Power User

Reputacja: 149
Zaawansowany

  • Postów:568
  • GG:
  • Imię:heniu
  • Lokalizacja:zapomniałem
Offline

Napisano 16.07.2017 16:45

Znalazłem coś na rosyjskim ale to do edycji i tłumaczenia :/ spróbuje go edytować albo napisać na nowo ale nie obiecuje. Łap tutaj sma

#include <amxmodx>
#include <csstats>

//#define CT_SUPPORT	// uncomment for enable colored translit support

#define PLUGIN "Top SayPrefix"
#define VERSION "0.3"
#define AUTHOR "serfreeman1337"

#define TOP_RANK	5

#define TOP_PREFIX	"^1[^4TOP Đгрок^1]"
#define T_TAG		"(Terrorist)"
#define CT_TAG		"(CT)"
#define SPEC_TAG	"(Spectator)"
#define DEAD_TAG	"*DEAD*"

#if !defined CT_SUPPORT
	new Trie:g_ChatOpts
	new g_maxplayers
	
	new msgHolder[191],msgLastId,Float:msgLastTime,bool:notRankedYet
#else
	#include <colored_translit>
#endif

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	#if !defined CT_SUPPORT
		register_message(get_user_msgid("SayText"),"Msg_SayText")
		
		g_ChatOpts = TrieCreate()
		
		TrieSetCell(g_ChatOpts,"#Cstrike_Chat_All",1)
		TrieSetCell(g_ChatOpts,"#Cstrike_Chat_T",2)
		TrieSetCell(g_ChatOpts,"#Cstrike_Chat_CT",3)
		TrieSetCell(g_ChatOpts,"#Cstrike_Chat_AllDead",4)
		TrieSetCell(g_ChatOpts,"#Cstrike_Chat_T_Dead",5)
		TrieSetCell(g_ChatOpts,"#Cstrike_Chat_CT_Dead",6)
		TrieSetCell(g_ChatOpts,"#Cstrike_Chat_AllSpec",7)
		
		g_maxplayers = get_maxplayers()
	#endif
}

#if !defined CT_SUPPORT
public Msg_SayText(MsgID,MsgDEST,MsgPLAYER){
	if(MsgDEST != MSG_ONE)
		return PLUGIN_CONTINUE
	
	new id = get_msg_arg_int(1)
	
	if(!id || id > g_maxplayers)
		return PLUGIN_CONTINUE
		
	new paramsCount = get_msg_args()
	
	// ďđîâĺđ˙ĺě ęĺř
	if(msgLastId == id && msgLastTime == get_gametime()){
		if(notRankedYet)	// čăđîę áĺç ňĺăŕ
			return PLUGIN_CONTINUE
		
		// ńîîáůĺíčĺ čç ęĺřŕ
		set_msg_arg_string(2,msgHolder)
		
		// ŕçŕçŕçŕ
		if(paramsCount == 4)
			set_msg_arg_string(4,"")
			
		return PLUGIN_CONTINUE
	}
	
	new st[8]
	new rank = get_user_stats(id,st,st)

	// ďđîâĺđ˙ĺě íŕ ŇÎĎ
	if(rank > TOP_RANK){ // čăđîę íĺ ňîď čăđîę
		// çŕďčńűâŕĺě äŕííűĺ â ęĺř
		notRankedYet = true
		
		msgLastId = id
		msgLastTime = get_gametime()
		
		return PLUGIN_CONTINUE
	}else // čăđîę ŇÎĎ, ńáđŕńűâŕĺě óęŕçŕňĺëü
		notRankedYet = false
	
	new name[32]
	get_user_name(id,name,31)
	
	new chatIndefer[191],sayText[191],chatPointer
	get_msg_arg_string(2,chatIndefer,190)
	get_msg_arg_string(4,sayText,190)
	
	TrieGetCell(g_ChatOpts,chatIndefer,chatPointer)
	
	
	new buff[192],len
	
	len += formatex(buff[len],191-len,TOP_PREFIX)
	
	if(chatPointer && paramsCount == 4){	// ńňŕíäŕđňíîĺ ńîîáůĺíčĺ äâčćęŕ
		switch(chatPointer){
			case 1:{
				len += formatex(buff[len],191-len," ^3%s^1",name)
			}
			case 2:{
				len += formatex(buff[len],191-len," %s ^3%s^1",T_TAG,name)
			}
			case 3:{
				len += formatex(buff[len],191-len," %s ^3%s^1",CT_TAG,name)
			}
			case 4:{
				len += formatex(buff[len],191-len," %s ^3%s^1",DEAD_TAG,name)
			}
			case 5:{
				len += formatex(buff[len],191-len," %s%s ^3%s^1",DEAD_TAG,T_TAG,name)
			}
			case 6:{
				len += formatex(buff[len],191-len," %s%s ^3%s^1",DEAD_TAG,CT_TAG,name)
			}
			case 7:{
				len += formatex(buff[len],191-len," %s ^3%s^1",SPEC_TAG,name)
			}
			default: return PLUGIN_CONTINUE
		}
		
		len += formatex(buff[len],191-len," : %s",sayText)
	}else{	// ńîîáůĺíčĺ, čçěĺíĺííîĺ äđóăčě ďëŕăčíîě
		len += formatex(buff[len],191-len," %s",chatIndefer)
	}
	
	set_msg_arg_string(2,buff)
	
	if(paramsCount == 4)
		set_msg_arg_string(4,"")
	
	// ńîőđŕí˙ĺě íŕřĺ ńîîáůĺíčĺ â ęĺř
	if(msgLastId != id || msgLastTime != get_gametime()){
		msgLastId = id
		msgLastTime = get_gametime()
		
		copy(msgHolder,190,buff)
	}
	
	return PLUGIN_CONTINUE
}
#else
public ct_message_format(id){
	new st[8]
	
	if(get_user_stats(id,st,st) <= TOP_RANK)
		ct_add_to_msg(CT_MSGPOS_PREFIX,TOP_PREFIX)
}
#endif

  • +
  • -
  • 1

Zawsze służę pomocą, pomogę na tyle ile jestem wstanie  :)

 

Poradnik do instalacji AmxBans: https://www.youtube....h?v=fYq5iKQhVIM

 

Link do lekkiej "modyfikacji" AmxBans: https://amxx.pl/topi...ndpost&p=733955

 

#3 NacpanyKsiaze

    Zaawansowany

  • Autor tematu
  • Użytkownik

Reputacja: 27
Życzliwy

  • Postów:118
  • GG:
  • Imię:Szymon
  • Lokalizacja:Świętno
Offline

Napisano 16.07.2017 18:17

Mam coś takiego co osobiście bardziej mi się podoba

#include <amxmodx>
#include <csstats>

#define PLUGIN "Top SayPrefix"
#define VERSION "0.4"
#define AUTHOR "serfreeman1337"

#define TOP_RANK	3  // Primii X jucatorii care vor primi Prefixul in chat
#define TOP_PREFIX	"^1[^4TOP-#rank#^1]" // Prefixul. #rank# - Pozitia jucatorului in top

new g_maxplayers
new msgHolder[191],msgLastId,Float:msgLastTime,bool:notRankedYet


public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_message(get_user_msgid("SayText"),"Msg_SayText")
	g_maxplayers = get_maxplayers()
}

public Msg_SayText(MsgID,MsgDEST,MsgPLAYER){
	if(MsgDEST != MSG_ONE)
		return PLUGIN_CONTINUE
	
	new id = get_msg_arg_int(1)
	
	if(!id || id > g_maxplayers)
		return PLUGIN_CONTINUE
		
	if(msgLastId == id && msgLastTime == get_gametime()){
		if(notRankedYet)
			return PLUGIN_CONTINUE
		
		set_msg_arg_string(2,msgHolder)
			
		return PLUGIN_CONTINUE
	}
	
	new st[8]
	new rank = get_user_stats(id,st,st)
	
	new str_rank[8]
	num_to_str(rank,str_rank,7)

	if(rank > TOP_RANK){
		notRankedYet = true
		
		msgLastId = id
		msgLastTime = get_gametime()
		
		return PLUGIN_CONTINUE
	}else
		notRankedYet = false
		
	new formatedMsg[191],chatMsg[191],contentMsg[191]
	get_msg_arg_string(2,chatMsg,190)
	get_msg_arg_string(4,contentMsg,190)
	
	if(!strcmp(chatMsg,"#Cstrike_Chat_All")){
		formatex(formatedMsg,190,"%s ^3%%s1^1 :  %%s2",TOP_PREFIX)
	}else
		formatex(formatedMsg,190,"%s %s",TOP_PREFIX,chatMsg)
		
	replace_all(formatedMsg,190,"#rank#",str_rank)

	if(strlen(formatedMsg) + strlen(contentMsg) >= 189){	
		new contentLen = (strlen(formatedMsg) + strlen(contentMsg)) - 188
		contentLen = strlen(contentMsg) - contentLen
		
		if(((contentMsg[contentLen - 1] & 0xFF) >= 0xC2) && ((contentMsg[contentLen - 1] & 0xFF) <= 0xEF))
			contentLen-- 
		
		contentMsg[contentLen] = 0
		set_msg_arg_string(4,contentMsg)
	}
	
	set_msg_arg_string(2,formatedMsg)

	msgLastId = id
	msgLastTime = get_gametime()
		
	copy(msgHolder,190,formatedMsg)
	
	return PLUGIN_CONTINUE
}

Tylko nie wiem jak to dopasować do łatki VALVE co do prefixów ;x

https://amxx.pl/topi...alizacji/page-2


Użytkownik NacpanyKsiaze edytował ten post 16.07.2017 18:19

  • +
  • -
  • 0
Wróć do Szukam pluginu


Użytkownicy przeglądający ten temat: 0

0 użytkowników, 0 gości, 0 anonimowych

Coinsy CSGOPolygon Za SMS, PSC , Przelew - CoinSell.pro
Skiny do CS:GO za SMS, PSC, Przelew - CSGOPaka.com
Automatyczny Bot Levelowania Steam - LVLUPSteam.com
CSGO Gambling Sites and Free Betting Codes - DreamCodes.gg
  1. AMXX.pl: Support AMX Mod X i SourceMod
  2. → AMX Mod X
  3. → Szukam pluginu
  4. Regulamin