#include <amxmodx>
#include <colorchat>
#include <fun>
#include <hamsandwich>

new Array:g_Array, bool:g_Vip[33];

new const g_Langcmd[][]={"say /vips","say_team /vips","say /vipy","say_team /vipy"};

public plugin_init(){
	register_plugin("VIP Ultimate", "5.1.0.2", "benio101 & speedkill");
	RegisterHam(Ham_Spawn, "player", "SpawnedEventPre", 1);
	register_message(get_user_msgid("ScoreAttrib"), "g_VipStatus");
	g_Array=ArrayCreate(64,32);
	for(new i;i<sizeof g_Langcmd;i++)
		register_clcmd(g_Langcmd[i],"g_Vips");
}
public client_authorized(id){
	if(get_user_flags(id) & 524288 == 524288){
		client_authorized_vip(id);
	}
}
public client_authorized_vip(id){
	g_Vip[id]=true;
	new g_Name[64];
	get_user_name(id,g_Name,charsmax(g_Name));
	ArrayPushString(g_Array,g_Name);
	set_hudmessage(24, 190, 220, 0.25, 0.2, 0, 6.0, 6.0);
	show_hudmessage(0, "Vip %s wbija na serwer !",g_Name);
}
public client_disconnect(id){
	if(g_Vip[id]){
		client_disconnect_vip(id);
	}
}
public client_disconnect_vip(id){
	g_Vip[id]=false;
	new Name[64];
	get_user_name(id,Name,charsmax(Name));

	new g_Size = ArraySize(g_Array);
	new g_Name[64];

	for(new i = 0; i < g_Size; i++){
		ArrayGetString(g_Array, i, g_Name, charsmax(g_Name));

		if(equal(g_Name,Name)){
			ArrayDeleteItem(g_Array,i);
			break;
		}
	}
}
public SpawnedEventPre(id){
	if(g_Vip[id]){
		if(is_user_alive(id)){
			SpawnedEventPreVip(id);
		}
	}
}
public SpawnedEventPreVip(id){
	set_user_gravity(id, 0.6);
	if(get_user_team(id)%2){
		give_item(id, "item_thighpack");
	}
}
public g_VipStatus(){
	new id=get_msg_arg_int(1);
	if(is_user_alive(id) && g_Vip[id])
		set_msg_arg_int(2, ARG_BYTE, get_msg_arg_int(2)|4);
}
public g_Vips(id){
	new g_Name[64],g_Message[192];

	new g_Size=ArraySize(g_Array);

	for(new i = 0; i < g_Size; i++){
		ArrayGetString(g_Array, i, g_Name, charsmax(g_Name));

		add(g_Message, charsmax(g_Message), g_Name);

		if(i == g_Size - 1)
			add(g_Message, charsmax(g_Message), ".");
		else
			add(g_Message, charsmax(g_Message), ", ");
	}
	ColorChat(id,GREEN,"^x03Vipy ^x04na ^x03serwerze : ^x04%s", g_Message);
}
public client_infochanged(id){
	if(g_Vip[id]){
		new szName[64];
		get_user_info(id,"name",szName,charsmax(szName));

		ArrayPushString(g_Array,szName);

		new Name[64];
		get_user_name(id,Name,charsmax(Name));

		new g_Size=ArraySize(g_Array);
		new g_Name[64];

		for(new i = 0; i < g_Size; i++){
			ArrayGetString(g_Array, i, g_Name, charsmax(g_Name));

			if(equal(g_Name,Name)){
				ArrayDeleteItem(g_Array,i);
				break;
			}
		}
	}
}
public plugin_end(){
	ArrayDestroy(g_Array);
}