3 odpowiedzi w tym temacie

[Pa+hetiC]

Zrobiłem klasę z która podpala atakując, oraz gdy rzuci granat to on wybucha w trakcie kontaktu z ścianą/podłogą/sufitem [...]
Problem polega na tym iż HE działają w ten sposób nie tylko na klasie ;/ Mógłby mi ktoś wskazać jak temu zaradzić? Byłbym wdzięczny.

Kolorem czerwonym zaznaczyłem linie odpowiedzialne za wybuchanie HE w kontakcie z ścianami.

Spoiler

#include <amxmodx>
#include <codmod>
#include <amxmisc>
#include <fakemeta>
#include <engine>
#include <cstrike>
#include <xs>

#define MAX 32

new const gszModels[][] = {"w_hegrenade.mdl"};

new sprite_fire,
sprite_smoke;

new palenie_gracza[MAX+1];

new const nazwa[] = "Terrorysta";
new const opis[] = "Obrażenia zadane przez niego mogą podpalić cel, ma lewe granaty.";
new const bronie = 1<<CSW_AK47 | 1<<CSW_HEGRENADE | 1<<CSW_SMOKEGRENADE;
new const zdrowie = 20;
new const kondycja = 0;
new const inteligencja = 0;
new const wytrzymalosc = 30;

new bool:ma_klase[33];

new gcvarEnabled;
public plugin_init()
{
register_plugin(nazwa, "0.1", "Pa+hetiC")
cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);

register_event("Damage", "Damage", "b", "2!=0");
register_event("ResetHUD", "ResetHUD", "abe");
register_touch("*", "grenade", "fwTouchGrenade2");
register_touch("grenade", "*", "fwTouchGrenade");

gcvarEnabled = register_cvar("amx_kaboom", "1");
}

public cod_class_enabled(id)
{
client_print(id, print_chat, "Klasa stworzona przez Pa+hetiC.")
ma_klase[id] = true;
ResetHUD(id);
}

public cod_class_disabled(id)
{
ma_klase[id] = false;
}

public plugin_precache()
{
sprite_fire = precache_model("sprites/fire.spr")
sprite_smoke = precache_model("sprites/steam1.spr")
}


public ResetHUD(id)
set_task(0.1, "ResetHUDx", id);

public ResetHUDx(id)
{
if(!is_user_connected(id)) return;

if(!ma_klase[id]) return;

cs_set_user_bpammo(id, CSW_HEGRENADE, 4);
}

public fwTouchGrenade2(ent, nade){
fwTouchGrenade(nade, ent);
}

public fwTouchGrenade(nade, ent){
if(!get_pcvar_num(gcvarEnabled)) return;

if(pev_valid(ent) && pev(ent, pev_solid) == SOLID_TRIGGER) return;

new szModel[32];
pev(nade, pev_model, szModel, 31);

for(new i=0;i<sizeof(gszModels); i++)
if(equal(szModel[7], gszModels[i])){
set_pev(nade, pev_dmgtime, get_gametime());
dllfunc(DLLFunc_Think, nade);
break;
}
}

public Damage(id)
{
new attacker = get_user_attacker(id);
if(!is_user_alive(attacker))
return PLUGIN_CONTINUE;

if(id == attacker)
return PLUGIN_CONTINUE;


if(ma_klase[attacker] && random_num(1, 3) == 1)
{
if(task_exists(id+2936))
remove_task(id+2936);
palenie_gracza[id] = 40;
new data[2]
data[0] = id
data[1] = attacker
set_task(0.2, "burning_flame", id+2936, data, 2, "b");
}
return PLUGIN_CONTINUE;
}

public burning_flame(data[2])
{
new id = data[0]

if(!is_user_alive(id))
{
palenie_gracza[id] = 0
remove_task(id+2936);
return PLUGIN_CONTINUE;
}

new origin[3], flags = pev(id, pev_flags)
get_user_origin(id, origin)

if(flags & FL_INWATER || palenie_gracza[id] < 1 || !get_user_health(id))
{
message_begin(MSG_PVS, SVC_TEMPENTITY, origin)
write_byte(TE_SMOKE)
write_coord(origin[0])
write_coord(origin[1])
write_coord(origin[2]-50)
write_short(sprite_smoke)
write_byte(random_num(15,20))
write_byte(random_num(10,20))
message_end()

remove_task(id+2936);
return PLUGIN_CONTINUE;
}

if(flags & FL_ONGROUND)
{
static Float:velocity[3]
pev(id, pev_velocity, velocity)
xs_vec_mul_scalar(velocity, 0.5, velocity)
set_pev(id, pev_velocity, velocity)
}

cod_inflict_damage(data[1], id, 1.0, 0.0, 0, 1<<24);

message_begin(MSG_PVS, SVC_TEMPENTITY, origin)
write_byte(TE_SPRITE)
write_coord(origin[0]+random_num(-5,5))
write_coord(origin[1]+random_num(-5,5))
write_coord(origin[2]+random_num(-10,10))
write_short(sprite_fire)
write_byte(random_num(5,10))
write_byte(25)
message_end()

palenie_gracza[id]--
return PLUGIN_CONTINUE;
}

Pluginy użyte do stworzenia klasy:
1. http://amxx.pl/topic...zybkie-granaty/
2. http://amxx.pl/topic...plonace-naboje/

[Jak się nazwać]

Spróbuj
public fwTouchGrenade2(ent, nade){
fwTouchGrenade(nade, ent);
}

public fwTouchGrenade(nade, ent){
new id = pev(nade, pev_owner)
if(!ma_klase[id]) return
if(!get_pcvar_num(gcvarEnabled)) return;

if(pev_valid(ent) && pev(ent, pev_solid) == SOLID_TRIGGER) return;

new szModel[32];
pev(nade, pev_model, szModel, 31);

for(new i=0;i<sizeof(gszModels); i++)
if(equal(szModel[7], gszModels[i])){
set_pev(nade, pev_dmgtime, get_gametime());
dllfunc(DLLFunc_Think, nade);
break;
}
}

[Pa+hetiC]

Działa... Dziękuję mistrzu, leci +
Sam bym nigdy na to nie wpadł :<

[Goliath]

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Pomoc udzielona

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL