3 odpowiedzi w tym temacie

[v139]

Cześć, napisałem taki plugin:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <fun>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "Bartosz"

new bool:uzycie[33];

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_clcmd("lecz", "komenda_leczenie");
	register_clcmd("say /lecz", "komenda_leczenie");
	register_event("HLTV", "Nowa_Runda", "a", "1=0", "2=0")
}

public client_connect(id){
	uzycie[id] = false;
}

public komenda_leczenie(id){
	if(!is_user_alive(id)){
		client_cmd(id, "spk misc/zakaz.wav");  // dzwiek kiedy uslyszy niezywy gracz po uzyciu komendy
		return;
	}
	if(!uzycie[id]){
		set_user_health(id, get_user_health(id)+15);
		emit_sound(id, CHAN_STATIC, "misc/mktoasty.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM); // dzwiek uslyszy gracz i osoby blisko kiedy zywy gracz uzyje komendy
		client_print(id, print_center, "Apteczka dodala ci 15HP!");
		uzycie[id] = true;
	}
	else
	{
		client_cmd(id, "spk misc/zakaz.wav");
		client_print(id, print_center, "Uzyles apteczki w tej rundzie!");
	}
}

public Nowa_Runda(id){
	uzycie[id] = false;
}

public plugin_precache(){
	precache_sound("misc/mktoasty.wav");
	precache_sound("misc/zakaz.wav");
}

Plugin działa, ale nie w pełni. Funkcję komendy "lecz" można użyć raz na mapę, ja natomiast chcę raz na rundę.

Próbowałem również z eventem register_logevent("Poczatek_Rundy", 2, "1=Round_Start"), ale też nie działa. Kompiluje się, ale nie działa.

Może ja źle używam eventów, czy ktoś pomoże?

 

[GwynBleidD]

event HLTV oraz logevent round_start nie podają ID gracza.

 

Rozwiązania widze 2:

1. użyj np eventu spawnu gracza (jeśli posiadasz plugin na respawny, musisz pomyśleć o tym, aby sprawdzać, czy to jest 1 spawn w rundzie

2. użyj pętli, którą przejedziesz po wszystkich elementach tablicy.

[v139]

Dzięki, użyłem kanapki. Działa poprawnie

new bool:uzycie[33];

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_clcmd("lecz", "komenda_leczenie");
	register_clcmd("say /lecz", "komenda_leczenie");
	RegisterHam(Ham_Spawn, "player", "fwHamPlayerSpawnPost", 1)
}

public client_connect(id){
	uzycie[id] = false;
}

public komenda_leczenie(id){
	if(!is_user_alive(id)){
		//client_cmd(id, "spk misc/zakaz.wav");  // dzwiek kiedy uslyszy niezywy gracz po uzyciu komendy
		return;
	}
	if(!uzycie[id]){
		set_user_health(id, get_user_health(id)+15);
		emit_sound(id, CHAN_STATIC, "misc/mktoasty.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM); // dzwiek uslyszy gracz i osoby blisko kiedy zywy gracz uzyje komendy
		client_print(id, print_center, "Apteczka dodala ci 15HP!");
		uzycie[id] = true;
	}
	else
	{
		client_cmd(id, "spk misc/zakaz.wav");
		client_print(id, print_center, "Uzyles apteczki w tej rundzie!");
	}
}

public fwHamPlayerSpawnPost(id) {
        if (is_user_alive(id)) {
                uzycie[id] = false;
        }
} 


public plugin_precache(){
	precache_sound("misc/mktoasty.wav");
	precache_sound("misc/zakaz.wav");
}

[grankee]

Event HLTV podaje id, ale nie w przypadku jeśli przy rejestracji damy warunek, że ma się równać 0.