3 odpowiedzi w tym temacie

[L0rdS^P0l4K]

Sprawa wygląda tak...
Mam funkcję która 'koloruje chat'

wiad(player, message[])
{ 
 replace_all(message, 127, "!n", "^x01")
 replace_all(message, 127, "!t", "^x03")
 replace_all(message, 127, "!g", "^x04")
 
 if(player==0)
 {
  new plist[32], playernum, player;
  get_players(plist, playernum);
  for(new i = 0; i < playernum; i++)
  {
   player = plist[i];
   message_begin(MSG_ONE, gmsgSayText, {0,0,0}, player);
   write_byte(player);
   write_string(message);
   message_end();
  }
 }
 else
 {
  message_begin(MSG_ONE, gmsgSayText, {0,0,0}, player);
  write_byte(player);
  write_string(message);
  message_end();
 }
}

Oczywiście mam w plugin_init

gmsgSayText = get_user_msgid("SayText");

oraz zmienną globalną ? Nie wiem czy tak się to pisze.

new gmsgSayText;

Wszystko działa bez żadnego problemu gdy chcę wykorzystać to tak..

wiad(id, "!tinfo1 !ginfo2 !tinfo3")

Jednak muszę teraz wykorzystać to do

client_print(id, print_chat, "%L %L", id, "SCAN_RESULTS", id, g_preinfect[id] ? "SCAN_INFECTED" : "SCAN_CLEAN")

Jest to z biohazardu... ale tutaj pojawia się problem bo w jakikolwiek sposób ja to przerobie aby miało postać funkcji wiad... to i tak kompilator wyrzuca mi błąd

number of arguments does not match definition

[darkman]

funkcja format().

[R3X]

łatwiej z vformat()

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "vFormat"
#define VERSION "1.0"
#define AUTHOR "test"

new gmsgSayText;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_clcmd("test","test");
	gmsgSayText = get_user_msgid("SayText");
}
public test(id){
	wiad(id, "!g[UWAGA]!n Test!t %s!n nr!g %d","komendy",1);
	return PLUGIN_HANDLED;
}
wiad(player, const text[], any:...)
{
	static szMessage[192];
	vformat(szMessage, 191, text, 3);
	
	replace_all(szMessage, 191, "!n", "^x01")
	replace_all(szMessage, 191, "!t", "^x03")
	replace_all(szMessage, 191, "!g", "^x04")
 
	if(player==0)
	{
		new plist[32], playernum, player;
		get_players(plist, playernum);
		for(new i = 0; i < playernum; i++)
		{
			player = plist[i];
			message_begin(MSG_ONE, gmsgSayText, {0,0,0}, player);
			write_byte(player);
			write_string(szMessage);
			message_end();
		}
	}
	else
	{
		message_begin(MSG_ONE, gmsgSayText, {0,0,0}, player);
		write_byte(player);
		write_string(szMessage);
		message_end();
	}
}

[L0rdS^P0l4K]

Dziękuję bardzo. Wszystko działa jak trzeba

Pomógł+