enum(<<=1){
	COLORCHAT=1,
	TUTOR
}

enum{				// Colors are projected to be compatible with ColorChat
	YELLOW=1,		// Yellow color has been added to make names more sense
	GREEN,
	RED=5,
	BLUE
}

public prize_info(){
	// Shows drawed prize`s description
	new	id=get_param(1),			// winner player`s id to send info
		color=get_param(2),			// color of message
		bool:key=!!get_param(5),	// determines if translate text by given key (1) or just show given text (0)
		channel=get_param(6),		// canals to send message to
		Float:time=get_param_f(7),	// time to last the message
		msg[192], msgSpec[192], skey[128];
	
	get_string(3, msg, 190);		// message text to prize winner player
	get_string(4, msgSpec, 190);	// message text to winner`s spectators
	
	new bool:channel_colorchat=!!(channel&COLORCHAT);
	new bool:channel_tutor=!!(channel&TUTOR);
	new any:tutor_color=max(1, min(4, (color+2)%6));
	
	if(strlen(msg)){
		if(key){
			copy(skey, 127, msg);
			copy(msg, 190, translate(id, skey));
		}
		if(channel_colorchat){
			ColorChat(id, Color:color, msg);
		}
		if(channel_tutor){
			tutorMake(id, tutor_color, time, msg);
		}
	}
	if(strlen(msgSpec)){
		if(key){
			copy(skey, 127, msgSpec);
			copy(msgSpec, 190, translate(id, skey));
		}
		for(new i=1; i<=maxPlayers; ++i){
			if(i!=id && !is_user_alive(i) && pev(i, pev_iuser2)==id){
				if(channel_colorchat){
					ColorChat(i, Color:color, msgSpec);
				}
				if(channel_tutor){
					tutorMake(i, tutor_color, time, msgSpec);
				}
			}
		}
	}
}