12 odpowiedzi w tym temacie

[camilost]

Potrzebuję tego pluginu: No Team Flash (KRoT@L) - AlliedModders przerobionego tak, że admin z flagą ADMIN_LEVEL_H nie zostaje oślepiony przez drużynę. Właściciel zostanie oślepiony - już tak jest w pluginie.

Wiem że to tylko dopisanie paru liter ale nie myślę już : /

/*************************************************************************************************************
                        	  		 AMX No Team Flash

  Version: 0.2
  Author: KRoT@L

  0.1    Release
  0.2    Bug fix


  You won't be flashed by your teammates.


  Cvar:

	no_team_flash "1"		-	0: Disables the plugin
                        1: Enables the plugin
                        

  Setup (AMX 0.9.9):

	Install the amx file.
  Enabled VexdUM (both in metamod/plugins.ini and amx/config/modules.ini)
  
  
  Credits:
  
  Requested by baldbobby
  Cluster Grenade by doomy

*************************************************************************************************************/

#include <amxmodx>

new g_msgScreenFade, grenade[32], last
new Float:g_gametime, g_owner

public plugin_init()
{
	register_plugin("No Team Flash", "0.2", "KRoTaL")
	register_cvar("no_team_flash", "1")
	register_event("ScreenFade", "eventFlash", "be", "4=255", "5=255", "6=255", "7>199")
	register_event("TextMsg", "fire_in_the_hole", "b", "2&#Game_radio", "4&#Fire_in_the_hole")
	register_event("TextMsg", "fire_in_the_hole2", "b", "3&#Game_radio", "5&#Fire_in_the_hole")
	register_event("99", "grenade_throw", "b")
	g_msgScreenFade = get_user_msgid("ScreenFade")
}

public eventFlash(id)
{
  new Float:gametime = get_gametime()
  if(gametime != g_gametime)
  {
    g_owner = get_grenade_owner()
    g_gametime = gametime
  }
  if(is_user_connected(g_owner) && g_owner != id && get_user_team(id) == get_user_team(g_owner))
  {
  	message_begin(MSG_ONE, g_msgScreenFade, {0,0,0}, id)
  	write_short(1)
  	write_short(1)
  	write_short(1)
  	write_byte(0)
  	write_byte(0)
  	write_byte(0)
  	write_byte(255)
  	message_end()
	}
}

public grenade_throw()
{
	if(read_datanum() < 2)
    return PLUGIN_HANDLED_MAIN

	if(read_data(1) == 11 && (read_data(2) == 0 || read_data(2) == 1))
	{
		add_grenade_owner(last)
	}

	return PLUGIN_CONTINUE
}

public fire_in_the_hole()
{
	new name[32]
	read_data(3, name, 31)
	last = get_user_index(name)

	return PLUGIN_CONTINUE
}

public fire_in_the_hole2()
{
	new name[32]
	read_data(4, name, 31)
	last = get_user_index(name)

	return PLUGIN_CONTINUE
}

add_grenade_owner(owner)
{
	for(new i = 0; i < 32; i++)
  {
		if(grenade[i] == 0)
    {
			grenade[i] = owner
			return
		}
	}
}

get_grenade_owner()
{
	new which = grenade[0]
	for(new i = 1; i < 32; i++)
  {
		grenade[i-1] = grenade[i]
	}
	grenade[31] = 0
	return which
}

Użytkownik camilost edytował ten post 07.05.2010 21:28

[G[o]Q]

public eventFlash(id)
{
  new Float:gametime = get_gametime()
  if(gametime != g_gametime)
  {
    g_owner = get_grenade_owner()
    g_gametime = gametime
  }
  if(is_user_connected(g_owner) && g_owner != id && get_user_team(id) == get_user_team(id))
  {
        message_begin(MSG_ONE, g_msgScreenFade, {0,0,0}, id)
        write_short(1)
        write_short(1)
        write_short(1)
        write_byte(0)
        write_byte(0)
        write_byte(0)
        write_byte(255)
        message_end()
        }
}

na

public eventFlash(id)
{
  new Float:gametime = get_gametime()
  if(gametime != g_gametime)
  {
    g_owner = get_grenade_owner()
    g_gametime = gametime
  }
  if(is_user_connected(g_owner) && g_owner != id && get_user_team(id) == get_user_team(g_owner)&& get_user_flags(id)&ADMIN_LEVEL_H)
  {
        message_begin(MSG_ONE, g_msgScreenFade, {0,0,0}, id)
        write_short(1)
        write_short(1)
        write_short(1)
        write_byte(0)
        write_byte(0)
        write_byte(0)
        write_byte(255)
        message_end()
        }
}

Użytkownik G[o]Q edytował ten post 07.05.2010 21:44

[camilost]

heh dzięki wystarczyło 1 linijkę
(get_user_flags(g_owner) & ADMIN_LEVEL_H)
a tu chodzi że owner czyli że właściciel flesza czy ten co dostał na ryja?

[sbstn]

ten co dostał na ryja

to w tym wypadku id, a

właściciel flesza

to właśnie jak nazwa wskazuje g_owner

[camilost]

Don't work. Testuje z gracze bez flag (Zwykłym)

[G[o]Q]

jak nie dziala sproboj jeszcze raz podmienic

[camilost]

I tk nie działa nie wiem o co kaman : / I mnie i tego goscia oslepia

07 maj 2010 - 23:26:
Może to być przez plugin co zmienia kolor flasha (Colored Flashbangs)? Może zrobicie mi na czarny do tego NoTeamFlesh i bd git (Wszyscy oprócz ADMINA_LEVEL_H)
I bym usunął te colored flashbangs

07 maj 2010 - 23:42:
Albo połączyć te dwa pluginy?
i dać tego ifa przed tamtym? Nie wiem

JBC. macie .sma do colored flashbang, może jutro sobie to zrobię jak otrzeźwieję

#include <amxmodx>

#define PLUGIN	"Colored Flashbangs"
#define VERSION	"1.0"
#define AUTHOR	"v3x"

new g_nMsgScreenFade

public plugin_init()
{
	register_plugin(PLUGIN,VERSION,AUTHOR)
	register_event("ScreenFade","FlashedEvent","be","4=255","5=255","6=255","7>199")
	g_nMsgScreenFade = get_user_msgid("ScreenFade")
	// Cvars
	register_cvar("amx_fb_mode", "1")
	register_cvar("amx_fb_r",    "255")
	register_cvar("amx_fb_g",    "25")
	register_cvar("amx_fb_b",    "25")
}

public FlashedEvent( id )
{
	new iMode = get_cvar_num("amx_fb_mode")

	if ( !iMode ) return PLUGIN_CONTINUE

	new iRed,iGreen,iBlue

	switch( iMode )
	{
		case 1:
		{
			iRed =   get_cvar_num("amx_fb_r")
			iGreen = get_cvar_num("amx_fb_g")
			iBlue =  get_cvar_num("amx_fb_b")
		}
		case 2:
		{
			iRed =   random_num(0,255)
			iGreen = random_num(0,255)
			iBlue =  random_num(0,255)
		}
	}

	if ( !( iRed ) || !( iGreen ) || !( iBlue ) )
	{
		iRed =   100
		iGreen = 100
		iBlue =  100
	}

		message_begin( MSG_ONE,g_nMsgScreenFade,{0,0,0},id )
		write_short( read_data( 1 ) )	// Duration
		write_short( read_data( 2 ) )	// Hold time
		write_short( read_data( 3 ) )	// Fade type
		write_byte ( iRed )				// Red
		write_byte ( iGreen )			// Green
		write_byte ( iBlue )			// Blue
		write_byte ( read_data( 7 ) )	// Alpha
		message_end()

	return PLUGIN_HANDLED
}

08 maj 2010 - 01:49:
Zrobiłem takie coś tylko nie wiem czy bd dobrze działać (Nie mam z kim testowa, bo all śpią)

/*
	AMX No Team Flash
	Version: 0.2
	Author: KRoT@L
	Cvar: no_team_flash "1"	- 0: Disables the plugin, 1: Enables the plugin
*/

#include <amxmodx>

new g_msgScreenFade, g_nMsgScreenFade, grenade[32], last
new Float:g_gametime, g_owner

public plugin_init()
{
	register_plugin("Clr n NoTeam Flash", "0.3", "KRoTaL n v3x")
	register_cvar("no_team_flash", "1")
	register_cvar("amx_fb_mode", "1")
	register_cvar("amx_fb_r",    "255")
	register_cvar("amx_fb_g",    "25")
	register_cvar("amx_fb_b",    "25")
	register_event("ScreenFade", "eventFlash", "be", "4=255", "5=255", "6=255", "7>199")
	register_event("TextMsg", "fire_in_the_hole", "b", "2&#Game_radio", "4&#Fire_in_the_hole")
	register_event("TextMsg", "fire_in_the_hole2", "b", "3&#Game_radio", "5&#Fire_in_the_hole")
	register_event("99", "grenade_throw", "b")
	g_nMsgScreenFade = get_user_msgid("ScreenFade")
	g_msgScreenFade = get_user_msgid("ScreenFade")
}

public eventFlash(id)
{
	new iMode = get_cvar_num("amx_fb_mode")
	new iRed,iGreen,iBlue
	new Float:gametime = get_gametime()

	if(gametime != g_gametime)
	{
		g_owner = get_grenade_owner()
		g_gametime = gametime
	}

	if ( !iMode ) return PLUGIN_CONTINUE

	switch( iMode )
	{
		case 1:
		{
			iRed =   get_cvar_num("amx_fb_r")
			iGreen = get_cvar_num("amx_fb_g")
			iBlue =  get_cvar_num("amx_fb_b")
		}
		case 2:
		{
			iRed =   random_num(0,255)
			iGreen = random_num(0,255)
			iBlue =  random_num(0,255)
		}
	}

	if ( !( iRed ) || !( iGreen ) || !( iBlue ) )
	{
		iRed =   100
		iGreen = 100
		iBlue =  100
	}

	if(is_user_connected(g_owner) && g_owner != id && get_user_team(id) == get_user_team(g_owner) && (get_user_flags(id) & ADMIN_LEVEL_H))
	{
		message_begin(MSG_ONE, g_msgScreenFade, {0,0,0}, id)
		write_short(1)
		write_short(1)
		write_short(1)
		write_byte(0)
		write_byte(0)
		write_byte(0)
		write_byte(255)
		message_end()
	}
	else
	{
		message_begin( MSG_ONE,g_nMsgScreenFade,{0,0,0},id )
		write_short( read_data( 1 ) )	// Duration
		write_short( read_data( 2 ) )	// Hold time
		write_short( read_data( 3 ) )	// Fade type
		write_byte ( iRed )				// Red
		write_byte ( iGreen )			// Green
		write_byte ( iBlue )			// Blue
		write_byte ( read_data( 7 ) )	// Alpha
		message_end()
	}
	return PLUGIN_HANDLED
}

public grenade_throw()
{
	if(read_datanum() < 2)
		return PLUGIN_HANDLED_MAIN

	if(read_data(1) == 11 && (read_data(2) == 0 || read_data(2) == 1))
	{
		add_grenade_owner(last)
	}

	return PLUGIN_CONTINUE
}

public fire_in_the_hole()
{
	new name[32]
	read_data(3, name, 31)
	last = get_user_index(name)

	return PLUGIN_CONTINUE
}

public fire_in_the_hole2()
{
	new name[32]
	read_data(4, name, 31)
	last = get_user_index(name)

	return PLUGIN_CONTINUE
}

add_grenade_owner(owner)
{
	for(new i = 0; i < 32; i++)
	{
		if(grenade[i] == 0)
		{
			grenade[i] = owner
			return
		}
	}
}

get_grenade_owner()
{
	new which = grenade[0]
	for(new i = 1; i < 32; i++)
	{
		grenade[i-1] = grenade[i]
	}
	grenade[31] = 0
	return which
}

09 maj 2010 - 21:53:
Nie działa to @UP najnowsze. Ktoś sprawdzi czemu/ewent. poprawi?

Użytkownik camilost edytował ten post 07.05.2010 22:43

[R3X]

Może bardziej coś takiego

if(is_user_connected(g_owner) && g_owner != id && get_user_team(id) == get_user_team(g_owner) )
{
	if(get_user_flags(id) & ADMIN_LEVEL_H){
		message_begin(MSG_ONE, g_msgScreenFade, {0,0,0}, id)
		write_short(1)
		write_short(1)
		write_short(1)
		write_byte(0)
		write_byte(0)
		write_byte(0)
		write_byte(255)
		message_end()
	}
	else
	{
		message_begin( MSG_ONE,g_nMsgScreenFade,{0,0,0},id )
		write_short( read_data( 1 ) )	// Duration
		write_short( read_data( 2 ) )	// Hold time
		write_short( read_data( 3 ) )	// Fade type
		write_byte ( iRed )				// Red
		write_byte ( iGreen )			// Green
		write_byte ( iBlue )			// Blue
		write_byte ( read_data( 7 ) )	// Alpha
		message_end()
	}
}

[camilost]

A na końcu zostawić to return PLUGIN_HANDLED?

[R3X]

Jasne.

Nie sprawdzałem tego kodu, ale to 'else' było wyraźnie w złym miejscu

[camilost]

Hemm... sam siebie oślepiłem i miałem białe zamiast tego co zdefiniowane w cvarach (Szary) : /

Na serwerze żadnego VIPa ani gracza i nie mam jak testować

[R3X]

Pomyliłem się Następnym razem mi się uda (taa), idę to przejrzeć na HLDS

09 maj 2010 - 23:12:
Kod, który napisałeś wygląda rozsądnie i nawet zadziałał. Bez mojej poprawki

Sprawdź samego NoTeamFlasha czy działa, jeśli nie to dopisz 1 linijkę do łapania eventów

register_event("TextMsg", "fire_in_the_hole2", "b",  "6&#Fire_in_the_hole")

[camilost]

Hehe Ja tylko je ze sobą skleiłem i zrobiłem to:

Spoiler

if(is_user_connected(g_owner) && g_owner != id && get_user_team(id) == get_user_team(g_owner) && (get_user_flags(id) & ADMIN_LEVEL_H))
	{
		message_begin(MSG_ONE,g_msgScreenFade,{0,0,0},id)
		write_short(1)					// Duration
		write_short(1)					// Hold time
		write_short(1)					// Fade type
		write_byte(0)					// Red
		write_byte(0)					// Green
		write_byte(0)					// Blue
		write_byte(255)					// Alpha
		message_end()
	}
	else
	{
		message_begin( MSG_ONE,g_nMsgScreenFade,{0,0,0},id )
		write_short( read_data( 1 ) )	// Duration
		write_short( read_data( 2 ) )	// Hold time
		write_short( read_data( 3 ) )	// Fade type
		write_byte ( iRed )				// Red
		write_byte ( iGreen )			// Green
		write_byte ( iBlue )			// Blue
		write_byte ( read_data( 7 ) )	// Alpha
		message_end()
	}
	return PLUGIN_HANDLED

Hmm... muszę jutro z jakimś VIPem przetestować, oślepiać, na kolorowo oślepia a jak dalej to trza przetestować

Teraz idę spać, bo z budy mnie jeszcze wywalą

10 maj 2010 - 19:59:
Ehh jakoś to nie działa Chyba kilka razy mnie nie oślepiło (3) od drużyny. A większość oślepiło. I może mi się zdawało ale te flesze jeśli mi rzuci VIP to ja niedostaję : / A normalny gracz jak mi rzuci to dostaje.