2 odpowiedzi w tym temacie

[Batonik]

Witam, otóż chcę przerobić plugin od kickowania spectów:

#include <amxmodx>
#include <amxmisc>

new const PLUGIN[] = "Kickuje Spectow";
new const VERSION[] = "1.0";
new const AUTHOR[] = "v3x";

#define ACCESS_LEVEL ADMIN_KICK
#define CS_TEAM_SPECTATOR 3

new g_MaxPlayers;

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_concmd("amx_kicks", "ConCmd_KickSpecs", ACCESS_LEVEL, "- Kickuje wszystkich spectow");

	g_MaxPlayers = get_maxplayers();
}

public ConCmd_KickSpecs(id, lvl, cid)
{
	if(!cmd_access(id, lvl, cid, 1))
		return PLUGIN_HANDLED;


	for(new i = 1; i <= g_MaxPlayers; i++)
	{
		if(!is_user_connected(i) || get_user_team(i) != CS_TEAM_SPECTATOR)
			continue;

		server_cmd("kick #%d ^"Zostales wyrzucony przez admina za siedzienie na spekcie^"", get_user_userid(i));
	}

	static name[32];
	get_user_name(id, name, 31);

	switch(get_cvar_num("amx_show_activity"))
	{
		case 2: client_print(0, print_chat, "[AMXX] ADMIN %s: Kicknal spectatorow", name);
		case 1: client_print(0, print_chat, "[AMXX] ADMIN: Kicknal spectatorow");
	}

	return PLUGIN_HANDLED;
}

I mam pytanie:

{
	register_plugin(PLUGIN, VERSION, AUTHOR);

	register_concmd("amx_kicks", "ConCmd_KickSpecs", ACCESS_LEVEL, "- Kickuje wszystkich spectow");

	g_MaxPlayers = get_maxplayers();
}

ACCESS_LEVEL odpowiada za poziom gracza, w tym przypadku jest ustawione że kickuje wszystkich spectów, co wpisać by nie kickowało graczy z flagą b, czyli od rezerwacji.

[R3X]

To flaga dostępu do komendy, popraw tego fora co jest na taki

for(new i = 1; i <= g_MaxPlayers; i++)
{
	if(!is_user_connected(i) || get_user_team(i) != CS_TEAM_SPECTATOR)
		continue;
	if(get_user_flags(i) & ADMIN_RESERVATION) 
			continue;

	server_cmd("kick #%d ^"Zostales wyrzucony przez admina za siedzienie na spekcie^"", get_user_userid(i));
}

[Batonik]

Ok, dzięki, można zamknąć
Reput dla Ciebie 666