Skocz do zawartości

Witamy w Nieoficjalnym polskim support'cie AMX Mod X

Witamy w Nieoficjalnym polskim support'cie AMX Mod X, jak w większości społeczności internetowych musisz się zarejestrować aby móc odpowiadać lub zakładać nowe tematy, ale nie bój się to jest prosty proces w którym wymagamy minimalnych informacji.
  • Rozpoczynaj nowe tematy i odpowiedaj na inne
  • Zapisz się do tematów i for, aby otrzymywać automatyczne uaktualnienia
  • Dodawaj wydarzenia do kalendarza społecznościowego
  • Stwórz swój własny profil i zdobywaj nowych znajomych
  • Zdobywaj nowe doświadczenia

Dołączona grafika Dołączona grafika

Guest Message by DevFuse
 

Zdjęcie

Przerobienie klasy


  • Nie możesz napisać tematu
  • Zaloguj się, aby dodać odpowiedź
3 odpowiedzi w tym temacie

#1 Bolson

    Życzliwy

  • Zbanowany

Reputacja: -2
Nowy

  • Postów:23
  • Imię:Krzysiek
  • Lokalizacja:Polska
Offline

Napisano 20.02.2012 18:59

Przerobienie poniższej klasy na:
- Skasowanie rakiety
- Dodanie + 30 obrażeń z broni M4/AK/DGL
- Ma posiadać M4 / AK oraz Deagla
- Respienie się u wroga na 1/6
- Ma przebranie wroga



/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <codmod>
#include <hamsandwich>
#include <cstrike>
#include <colorchat>
#include <engine>

//rakiety
new sprite_blast;
new ilosc_rakiet_gracza[33];
new poprzednia_rakieta_gracza[33];
//koniec rakiety

new bool:ma_klase[33];

new CT_Skins[4][] = {"sas","gsg9","urban","gign"};
new Terro_Skins[4][] = {"arctic","leet","guerilla","terror"}

new const nazwa[] = "Terrorysta";
new const opis[] = "Ma 1 rakiete oraz 1/2 szansy na pojawienie sie na poczatku rundy na respie wroga z przebraniem wroga";
new const bronie = 1<<CSW_M4A1;
new const zdrowie = 20;
new const kondycja = 5;
new const inteligencja = 0;
new const wytrzymalosc = 0;

public plugin_init()
{
    register_plugin(nazwa, "1.0", "PYRDYS");
    
    cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);
    //rakiety
    register_touch("rocket", "*" , "DotykRakiety");
    register_event("ResetHUD", "ResetHUD", "abe");
    //koniec rakiety
    RegisterHam(Ham_Spawn, "player", "Spawn", 1);
}

//rakiety
public plugin_precache()
{
    sprite_blast = precache_model("sprites/dexplo.spr");
    precache_model("models/rpgrocket.mdl");
}
//koniec rakiety

public cod_class_enabled(id)
{
    ma_klase[id] = true;
    ColorChat(id, GREEN, "Klasa %s została stworzona przez Head Admina", nazwa);
    ilosc_rakiet_gracza[id] = 1;
}

public cod_class_disabled(id)
{
    ZmienUbranie(id, 1);
    ma_klase[id] = false;
}

public Spawn(id)
{
    if(!is_user_alive(id))
        return;
        
    if(!ma_klase[id])
        return;
        
    if(random_num(1,2) == 1)
    {
        new CsTeams:team = cs_get_user_team(id);
        
        cs_set_user_team(id, (team == CS_TEAM_CT)? CS_TEAM_T: CS_TEAM_CT);
        ExecuteHam(Ham_CS_RoundRespawn, id);
        
        cs_set_user_team(id, team);
    }
    ZmienUbranie(id, 0);
}

public ZmienUbranie(id, reset)
{
    if (!is_user_connected(id))
        return PLUGIN_CONTINUE;
    
    if(reset)
        cs_reset_user_model(id);
    else
    {
        new num = random_num(0,3);
        cs_set_user_model(id, (cs_get_user_team(id) == CS_TEAM_T)? CT_Skins[num]: Terro_Skins[num]);
    }
    
    return PLUGIN_CONTINUE;
}

//rakiety
public cod_class_skill_used(id)
{
    if (!ilosc_rakiet_gracza[id])
    {
        client_print(id, print_center, "Wykorzystales juz wszystkie rakiety!");
        return PLUGIN_CONTINUE;
    }
    
    if(poprzednia_rakieta_gracza[id] + 2.0 > get_gametime())
    {
        client_print(id, print_center, "Rakiet mozesz uzywac co 2 sekundy!");
        return PLUGIN_CONTINUE;
    }
    
    if (is_user_alive(id))
    {
        poprzednia_rakieta_gracza[id] = floatround(get_gametime());
        ilosc_rakiet_gracza[id]--;

        new Float: Origin[3], Float: vAngle[3], Float: Velocity[3];
        
        entity_get_vector(id, EV_VEC_v_angle, vAngle);
        entity_get_vector(id, EV_VEC_origin , Origin);
    
        new Ent = create_entity("info_target");
    
        entity_set_string(Ent, EV_SZ_classname, "rocket");
        entity_set_model(Ent, "models/rpgrocket.mdl");
    
        vAngle[0] *= -1.0;
    
        entity_set_origin(Ent, Origin);
        entity_set_vector(Ent, EV_VEC_angles, vAngle);
    
        entity_set_int(Ent, EV_INT_effects, 2);
        entity_set_int(Ent, EV_INT_solid, SOLID_BBOX);
        entity_set_int(Ent, EV_INT_movetype, MOVETYPE_FLY);
        entity_set_edict(Ent, EV_ENT_owner, id);
    
        VelocityByAim(id, 1000 , Velocity);
        entity_set_vector(Ent, EV_VEC_velocity ,Velocity);
    }    
    return PLUGIN_CONTINUE;
}

public DotykRakiety(ent)
{
    if (!is_valid_ent(ent))
        return;

    new attacker = entity_get_edict(ent, EV_ENT_owner);
    

    new Float:fOrigin[3];
    entity_get_vector(ent, EV_VEC_origin, fOrigin);    
    
    new iOrigin[3];
    for(new i=0;i<3;i++)
        iOrigin[i] = floatround(fOrigin[i]);
    
    message_begin(MSG_BROADCAST,SVC_TEMPENTITY, iOrigin);
    write_byte(TE_EXPLOSION);
    write_coord(iOrigin[0]);
    write_coord(iOrigin[1]);
    write_coord(iOrigin[2]);
    write_short(sprite_blast);
    write_byte(32);
    write_byte(20);
    write_byte(0);
    message_end();

    new entlist[33];
    new numfound = find_sphere_class(ent, "player", 190.0, entlist, 32);
    
    for (new i=0; i < numfound; i++)
    {        
        new pid = entlist[i];
        
        if (!is_user_alive(pid) || get_user_team(attacker) == get_user_team(pid))
            continue;
        cod_inflict_damage(attacker, pid, 55.0, 0.9, ent, (1<<24));
    }
    remove_entity(ent);
}    

public ResetHUD(id)
    ilosc_rakiet_gracza[id] = 1;

public client_disconnect(id)
{
    new ent = find_ent_by_class(0, "rocket");
    while(ent > 0)
    {
        if(entity_get_edict(id, EV_ENT_owner) == id)
            remove_entity(ent);
        ent = find_ent_by_class(ent, "rocket");
    }
}

//koniec rakiety


#2 Bolson

    Życzliwy

  • Autor tematu
  • Zbanowany

Reputacja: -2
Nowy

  • Postów:23
  • Imię:Krzysiek
  • Lokalizacja:Polska
Offline

Napisano 23.02.2012 16:02

Refresh?

#3 Bolson

    Życzliwy

  • Autor tematu
  • Zbanowany

Reputacja: -2
Nowy

  • Postów:23
  • Imię:Krzysiek
  • Lokalizacja:Polska
Offline

Napisano 28.02.2012 23:40

Refresh

#4 zQnem

    Zaawansowany

  • Użytkownik

Reputacja: 44
Pomocny

  • Postów:125
  • GG:
  • Imię:Michał
  • Lokalizacja:Warszawa
Offline

Napisano 29.02.2012 00:25

#include <amxmodx>
#include <codmod>
#include <hamsandwich>
#include <cstrike>
#include <colorchat>
#include <engine>
#include <hamsandwich>

#define DMG_BULLET (1<<1)

new bool:ma_klase[33];

new CT_Skins[4][] = {"sas","gsg9","urban","gign"};
new Terro_Skins[4][] = {"arctic","leet","guerilla","terror"}

new const nazwa[] = "Terrorysta";
new const opis[] = "1/6 szansy na pojawienie sie na poczatku rundy na respie wroga, posiada stroj wroga, +30dmg z wszystkich broni";
new const bronie = 1<<CSW_M4A1 | 1<<CSW_AK47 | 1<<CSW_DEAGLE;
new const zdrowie = 20;
new const kondycja = 5;
new const inteligencja = 0;
new const wytrzymalosc = 0;

public plugin_init()
{
    register_plugin(nazwa, "1.0", "PYRDYS");
    
    cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);

    RegisterHam(Ham_TakeDamage, "player", "TakeDamage");
    RegisterHam(Ham_Spawn, "player", "Spawn", 1);
}

public cod_class_enabled(id)
{
    ma_klase[id] = true;
    ColorChat(id, GREEN, "Klasa %s została stworzona przez Head Admina", nazwa);
}

public cod_class_disabled(id)
{
    ZmienUbranie(id, 1);
    ma_klase[id] = false;
}

public Spawn(id)
{
    if(!is_user_alive(id))
	    return;
	    
    if(!ma_klase[id])
	    return;
	    
    if(random_num(1,6) == 1)
    {
	    new CsTeams:team = cs_get_user_team(id);
	    
	    cs_set_user_team(id, (team == CS_TEAM_CT)? CS_TEAM_T: CS_TEAM_CT);
	    ExecuteHam(Ham_CS_RoundRespawn, id);
	    
	    cs_set_user_team(id, team);
    }
    ZmienUbranie(id, 0);
}

public ZmienUbranie(id, reset)
{
    if (!is_user_connected(id))
	    return PLUGIN_CONTINUE;
    
    if(reset)
	    cs_reset_user_model(id);
    else
    {
	    new num = random_num(0,3);
	    cs_set_user_model(id, (cs_get_user_team(id) == CS_TEAM_T)? CT_Skins[num]: Terro_Skins[num]);
    }
    
    return PLUGIN_CONTINUE;
}

public TakeDamage(this, idinflictor, idattacker, Float:damage, damagebits)
{
    if(!is_user_connected(idattacker))
    return HAM_IGNORED;

    if(!ma_klase[idattacker])
    return HAM_IGNORED;

    if(damagebits & DMG_BULLET)
    {
        new weapon = get_user_weapon(idattacker);

        if(weapon == CSW_M4A1)
        cod_inflict_damage(idattacker, this, 30.0, 0.0, idinflictor, damagebits);
        if(weapon == CSW_AK47)
        cod_inflict_damage(idattacker, this, 30.0, 0.0, idinflictor, damagebits);
        if(weapon == CSW_DEAGLE)
        cod_inflict_damage(idattacker, this, 30.0, 0.0, idinflictor, damagebits);
    }

    return HAM_IGNORED;
}

Proszę. Nie gwarantuję, że będzie działać, lecz jestem pewny w 95%, że zadziała :)

Pozdrawiam zQnem
  • +
  • -
  • 0




Użytkownicy przeglądający ten temat: 0

0 użytkowników, 0 gości, 0 anonimowych