13 odpowiedzi w tym temacie

[Kasia123]

Witam
Chcialabym zapytac czy istnieje taki plugin na serwer nowy cod mod ze jak ktos wpisze komende /gracze to wyswietli mu sie okno w motd lista z grazcami na ktorej jest jaki ma inet/perk i jaka klase a fajnie bylo by gdyby bylo tez pokazane ile ma hp i jaki rank ?

[Adminek AMXX.PL]

Automatyczna wiadomość


Ten temat został przeniesiony z forum:
AMX Mod X -> Problemy
do
AMX Mod X -> Szukam pluginu

[master.]

Ja mam cos takiego^^
Zapraszam na pw

[R3X]

Wyglądałoby to mniej więcej tak:

#include <amxmodx>
#include <amxmisc>
#include <codmod>

#define PLUGIN "CodMod_Gracze"
#define VERSION "1.0.1"
#define AUTHOR "R3X"

new giMaxPlayers;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_clcmd("say /gracze", "cmdGracze");
	
	giMaxPlayers = get_maxplayers();
}

public cmdGracze(caller){
	const iMax = 2048;
	static szMotd[iMax];
	new iLen = 0;
	
	iLen += formatex(szMotd[iLen], iMax-iLen, "<pre>Nick   Klasa   Perk^n");
	
	new szTemp[32];
	new class, perk, val;
	for(new id=1; id<=giMaxPlayers; id++){
		if(!is_user_connected(id)) continue;
		
		get_user_name(id, szTemp, 31);
		iLen += formatex(szMotd[iLen], iMax-iLen, "%20s", szTemp);
		
		class = cod_get_user_class(id);
		if(class == 0)
			iLen += formatex(szMotd[iLen], iMax-iLen, "Brak klasy");
		else{
			cod_get_class_name(class, szTemp, 31);
			iLen += formatex(szMotd[iLen], iMax-iLen, "%20s", szTemp);
		}
		
		perk = cod_get_user_perk(id, val);
		if(perk == 0)
			iLen += formatex(szMotd[iLen], iMax-iLen, "Brak perka^n");
		else{
			cod_get_perk_name(perk, szTemp, 31);
			iLen += formatex(szMotd[iLen], iMax-iLen, "%20s^n", szTemp);
		}
		
	}
	show_motd(caller, szMotd, "Gracze");
	return PLUGIN_HANDLED;
}

[Kasia123]

nie bardzio dziala pokazuje tylko 3 napisy klasa perk i nick i nic wiecej

[R3X]

pewnie nikogo oprócz Ciebie nie ma na serwerze

|| id == caller

ten fragment blokuje pokazywanie własnej klasy i perka

tak czy inaczej zainstaluje sobie codmoda i to sprawdzę

[Kasia123]

ok byłabym bardzo wdzieczna

[R3X]

U mnie zadziałało, weź jeszcze raz ten kod:
Czy jest plugin /gracze? - AMXX.pl: Support AMX Mod X

Wygląda prymitywnie, bo motd ma limit znaków; stworzenie tabelki wymaga zbyt ich dużo, ale coś da się ugrać; ile slotów masz na serwie?

[Kasia123]

na razie mam 14 slotow a teraz u mnie tez dziala ale to nie zgadza sie zeby bylo 1 pod 2 a chciałabym aby bylo jeszcze jaki kto ma lvl i ile hp

[mierzwi]

szczerze za dużo jak na motd (tak jak mówi r3x, jak będzie duża ilość graczy to po prostu urwie kod w połowie...)

[Kasia123]

a da sie jakos to zrobic pod gotowe okno motd razem z pluginem ze w tym motd bedzie od razu tlo ze bedzie wczytywac nicki klasy i perki z serwera [obecnych graczy]

[R3X]

"Gotowe okno motd", czyli co? Pokazanie listy graczy, ich klas i poziomów ze strony www obciążyłoby znacznie serwer, bo nie ma tych informacji wśród danych możliwych do wydobycia standardową metodą. Trzeba by wysłać dane do bazy lub w pliku XML przed każdym użycie komendy /gracze (inaczej dane nie byłyby aktualne), a to jest spory kłopot.

Pozostałe motd obowiązuje surowy limit znaków i 14 wierszy z pełnymi danymi zmieści się tylko wrzucone jeden pod drugim. Grafikę w tle można dodać bez problemu, grafika dla poszczególnych graczy odpada.

Moja propozycja: komenda /gracze pokazuje menu

Wybierz druzyne

1. Teroryści
2. CT

albo nawet okno z pojedynczym graczem

say /gracz Kasia

Jak masz jakąś wizję tej listy to narysuj w Paincie, coby nie były czarne mrówki na białym tle.

[Kasia123]

a jak zrobic to /gracze
1. tero
2. ct ?

[R3X]

A tak:

Spoiler

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <codmod>

#define PLUGIN "CodMod_Gracze"
#define VERSION "1.1"
#define AUTHOR "R3X"
#define KeysTeamChoose (1<<0)|(1<<1)|(1<<9) // Keys: 120

new giMaxPlayers;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_menucmd(register_menuid("TeamChoose"), KeysTeamChoose, "PressedTeamChoose");

	register_clcmd("say /gracze", "cmdGracze");
	
	giMaxPlayers = get_maxplayers();
}

public cmdGracze(caller){
	ShowTeamChoose(caller);
	return PLUGIN_HANDLED;
}
	
showPlayerList(caller, CsTeams:team){
	const iMax = 2048;
	static szMotd[iMax];
	new iLen = 0;
	
	iLen += formatex(szMotd[iLen], iMax-iLen, "<pre>Nick   Klasa   Perk^n");
	
	new szTemp[32];
	new class, perk, val;
	for(new id=1; id<=giMaxPlayers; id++){
		if(!is_user_connected(id)) continue;
		if(cs_get_user_team(id) != team) continue;
		
		get_user_name(id, szTemp, 31);
		iLen += formatex(szMotd[iLen], iMax-iLen, "%20s", szTemp);
		
		class = cod_get_user_class(id);
		if(class == 0)
			iLen += formatex(szMotd[iLen], iMax-iLen, "Brak klasy");
		else{
			cod_get_class_name(class, szTemp, 31);
			iLen += formatex(szMotd[iLen], iMax-iLen, "%20s", szTemp);
		}
		
		perk = cod_get_user_perk(id, val);
		if(perk == 0)
			iLen += formatex(szMotd[iLen], iMax-iLen, "Brak perka^n");
		else{
			cod_get_perk_name(perk, szTemp, 31);
			iLen += formatex(szMotd[iLen], iMax-iLen, "%20s^n", szTemp);
		}
		
	}
	show_motd(caller, szMotd, "Gracze");
}

public ShowTeamChoose(id) {
	show_menu(id, KeysTeamChoose, "\yZ ktorej druzyny?^n\w^n1. Terrorysci^n2. CT^n^n0. Wyjdz^n", -1, "TeamChoose") // Display menu
}

public PressedTeamChoose(id, key) {
	switch (key) {
		case 0: { 
			showPlayerList(id, CS_TEAM_T);
		}
		case 1: {
			showPlayerList(id, CS_TEAM_CT);
		}
	}
}

Teraz można myśleć o wyglądzie tabelki i nowych wierszach to jak?