3 odpowiedzi w tym temacie

[Co nie?]

proszę o dodanie HE do pierwszej broni w pluginie http://amxx.pl/topic...780-menu-broni/

[Wielkie Jol]

#include <amxmodx>
#include <fun>
#include <cstrike>
#include <hamsandwich>

#define DROPUJ

new X[][] = { "Weapon Menu", "1.0", "AztekHQS" }

new pCvar[3], i

enum BronInfo { _NazwaBroni[12], _NazwaConstBroni[17], _CSW_ID, _Ammo }

new const GlowneBronie[][BronInfo] = {
    { "AK47",    "weapon_ak47",    28,    90 },
    { "M4A1",    "weapon_m4a1",    22,    90 },
    { "Galil",    "weapon_galil",    14,    90 },
    { "Famas",    "weapon_famas",    15,    90 },
    { "MP5",    "weapon_mp5navy", 19,    120 },
    { "AWP",    "weapon_awp",    18,    30 }
}
 
new const Pistolety[][BronInfo] = {
    { "Deagle",    "weapon_deagle",    26,    35 },
    { "USP",    "weapon_usp",        16,    100 },
    { "Glock",    "weapon_glock18",    17,    120 }
}

public plugin_init() {
    register_plugin(X[0], X[1], X[2])

    RegisterHam(Ham_Spawn, "player", "Odrodzenie", 1)

    pCvar[0] = register_cvar("amx_weapon_menu", "2") // menu broni dla: 0 - ALL, 1 - TT, 2 - CT
    pCvar[1] = register_cvar("amx_weapon_menu_delay", "2") // po ilu sekundach ma sie pojawic menu broni
    pCvar[2] = register_cvar("amx_weapon_menu_drop", "1") // czy ma wyrzucac bronie i dawac sam noz przy spawnie: 1 - TAK, 0 - NIE
}

public Odrodzenie(id) {
    if(!is_user_alive(id)) return 0

    remove_task(id + 9101)

    if(get_pcvar_num(pCvar[2]) == 1) DropBronie(id)

    if(get_pcvar_num(pCvar[0]) == 1) {
        if(get_user_team(id) == 1) set_task(get_pcvar_float(pCvar[1]), "MenuWeapon", id + 9101)
    }
    else if(get_pcvar_num(pCvar[0]) == 2) {
        if(get_user_team(id) == 2) set_task(get_pcvar_float(pCvar[1]), "MenuWeapon", id + 9101)
    }
    else if(get_pcvar_num(pCvar[0]) == 0) {
        set_task(get_pcvar_float(pCvar[1]), "MenuWeapon", id + 9101)
    }
    return 0
}

public MenuWeapon(id) {
    if(!is_user_alive(id-9101)) return 1

    new numer[10]
    new menu = menu_create("\rWybierz\w Podstawowa bron", "HandleBron")
    for(i = 0; i < sizeof(GlowneBronie); i++) {
        num_to_str(i, numer, 9)
        menu_additem(menu, GlowneBronie[i][_NazwaBroni], numer)
    }
    menu_setprop(menu, 2, "Poprzednia strona")
    menu_setprop(menu, 3, "Nastepna strona")
    menu_setprop(menu, 4, "Wyjdz")
    menu_setprop(menu, 6, 1)
    menu_display(id-9101, menu)
    return 0
}

public HandleBron(id, menu, item) {
    if(!is_user_alive(id) || item == -3) {
        menu_destroy(menu)
        return 1
    }
    new data[3]
    new iaccess, callback, key
    menu_item_getinfo(menu, item, iaccess, data, 2, _, _, callback)

    key = str_to_num(data)

    DropBronie(id)
    give_item(id, GlowneBronie[key][_NazwaConstBroni])
    give_item(id, "weapon_hegrenade");
    cs_set_user_bpammo(id, GlowneBronie[key][_CSW_ID], GlowneBronie[key][_Ammo])

    new numer[10]
    new menu2 = menu_create( "\rWybierz\w Pistolet", "HandlePistolet")
    for(i = 0; i < sizeof(Pistolety); i++) {
        num_to_str(i, numer, 9)
        menu_additem(menu2, Pistolety[i][_NazwaBroni], numer)
    }
    menu_setprop(menu2, 4, "Wyjdz")
    menu_setprop(menu2, 6, 1)
    menu_display(id, menu2)
    return 0
}

public HandlePistolet(id, menu, item) {
    if(item == -3 || !is_user_alive(id)) {
        menu_destroy(menu)
        return 1
    }
    new data[3]
    new iaccess, callback, key
    menu_item_getinfo(menu, item, iaccess, data, 2, _, _, callback)

    key = str_to_num(data)

    give_item(id, Pistolety[key][_NazwaConstBroni])
    cs_set_user_bpammo(id, Pistolety[key][_CSW_ID], Pistolety[key][_Ammo])
    return 1
}

stock DropBronie(id) {
    strip_user_weapons(id)
    give_item(id, "weapon_knife")
}

[Co nie?]

Działa thx można cl.

[glut]

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Pomoc udzielona

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL