5 odpowiedzi w tym temacie

[emblaze]

Witam.
Mam taką prośbe/pytanie Jak podmienić model granata "W" (world) ale z warunkiem if ?
Bo szczeze mówiąc nie wiem w ogóle jak to zrobić ;> A jeśli się da to jeszcze tak:
- Jeśli u atakującego (tego co rzuca) zmienna bool (na id) jest równa np. true to wtedy ten jego granat wygląda inaczej, a jeśli ta zmienna u atakującego jest równa np. false to ma wyglądać normalnie ;>
Rozumiecie coś z tego ? Jeśli tak to proszę o pomoc Jeśli się nie da to cóż trudno, ale zapytać można
A tak przy okazji (po co zakładać drugi temat, nawet nie wiem w jakim dziale ) Czy w folderze valve jest model klucza francuskiego (tzn do HL) bo tak mi sie kojazy, że był, ale nie moge go znaleźć Jeśli jest to o jakiej nazwie ?

[Vertricus]

public W_Model_Hook(ent,model[])
{
	if(!pev_valid(ent))
	{
		return FMRES_IGNORED
	}
	static i
	for(i=0;i<w_modelsnum;i++)
	{
		if(equali(model,old_w_models[i]))
		{
			engfunc(EngFunc_SetModel,ent,new_w_models[i])
			return FMRES_SUPERCEDE
		}
	}
	return FMRES_IGNORED
}

Zmień for(i=0;i
if(equali(model,nazwa modelu chyba)
engfunc(EngFunc_SetModel,ent,nazwa new modelu)
GHW

Edit:
jeszcze chyba to:

public newround()
{
	static ent, classname[8], model[32]
	ent = engfunc(EngFunc_FindEntityInSphere,maxplayers,Float:{0.0,0.0,0.0},4800.0)
	while(ent)
	{
		pev(ent,pev_classname,classname,7)
		if(containi(classname,"armoury")!=-1)
		{
			pev(ent,pev_model,model,31)
			W_Model_Hook(ent,model)
		}
		ent = engfunc(EngFunc_FindEntityInSphere,ent,Float:{0.0,0.0,0.0},4800.0)
	}
}

[emblaze]

Vertricus, dużo z tego wiem Właśnie patrzyłem do GHW replace, i nie jestem pewien jak to zrobić A w ogóle register_event nie podałes Potrzebowałbym to z troche z lepszą instrukcją + Gdzie dodać if'a

[mgr inż. Pavulon]

Właśnie patrzyłem do GHW replace, i nie jestem pewien jak to zrobić

register_forward(FM_SetModel,"W_Model_Hook",1)

public W_Model_Hook(ent,model[])
{
	if(!pev_valid(ent))
	{
		return FMRES_IGNORED
	}
	static i
	for(i=0;i<w_modelsnum;i++)
	{
		if(equali(model,old_w_models[i]))
		{
			engfunc(EngFunc_SetModel,ent,new_w_models[i])
			return FMRES_SUPERCEDE
		}
	}
	return FMRES_IGNORED
}

To właśnie z GHW Weapon Replacement'a

[mgr inż. Pavulon]

A tu przykładowy plugin:

#include <amxmodx>
#include <fakemeta>

new const stary_model[] = "models/w_flashbang.mdl"
new const nowy_model[] = "models/w_knife.mdl"
new bool:moze_model[33]

public plugin_init() {
	register_plugin("Zmiana modelu", "0.1", "AMXX")
	
	register_clcmd("say /mozemodel", "say_mozemodel")
	
	register_forward(FM_SetModel, "W_Model_Hook", 1)
}

public client_connect(id)
	moze_model[id] = false

public say_mozemodel(id)
{
	moze_model[id] = true
	return PLUGIN_HANDLED
}

public W_Model_Hook(ent,model[])
{
	if(!pev_valid(ent))
	{
		return FMRES_IGNORED
	}
	
	new id = pev(ent,pev_owner)
	
	if (moze_model[id] && equali(model, stary_model))
	{
		engfunc(EngFunc_SetModel, ent, nowy_model)
		return FMRES_SUPERCEDE
	}
	
	return FMRES_IGNORED
}

public plugin_precache()
{
	precache_model(nowy_model)
}

Po wpisaniu w say "/mozemodel" rzuca się nożem zamiast FB

[emblaze]

lol działa ! Myślałem, że to tak nie odpali
Dzięki temu znowu więcej zdziałam w moim modzie
Dzięki Leci pomógł
A ten model tego klucza francuskiego ?