4 odpowiedzi w tym temacie

[adsads]

Witam, jest jakiś plugin który po wpisaniu przez admina komendy odradza wszystkich nie żywych graczy?

Tą komendą można odrodzić wszystkich i pojedynczo.

 

Prosiłbym o podanie linku do takiego pluginu.

[speedkill]

Sprawdź.

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>

#define PLUGIN "Respawn"
#define VERSION "1.0"
#define AUTHOR "speedkill"

new g_MaxPlayers;

public plugin_init(){
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	register_clcmd("say /ozyw", "RespawnPlayerMenu");
}

public plugin_cfg(){
	g_MaxPlayers = get_maxplayers();
}

public RespawnPlayerMenu(id){
	if(get_user_flags(id) & ADMIN_CFG){
		new g_UserName[64],
		g_Menu = menu_create("Wybierz gracza:", "PlayerChoose");
		
		menu_additem(g_Menu, "Wszyscy niezywi");
		
		for(new i = 1; i <= g_MaxPlayers; i++){
			if(is_user_connected(i) && !is_user_alive(i) && is_real_user(i)){
				get_user_name(i, g_UserName, charsmax(g_UserName));
				menu_additem(g_Menu, g_UserName);
			}
		}
		menu_setprop(g_Menu, MPROP_BACKNAME, "Powrot");
		menu_setprop(g_Menu, MPROP_NEXTNAME, "Dalej");
		menu_setprop(g_Menu, MPROP_EXITNAME, "Wyjscie");
		
		menu_display(id, g_Menu);
	}
}

public PlayerChoose(id, g_Menu, g_Item){
	if(g_Item == MENU_EXIT){
		menu_destroy(g_Menu);
		return PLUGIN_HANDLED;
	}
	new g_Data[6], 
		g_UserName[64],
		g_AdminName[64],
		g_Access,
		g_CallBack;
	
	if(g_Item == 0){
		for(new i = 1; i <= g_MaxPlayers; i++){
			if(is_user_connected(i) && !is_user_alive(i) && is_real_user(i)){
				PrepareRespawnPlayer(i);
			}
		}
	}
	else{
		menu_item_getinfo(g_Menu, g_Item, g_Access, g_Data, charsmax(g_Data), g_UserName, charsmax(g_UserName), g_CallBack);
		PrepareRespawnPlayer(get_user_index(g_UserName));
	}
	get_user_name(id, g_AdminName, charsmax(g_AdminName));
	log_amx("Admin: %s odrodzil: %s", g_AdminName, g_Item == 0? "wszystkich" : g_UserName);
	
	menu_destroy(g_Menu);
	return PLUGIN_HANDLED;
}

public PrepareRespawnPlayer(id){
	set_task(0.5, "RespawnPlayer", id);
}
		
public RespawnPlayer(id){
	if(is_user_connected(id) && !is_user_alive(id) && is_real_user(id)){
		ExecuteHamB(Ham_CS_RoundRespawn, id);
	}
}
		
stock is_real_user(id){
	if(is_user_bot(id) || is_user_hltv(id)){
		return false;
	}
	return true;
}

[adsads]

a można dorobić też logi do tego?

[speedkill]

log_amx("Admin: %s odrodzil: %s", g_AdminName, g_Item == 0? "wszystkich" : g_UserName);

[adsads]

oki dzięki