5 odpowiedzi w tym temacie

[kubus]

witam

Mam problem z pluginem afkbomb - mianowicie chodzi o czas po którym wypada paka - standardowo jest on ustawiony na 20 sekund, chciałem zmienić na 10 sekund więc zmienilem w cvarze mp_afktime 10 i nic - paka dalej wypada po 20 sekundach więc postanowiłem w samym kodzie zmienić wartość z 20 na 10 - to samo paka nadal wypada po 20 sekundach, dopisałem nawet do server.cfg mp_afktime 10 i bez rezultatu...

O co może chodzić?

Załączam kod:

/*
 *
 *	Author:		BlackFlagg based on Cheesy Peteza generic AFK kicker
 *	Date:		06-July-2004
 *
 *
 *	Description:	Drop bomb when player is AFK for 30 secs
 *
 *	Cvars:
 *			mp_afktime 20		Time a player is allowed to be AFK in seconds before they drop bomb
 *						They time is only accumulated while they are alive.
 *			mp_afkminplayers 1	Minimum number of players required .
 *
 *
 *	Requirements:	AMXModX
 *
 *
 */

#include <amxmodx>

#define MIN_AFK_TIME 20		// I use this incase stupid admins accidentally set mp_afktime to something silly.
#define CHECK_FREQ 5		// This is also the warning message frequency.

new g_oldangles[33][3]
new g_afktime[33]
new bool:g_spawned[33] = {true, ...}

public plugin_init() {
	register_plugin("AFK Bomb Drop","1.0","BlackFlagg") 
	register_cvar("afk_version", "1.0a", FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_SPONLY)

	register_cvar("mp_afktime", "10")	// Drop bomb if AFK longer than this time
	register_cvar("mp_afkminplayers", "1")	// at least this many players on the server
	set_task(float(CHECK_FREQ),"checkPlayers",_,_,_,"b")
	register_event("ResetHUD", "playerSpawned", "be")
}

public checkPlayers() {
	for (new i = 1; i <= get_maxplayers(); i++) {
		if (is_user_alive(i) && is_user_connected(i) && !is_user_bot(i) && !is_user_hltv(i) && g_spawned[i]) {
			new newangle[3]
			get_user_origin(i, newangle)

			if ( newangle[0] == g_oldangles[i][0] && newangle[1] == g_oldangles[i][1] && newangle[2] == g_oldangles[i][2] ) {
				g_afktime[i] += CHECK_FREQ
				check_afktime(i)
			} else {
				g_oldangles[i][0] = newangle[0]
				g_oldangles[i][1] = newangle[1]
				g_oldangles[i][2] = newangle[2]
				g_afktime[i] = 0
			}
		}
	}
	return PLUGIN_HANDLED
}

check_afktime(id) {
	new numplayers = get_playersnum()
	new minplayers = get_cvar_num("mp_afkminplayers")
					
	if (numplayers >= minplayers) {
		new maxafktime = get_cvar_num("mp_afktime")
		if (maxafktime < MIN_AFK_TIME) {
			log_amx("cvar mp_afktime %i is too low. Minimum value is %i.", maxafktime, MIN_AFK_TIME)
			maxafktime = MIN_AFK_TIME
			set_cvar_num("mp_afktime", MIN_AFK_TIME)
		}

		if (g_afktime[id] > maxafktime) {
			new name[32]
			get_user_name(id, name, 31)
			client_cmd(id,"drop weapon_c4 ") 
		}
	}
}

public client_putinserver(id) {
	g_afktime[id] = 0
	return PLUGIN_HANDLED
}

public playerSpawned(id) {
	g_spawned[id] = false
	new sid[1]
	sid[0] = id
	set_task(0.75, "delayedSpawn",_, sid, 1)	// Give the player time to drop to the floor when spawning
	return PLUGIN_HANDLED
}

public delayedSpawn(sid[]) {
	get_user_origin(sid[0], g_oldangles[sid[0]])
	g_spawned[sid[0]] = true
	return PLUGIN_HANDLED
}

[mgr inż. Pavulon]

A nie masz przypadkiem w logach informacji:

cvar mp_afktime 10 is too low. Minimum value is 20.

??

Bo twórca w ten sposób zabezpieczył plugin przed "głupimi adminami".

[kubus]

Mhm faktycznie mam to:

[afkbomb.amxx] cvar mp_afktime 10 is too low. Minimum value is 20.

Da się to jakoś "obskoczyć" ?

Użytkownik kubus edytował ten post 14.01.2010 00:53

[mgr inż. Pavulon]

Zmień w tym 20 na to co chcesz:

#define MIN_AFK_TIME 20		// I use this incase stupid admins accidentally set mp_afktime to something silly.

//komentarz w PL: Używam tego w przypadku głupich administratorów ustawiajacych przypadkowo mp_afktime na coś głupiego.

[kubus]

Dzięki serdeczne, zadziałało.

[Adminek AMXX.PL]

Wiadomość wygenerowana automatycznie


Ten temat został zamknięty przez moderatora.

Powód: Problem rozwiązany

Jeśli się z tym nie zgadzasz, raportuj ten post, a moderator lub administrator rozpatrzy go ponownie.


Z pozdrowieniami,
Zespół AMXX.PL