2 odpowiedzi w tym temacie

[A może sma?]

Siema.
Jak mogę wykryć następujące rzeczy:
1. Podłożenie bomby
2. 10 sek do wybuchu bomby
3. 5 sek do wybuchu bomby
4. próbę rozbrojenia bomby
5. rozbrojenie bomby
6. wybuch bomby
Najfajniej by było z jakimiś przykładami czy cuś

[;((]

Dokumentacja AMXX.pl: csx.inc

Zaraz dam przykłady

@edit

#include <amxmodx>
#include <amxmisc>
#include <csx>

#define PLUGIN "Przyklad uzycia eventu bomby"
#define VERSION "1.0"
#define AUTHOR "DAMIANq"


public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
}

public  bomb_defused () 
{
	client_print(0, print_chat, "Bomba zostala rozbrojona")
}

Użytkownik DAMIANq edytował ten post 08.08.2011 11:44

[speedkill]

Dokumentacja AMXX.pl: CSX >> csx > bomb_planted - Podłozenie
Dokumentacja AMXX.pl: CSX >> csx > bomb_defusing - Rozbrajanie
Dokumentacja AMXX.pl: CSX >> csx > bomb_explode - Wybuch
Dokumentacja AMXX.pl: CSX >> csx > bomb_defused - Rozbrojenie
Tu masz przykład pluginu odliczanie :

/* 
 Bomb Countdown HUD Timer v0.2 by SAMURAI

	* Plugin Details
 With this plugin enabled, you can see an colored Hud Message with the c4 time left, until explode
  Remeber : if until explode remains less than 8 seconds, hudmessage color will be red, if > 7 will be yellow and > 13 will be green.

	* Required Modules:
 - CSX
 
        * Credits:
- Emp` for various indicates
- Alka for full tests 

	* Changelog
 - Fixed Events problems
 - Pcvars
 - Fixed any bug on plugin

*/


#include <amxmodx>
#include <csx>
 
#define PLUGIN "Bomb Countdown HUD Timer"
#define VERSION "0.2"
#define AUTHOR "SAMURAI" 
 
new g_c4timer, pointnum;
new bool:b_planted = false;

new g_msgsync;
 
 
public plugin_init()
{
	register_plugin(PLUGIN,VERSION,AUTHOR);
 
	pointnum = get_cvar_pointer("mp_c4timer");
 
	register_logevent("newRound", 2, "1=Round_Start");
	register_logevent("endRound", 2, "1=Round_End");
	register_logevent("endRound", 2, "1&Restart_Round_");
 
	g_msgsync = CreateHudSyncObj();
}
 
public newRound()
{
	g_c4timer = -1;
	remove_task(652450);
	b_planted = false;
}
 
public endRound()
{
	g_c4timer = -1;
	remove_task(652450);
}
 
public bomb_planted()
{
	b_planted = true;
	g_c4timer = get_pcvar_num(pointnum);
	dispTime()
	set_task(1.0, "dispTime", 652450, "", 0, "b");
}
 
public bomb_defused()
{
	if(b_planted)
	{
		remove_task(652450);
		b_planted = false;
	}
    
}
 
public bomb_explode()
{
	if(b_planted)
	{
		remove_task(652450);
		b_planted = false;
	}
	
}
 
public dispTime()
{   
	if(!b_planted)
	{
		remove_task(652450);
		return;
	}
        
 
	if(g_c4timer >= 0)
	{
		if(g_c4timer > 13) set_hudmessage(0, 150, 0, -1.0, 0.80, 0, 1.0, 1.0, 0.01, 0.01, -1);
		else if(g_c4timer > 7) set_hudmessage(150, 150, 0, -1.0, 0.80, 0, 1.0, 1.0, 0.01, 0.01, -1);
		else set_hudmessage(150, 0, 0, -1.0, 0.80, 0, 1.0, 1.0, 0.01, 0.01, -1);
 
		ShowSyncHudMsg(0, g_msgsync, "C4: %d", g_c4timer);
 
		--g_c4timer;
	}
  
} 
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/

Użytkownik speedkill123 edytował ten post 08.08.2011 11:47