3 odpowiedzi w tym temacie

[Dermi97]

(SuperP) Dermi

1/5 z famasa na nozu w ogóle go nie widać i trzy miny

Bron: famas

Flaga  ADMIN_LEVEL_G

[NEQU#]

https://amxx.pl/generator-klas/

[Dermi97]

https://amxx.pl/generator-klas/

1/5 Z FAamas a nie z wszystkich broni tak jak jest w generatorze

[NEQU#]

#include <amxmodx>
#include <amxmisc>
#include <codmod>
#include <engine>
#include <hamsandwich>

#define DMG_BULLET (1<<1)
        
new const nazwa[]   = "(SuperP) Dermi";
new const opis[]    = "1/5 z famasa na nozu w ogóle go nie widać i trzy miny";
new const bronie    = (1<<CSW_FAMAS)|(1<<CSW_USP);
new const zdrowie   = 0;
new const kondycja  = 0;
new const inteligencja = 0;
new const wytrzymalosc = 0;
    
new const modelMiny[] = "models/QTM_CodMod/mine.mdl"

new sprite_blast_miny;
new ilosc_min_gracza[33];

new ma_klase[33];

public plugin_init()
{
	register_plugin(nazwa, "1.0", "amxx.pl");

	cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);

	register_event("CurWeapon", "eventKnife_Niewidzialnosc", "be", "1=1");

	register_touch("mine", "player",  "DotykMiny");

	register_event("HLTV", "NowaRunda_Miny", "a", "1=0", "2=0");

	RegisterHam(Ham_Spawn, "player", "fwSpawn_Miny", 1);

	RegisterHam(Ham_TakeDamage, "player", "TakeDamage");

}

public plugin_precache()
{

	precache_model(modelMiny);
	sprite_blast_miny = precache_model("sprites/dexplo.spr");

}

public client_disconnect(id)
{

	new entMiny = find_ent_by_class(0, "mine");
	while(entMiny > 0)
	{
		if(entity_get_edict(entMiny, EV_ENT_owner) == id)
			remove_entity(entMiny);
		entMiny = find_ent_by_class(entMiny, "mine");
	}

}

public cod_class_enabled(id)
{
	if(!(get_user_flags(id) & ADMIN_LEVEL_G))
	{
		client_print(id, print_chat, "[(SuperP) Dermi] Nie masz uprawnien, aby uzywac tej klasy.")
		return COD_STOP;
	}

	ilosc_min_gracza[id] = 3;
	ma_klase[id] = true;
   
	return COD_CONTINUE;
}

public cod_class_disabled(id)
{
	set_rendering(id,kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 255);
    	ma_klase[id] = false;

}

public cod_class_skill_used(id)
{
        
	if (!ilosc_min_gracza[id])
	{
		client_print(id, print_center, "Wykorzystales juz wszystkie miny!");
	}
	else
	{

		ilosc_min_gracza[id]--;

		new Float:origin[3];
		entity_get_vector(id, EV_VEC_origin, origin);

		new ent = create_entity("info_target");
		entity_set_string(ent ,EV_SZ_classname, "mine");
		entity_set_edict(ent ,EV_ENT_owner, id);
		entity_set_int(ent, EV_INT_movetype, MOVETYPE_TOSS);
		entity_set_origin(ent, origin);
		entity_set_int(ent, EV_INT_solid, SOLID_BBOX);

		entity_set_model(ent, modelMiny);
		entity_set_size(ent,Float:{-16.0,-16.0,0.0},Float:{16.0,16.0,2.0});

		drop_to_floor(ent);

		set_rendering(ent,kRenderFxNone, 0,0,0, kRenderTransTexture,50);
	}
}

public eventKnife_Niewidzialnosc(id)
{
	if(!ma_klase[id])
		return;

	if( read_data(2) == CSW_KNIFE )
	{
		set_rendering(id,kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 15);
	}
	else
	{
		set_rendering(id,kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 255);
	}
}

public fwSpawn_Miny(id)
{
	if(is_user_alive(id))
		ilosc_min_gracza[id] = 3;
}

public DotykMiny(ent, id)
{
	if(!is_valid_ent(ent))
		return;

	new attacker = entity_get_edict(ent, EV_ENT_owner);
	if (get_user_team(attacker) != get_user_team(id))
	{
		new Float:fOrigin[3];
		entity_get_vector( ent, EV_VEC_origin, fOrigin);

		new iOrigin[3];
		for(new i=0;i<3;i++)
			iOrigin[i] = floatround(fOrigin[i]);

		message_begin(MSG_BROADCAST,SVC_TEMPENTITY, iOrigin);
		write_byte(TE_EXPLOSION);
		write_coord(iOrigin[0]);
		write_coord(iOrigin[1]);
		write_coord(iOrigin[2]);
		write_short(sprite_blast_miny);
		write_byte(32);
		write_byte(20);
		write_byte(0);
		message_end();

		new entlist[33];
		new numfound = find_sphere_class(ent,"player", 90.0 ,entlist, 32);

		for (new i=0; i < numfound; i++)
		{
			new pid = entlist[i];

			if (!is_user_alive(pid) || get_user_team(attacker) == get_user_team(pid))
				continue;

			cod_inflict_damage(attacker, pid, 70.0, 0.8, ent, (1<<24));
		}
		remove_entity(ent);
	}
}

public NowaRunda_Miny()
{
	new entMiny = find_ent_by_class(-1, "mine");
	while(entMiny > 0)
	{
		remove_entity(entMiny);
		entMiny = find_ent_by_class(entMiny, "mine");
	}
}

public TakeDamage(this, idinflictor, idattacker, Float:damage, damagebits)
{
	if(!is_user_connected(idattacker))
		return HAM_IGNORED;
	
	if(!ma_klase[idattacker])
		return HAM_IGNORED;
	
	if(get_user_team(this) == get_user_team(idattacker))
		return HAM_IGNORED;
		
	if(get_user_weapon(idattacker) != CSW_FAMAS)
		return HAM_IGNORED;
	
	if(!(damagebits & DMG_BULLET))
		return HAM_IGNORED;
		
	if(random(5) != 1)
		return HAM_IGNORED;
		
	cod_inflict_damage(idattacker, this, float(get_user_health(this))-damage+1.0, 0.0, idinflictor, damagebits);
		
	return HAM_IGNORED;
}