2 odpowiedzi w tym temacie

[zaja]

Witam Wszystkich!
Otóż posiadam swój serwer CS 1.6 z modem CoD i osoba zasłużona z mojego forum postanowiła mi napisać nowy plugin na klasy do mojego moda.

I właśnie powstał jeden problem... Mianowicie chodzi oto, że:
- gracz który posiada klasę rambo po każdym zabójstwie / fragu przeciwnika dostaje podobno automatycznie nowy magazynek amunicji ale niestety ta funkcja nie działa nie wiem czemu.. jestem średnio-amator z tymi klockami więc proszę Was o pomoc. Autor powiedział że naprawi to na czasie, no ale już minęło 3 miesiące od kiedy powiedział mi, że naprawi ten błąd, a mi zależy na czasie, ponieważ nie chcę aby renoma mojej sieci serwerów spadła. . Więc szukam kogoś kto pomoże mi zrobić to szybciej. Poniżej zamieszczam kod pluginu:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <codmod>
#include <fakemeta>

new const nazwa[] = "Rambo *VIP*";
new const opis[] = "Ma podwojny skok, dostaje 20 hp za kazde zabojstwo";
new const bronie = 1<<CSW_FAMAS | 1<<CSW_HEGRENADE;
new const zdrowie = 30;
new const kondycja = 38;
new const inteligencja = 0;
new const wytrzymalosc = 20;

new bool:ma_klase[33];

new bool:moze_skoczyc[33];

new const maxClip[31] = { -1, 13, -1, 10,  1,  7,  1,  30, 30,  1,  30,  20,  25, 30, 35, 25,  12,  20, 
10,  30, 100,  8, 30,  30, 20,  2,  7, 30, 30, -1,  50 };

public plugin_init() {
	register_plugin(nazwa, "1.0", "QTM_Peyote");
	
	cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);
	
	register_forward(FM_CmdStart, "CmdStart");
	register_event("DeathMsg", "DeathMsg", "ade");
}

public cod_class_enabled(id)
{
	if(!(get_user_flags(id) & ADMIN_LEVEL_H))
	{
		client_print(id, print_chat, "[EX-COD] Nie masz uprawnien, aby uzywac tej klasy.")
		return COD_STOP;
	}
	ma_klase[id] = true;
	return COD_CONTINUE;
}

public cod_class_disabled(id)
	ma_klase[id] = false;

public CmdStart(id, uc_handle)
{
	if(!ma_klase[id])
		return FMRES_IGNORED;
	
	new button = get_uc(uc_handle, UC_Buttons);
	new oldbutton = pev(id, pev_oldbuttons);
	new flags = pev(id, pev_flags);
	if((button & IN_JUMP) && !(flags & FL_ONGROUND) && !(oldbutton & IN_JUMP) && moze_skoczyc[id])
	{
		moze_skoczyc[id] = false;
		new Float:velocity[3];
		pev(id, pev_velocity, velocity);
		velocity[2] = random_float(265.0,285.0);
		set_pev(id, pev_velocity, velocity);
	}
	else if(flags & FL_ONGROUND)	
		moze_skoczyc[id] = true;
		
	return FMRES_IGNORED;
}

public DeathMsg()
{
	new killer = read_data(1);
	new victim = read_data(2);
	
	if(!is_user_connected(killer))
		return PLUGIN_CONTINUE;
	
	if(ma_klase[victim] && !ma_klase[killer])
		cod_set_user_xp(killer, cod_get_user_xp(killer)+10);
	
	if(ma_klase[killer])
	{
		new cur_health = pev(killer, pev_health);
		new Float:max_health = 100.0+cod_get_user_health(killer);
		new Float:new_health = cur_health+20.0<max_health? cur_health+20.0: max_health;
		set_pev(killer, pev_health, new_health);
		
		new weapon = get_user_weapon(killer);
		if(maxClip[weapon] != -1)
			set_user_clip(killer, maxClip[weapon]);
	}
	
	
	return PLUGIN_CONTINUE;
}

stock set_user_clip(id, ammo)
{
	new weaponname[32], weaponid = -1, weapon = get_user_weapon(id, _, _);
	get_weaponname(weapon, weaponname, 31);
	while ((weaponid = engfunc(EngFunc_FindEntityByString, weaponid, "classname", weaponname)) != 0)
		if(pev(id, pev_owner) == id) 
		{
			set_pdata_int(weaponid, 51, ammo, 4);
			return weaponid;
		}
	return 0;
}

Bardzo proszę Was o pomoc i dziękuję!

Dodano 06 styczeń 2011 - 16:17:
hmm pomoże ktoś?

[DarkGL]

stock set_user_clip(id,ammo)
{
new wpn[32],WPNid=-1,null,weaponid = get_user_weapon(id,null,null);
get_weaponname(weaponid,wpn,31);
while ((WPNid = engfunc(EngFunc_FindEntityByString,WPNid,"classname",wpn)) != 0)
if (id == pev(WPNid,pev_owner)){
cs_set_weapon_ammo(WPNid,ammo);
return WPNid;
}
return 0;
}

sprobuj tak
musisz dodać na samej górze jeszcze
#include <cstrike>

[zaja]

Ok, spróbuję i zdam raport