1 odpowiedź w tym temacie

[Ceesik]

Witam czy ktoś by mógłby mnie nakierować jak przerobić vipa z generatora tak by można było zrobic z niego plugin w którym flaga jest sprawdzana co chwile tak aby działał nocny vip. 

[Skull.]

Dodaj sprawdzanie do spawn (odrodzenia)
Przykład:

Spoiler

#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <fun>
#include <hamsandwich>

forward amxbans_admin_connect(id);

new bool:g_Vip[33], skoki[33];

public plugin_init(){
	register_plugin("VIP Ultimate", "12.3.0.2", "benio101 & speedkill");
	register_forward(FM_CmdStart, "CmdStartPre");
	RegisterHam(Ham_Spawn, "player", "SpawnedEventPre", 1);
    register_message(get_user_msgid("SayText"),"handleSayText");
}
public client_authorized(id){
	if(get_user_flags(id) & 524288 == 524288){
		client_authorized_vip(id);
	}
}
public client_authorized_vip(id){
	g_Vip[id]=true;
}
public client_disconnect(id){
	if(g_Vip[id]){
		client_disconnect_vip(id);
	}
}
public client_disconnect_vip(id){
	g_Vip[id]=false;
}
public CmdStartPre(id, uc_handle){
	if(g_Vip[id]){
		if(is_user_alive(id)){
			CmdStartPreVip(id, uc_handle);
		}
	}
}
public CmdStartPreVip(id, uc_handle){
	new flags = pev(id, pev_flags);
	if((get_uc(uc_handle, UC_Buttons) & IN_JUMP) && !(flags & FL_ONGROUND) && !(pev(id, pev_oldbuttons) & IN_JUMP) && skoki[id]>0){
		--skoki[id];
		new Float:velocity[3];
		pev(id, pev_velocity,velocity);
		velocity[2] = random_float(265.0,285.0);
		set_pev(id,pev_velocity,velocity);
	} else if(flags & FL_ONGROUND && skoki[id]!=-1){
		skoki[id] = 2;
	}
}
public SpawnedEventPre(id){
	if(get_user_flags(id) & 524288 == 524288){
		g_Vip[id]=true;
	}
	if(g_Vip[id]){
		if(is_user_alive(id)){
			SpawnedEventPreVip(id);
		}
	}
}
public SpawnedEventPreVip(id){
	skoki[id]=2;
	set_user_health(id, get_user_health(id)+20);
	new henum=(user_has_weapon(id,CSW_HEGRENADE)?cs_get_user_bpammo(id,CSW_HEGRENADE):0);
	give_item(id, "weapon_hegrenade");
	++henum;
	new fbnum=(user_has_weapon(id,CSW_FLASHBANG)?cs_get_user_bpammo(id,CSW_FLASHBANG):0);
	give_item(id, "weapon_flashbang");
	++fbnum;
	cs_set_user_bpammo(id, CSW_FLASHBANG, 2);
	new sgnum=(user_has_weapon(id,CSW_SMOKEGRENADE)?cs_get_user_bpammo(id,CSW_SMOKEGRENADE):0);
	give_item(id, "weapon_smokegrenade");
	++sgnum;
}

public handleSayText(msgId,msgDest,msgEnt){
    new id = get_msg_arg_int(1);
 
    if(is_user_connected(id) && g_Vip[id]){
        new szTmp[256],szTmp2[256];
        get_msg_arg_string(2,szTmp, charsmax(szTmp))
 
        new szPrefix[64] = "^x04[VIP]";
 
        if(!equal(szTmp,"#Cstrike_Chat_All")){
            add(szTmp2,charsmax(szTmp2),szPrefix);
            add(szTmp2,charsmax(szTmp2)," ");
            add(szTmp2,charsmax(szTmp2),szTmp);
        }
    else{
        add(szTmp2,charsmax(szTmp2),szPrefix);
        add(szTmp2,charsmax(szTmp2),"^x03 %s1^x01 :  %s2");
    }
    set_msg_arg_string(2,szTmp2);
}
public amxbans_admin_connect(id)
{
client_authorized(id);
}

Aczkolwiek jest to sposób na szybko, tak zwaną łatwiznę, będzie raczej działać, aczkolwiek nie zbyt dobrze jest tak.
Najlepiej to jest zoptymalizować vipa, i bezpośrednio dodać sprawdzanie vipa.
Przykład:

Spoiler

#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <fun>
#include <hamsandwich>

new skoki[33];

public plugin_init()
{
	register_plugin("VIP Ultimate", "12.3.0.2", "benio101 & speedkill & Skull");
	
	register_forward(FM_CmdStart, "CmdStartPre");
	
	RegisterHam(Ham_Spawn, "player", "SpawnedEventPre", 1);
	
	register_message(get_user_msgid("SayText"),"handleSayText");
}

public CmdStartPre(id, uc_handle)
{
	if(get_user_flags(id) & ADMIN_LEVEL_H)
	{
		new flags = pev(id, pev_flags);
		
		if((get_uc(uc_handle, UC_Buttons) & IN_JUMP) && !(flags & FL_ONGROUND) && !(pev(id, pev_oldbuttons) & IN_JUMP) && skoki[id]>0){
			--skoki[id];
			
			new Float:velocity[3];
			pev(id, pev_velocity,velocity);
			velocity[2] = random_float(265.0,285.0);
			set_pev(id,pev_velocity,velocity);
		}
		else if(flags & FL_ONGROUND && skoki[id]!=-1)
		{
			skoki[id] = 2;
		}
	}
}

public SpawnedEventPre(id)
{
	if(get_user_flags(id) & ADMIN_LEVEL_H)
	{
		skoki[id]=2;
		set_user_health(id, get_user_health(id)+20);
		
		new henum=(user_has_weapon(id,CSW_HEGRENADE)?cs_get_user_bpammo(id,CSW_HEGRENADE):0);
		give_item(id, "weapon_hegrenade");
		++henum;
		
		new fbnum=(user_has_weapon(id,CSW_FLASHBANG)?cs_get_user_bpammo(id,CSW_FLASHBANG):0);
		give_item(id, "weapon_flashbang");
		++fbnum;
		cs_set_user_bpammo(id, CSW_FLASHBANG, 2);
		
		new sgnum=(user_has_weapon(id,CSW_SMOKEGRENADE)?cs_get_user_bpammo(id,CSW_SMOKEGRENADE):0);
		give_item(id, "weapon_smokegrenade");
		++sgnum;
	}
}

public handleSayText(msgId,msgDest,msgEnt)
{
	new id = get_msg_arg_int(1);
	
	if(is_user_connected(id) && get_user_flags(id) & ADMIN_LEVEL_H)
	{
		new szTmp[256],szTmp2[256];
		get_msg_arg_string(2,szTmp, charsmax(szTmp))
		
		new szPrefix[64] = "^x04[VIP]";
		
		if(!equal(szTmp,"#Cstrike_Chat_All"))
		{
			add(szTmp2,charsmax(szTmp2),szPrefix);
			add(szTmp2,charsmax(szTmp2)," ");
			add(szTmp2,charsmax(szTmp2),szTmp);
		}
		else
		{
			add(szTmp2,charsmax(szTmp2),szPrefix);
			add(szTmp2,charsmax(szTmp2),"^x03 %s1^x01 :  %s2");
		}
		set_msg_arg_string(2,szTmp2);
	}
	return PLUGIN_CONTINUE;
}

Użytkownik Mr.Skull edytował ten post 14.01.2017 17:40