3 odpowiedzi w tym temacie

[ferdias]

Mam problem z klasa buguje się tzn awp jest 1/1 raz działa a raz nie jak działa to i z deagla też mam 1/1 plus małe info gdzie popełniłem błąd.

 

Spoiler

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>
#include <fakemeta_util>
#include <cstrike>
#include <codmod>
 
//KONFIGURACJA
#define FLAGA ADMIN_LEVEL_B //Na jaka flage dostepna jest klasa premium?
 
new g_iKlasaGracza[33];
 
new const maxClip[31] = { -1, 13, -1, 10,  1,  7,  1,  30, 30,  1,  30,  20,  25, 30, 35, 25,  12,  20,  
10,  30, 100,  8, 30,  30, 20,  2,  7, 30, 30, -1,  50 };
 
new const g_szSkin[][][] = {
    {"arctic","leet","guerilla","terror"},
    {"sas","gsg9","urban","gign"}
};
public plugin_init()  
{
    new const szNazwa[] = "Zawodowy Snajper [Premium]";
    new const szOpis[] = "Natychmiastowe zabicie z AWP, +10%% z deagle'a, na siedzaco jest niewidoczny, posiada wyglad wroga oraz dostaje full maazynek za fraga";
    new const iBronie = (1<<CSW_AWP)|(1<<CSW_DEAGLE);
    new const iZdrowie = 50;
    new const iKondycja = 40;
    new const iInteligencja = 20;
    new const iWytrzymalosc = 30;
    
    register_plugin(szNazwa, "1.0", "d0naciak");
    
    cod_register_class(szNazwa, szOpis, iBronie, iZdrowie, iKondycja, iInteligencja, iWytrzymalosc);
    
    RegisterHam(Ham_Spawn, "player", "fw_Spawn_Post", 1);
    RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage");
    RegisterHam(Ham_Killed, "player", "fw_Killed_Post", 1);
    register_forward(FM_CmdStart, "fw_CmdStart");
}
 
public cod_class_enabled(id)
{
    if(!(get_user_flags(id) & FLAGA))
    {
        client_print(id, print_chat, "Nie masz uprawnien aby korzystac z tej klasy!");
        return COD_STOP;
    }
    
    g_iKlasaGracza[id] = 1;
    return COD_CONTINUE;
}
 
public cod_class_disabled(id)
    g_iKlasaGracza[id] = 0;
 
public fw_Spawn_Post(id)
{
    if(!is_user_alive(id) || !g_iKlasaGracza[id])
        return HAM_IGNORED;
    
    new iTeam = get_user_team(id);
    
    if(1 <= iTeam <= 2)
        cs_set_user_model(id, g_szSkin[iTeam - 1][random(4)]);
    
    return HAM_IGNORED;
}
 
public fw_TakeDamage(id, iEnt, iAttacker, Float:fDamage, iDamageBits)
{
    if(!is_user_connected(id) || !is_user_connected(iAttacker) || !g_iKlasaGracza[iAttacker] || get_user_team(id) == get_user_team(iAttacker))
        return HAM_IGNORED;
    
    static iWeapon;
    iWeapon = get_user_weapon(id);
    
    if(iWeapon == CSW_AWP)
    {
        cod_inflict_damage(iAttacker, id, float(get_user_health(id) + 1), 0.0, iEnt, (1<<1));
        return HAM_IGNORED;
    }
    else if(iWeapon == CSW_DEAGLE)
        cod_inflict_damage(iAttacker, id, fDamage * 0.1, 0.0, iEnt, (1<<1));
    
    return HAM_IGNORED;
}
    
public fw_Killed_Post(vId, kId)
{
    if(!is_user_alive(kId) || !g_iKlasaGracza[kId])
        return HAM_IGNORED;
    
    new iWeapon = get_user_weapon(kId);
    
    if(maxClip[iWeapon] != -1)
        set_user_clip(kId, maxClip[iWeapon]);
    
    return HAM_IGNORED;
}
 
public fw_CmdStart(id, iUc)
{
    if(!is_user_alive(id) || !g_iKlasaGracza[id] )
        return FMRES_IGNORED;
    
    static iButtons ,iOldButtons;
    
    iButtons = get_uc(iUc, UC_Buttons)
    iOldButtons = pev(id, pev_oldbuttons);
    
    if(iButtons & IN_DUCK && !(iOldButtons & IN_DUCK) && get_user_weapon(id) == CSW_KNIFE)
        fm_set_user_rendering(id,kRenderFxNone,255,255,255,kRenderTransAlpha,10);
    else if(!(iButtons & IN_DUCK) && iOldButtons & IN_DUCK)
        fm_set_user_rendering(id,kRenderFxNone,255,255,255,kRenderTransAlpha,255);
    
    return FMRES_IGNORED;
}
 
stock set_user_clip(id, ammo)
{
    new weaponname[32], weaponid = -1, weapon = get_user_weapon(id, _, _);
    get_weaponname(weapon, weaponname, 31);
    while ((weaponid = engfunc(EngFunc_FindEntityByString, weaponid, "classname", weaponname)) != 0)
        if (pev(weaponid, pev_owner) == id) {
        set_pdata_int(weaponid, 51, ammo, 4);
        return weaponid;
    }
    return 0;
}

 

[ex0]

Czemu Ty to fw_takedamage robisz a nie takim czymś:

 

public TakeDamage(this, idinflictor, idattacker, Float:damage,

damagebits)
{
if(!is_user_connected(idattacker))
return HAM_IGNORED;

if(!ma_klase[idattacker])
return HAM_IGNORED;

if(damagebits & DMG_BULLET)
{
new weapon = get_user_weapon(idattacker);

if(weapon == CSW_BRON && damage > 20.0 &&

random_num(1,2) == 1)
cod_inflict_damage(idattacker, this,

float(get_user_health(this))-damage+1.0, 0.0, idinflictor,

damagebits);

}

return HAM_IGNORED;
}

Lub SetParamFloat? 

[BlackPerfum]

Czemu Ty to fw_takedamage robisz

Boże uchroń mnie... To tylko nazwa funkcji ;D Ja swoją nazwę SramPijeIPale i będzie działać

Co do całej klasy to można by było popracować nad optymalnością ale chce mi się spać dlatego porozmawiamy na temat 1/1 i +10% dmg
Zatem twój kod wygląda tak:

public fw_TakeDamage(id, iEnt, iAttacker, Float:fDamage, iDamageBits)
{
    if(!is_user_connected(id) || !is_user_connected(iAttacker) || !g_iKlasaGracza[iAttacker] || get_user_team(id) == get_user_team(iAttacker))
        return HAM_IGNORED;
    
    static iWeapon;
    iWeapon = get_user_weapon(id);
    
    if(iWeapon == CSW_AWP)
    {
        cod_inflict_damage(iAttacker, id, float(get_user_health(id) + 1), 0.0, iEnt, (1<<1));
        return HAM_IGNORED;
    }
    else if(iWeapon == CSW_DEAGLE)
        cod_inflict_damage(iAttacker, id, fDamage * 0.1, 0.0, iEnt, (1<<1));
    
    return HAM_IGNORED;
}

Proponuje zacząć od samego początku czyli od if(!is_user_connected(id) || !is_user_connected(iAttacker) || !g_iKlasaGracza[iAttacker] || get_user_team(id) == get_user_team(iAttacker))
pogrubiony tekst jest niepotrzebny dlaczego? Bo trafiliśmy w gracza (bo jego classname to "player" (rejestr funkcji)) a nie wadzi nam to czy gracz trafiony jest online czy offline ważne by żył a zdażają się sporadyczne przypadki choć rzadko że gracz żyjący jest offline tzn. byt gracza został na serwerze ale gracz się rozłączył Zatem zamień pogrubiony tekst na is_user_alive bo nie interesuje nas łapanie dmg w gracza który już jest martwy.

Następnie widze że używasz cod_inflict_damage do zabijanie co jest błędem gdyż ta funkcja nie zabija lecz zadaje dmg!! Nawet jeśli zadasz 908490321 dmg to jakiś inny plugin może je zmodyfikować i sprawić że nie będzie to śmiertelne dmg!!! Tak samo z dodawaniem 10% dmg używasz cod_inflict_damage a ta funkcja nie modyfikuje już istniejącego dmg a zadaje nowe niestety dmg zadane tą funkcją nie da się wychwycić (bynajmniej nie za pomocą Ham_TakeDamage) zatem jeśli my mamy tą klasę a gracza w przeciwnym team'ie ma klase która jest odporna na dmg zadawane z deagla (bo z deagla mam +10% dmg) to nie będziemy jej bić po 0 (a powinniśmy bo jest na nas odporna) lecz po dmg/10 dlaczego? Bo zadawane jej dmg to dmg z cod_inflict_damage którego nie mogliśmy złapać a zarazem zatrzymać

dodatkowo nie sprawdzasz czy czasem to dmg nie jest z HE gdyż gracz rzuci HE zmieni broń na awp i ma 1/1 z HE bo get_user_weapon zwróci CSW_AWP

Poprawiony kod:

public fw_TakeDamage(id, iEnt, iAttacker, Float:fDamage, iDamageBits)
{
	if(!is_user_alive(id) || !is_user_connected(iAttacker) || !g_iKlasaGracza[iAttacker] || get_user_team(id) == get_user_team(iAttacker))	return HAM_IGNORED;

	if(iAttacker == iEnt && ~iDamageBits & 1<<24)
	{
		static iWeapon;
		iWeapon = get_user_weapon(id)
	
		if(iWeapon == CSW_AWP)	KillPlayer(id,iEnt,iAttacker,CSW_AWP,HIT_HEAD,3,iDamageBits)
		else if(iWeapon == CSW_DEAGLE)
		{
			SetHamParamFloat(4,fDamage*1.1)
			return HAM_HANDLED
		}
	}

	return HAM_IGNORED;
}


KillPlayer(id,inflictor,attacker,weapon,body,shouldgib,damagebits)
{
	if(weapon > 30 || !is_user_alive(id) || !is_user_connected(attacker))	return
	
	const GrenadeWeapon = 1<<CSW_HEGRENADE | 1<<CSW_C4 | 1<<CSW_SMOKEGRENADE | 1<<CSW_FLASHBANG
	const m_LastHitGroup = 75
	const m_bitsDamageType = 76
	const m_fHasTakenHighDamage = 107
	static DeathMsgId
	new msgblock,weaponname[32],effect
	if (!DeathMsgId)	DeathMsgId = get_user_msgid("DeathMsg")
	
	set_pdata_int(id,m_LastHitGroup,body,5)
	set_pdata_int(id,m_bitsDamageType,damagebits,5)
	set_pdata_int(id,m_fHasTakenHighDamage,1,5)
	set_pev(id,pev_dmg_inflictor,inflictor)
	msgblock = get_msg_block(DeathMsgId)
	set_msg_block(DeathMsgId, BLOCK_SET)
	ExecuteHamB(Ham_Killed,id,attacker,shouldgib)
	set_msg_block(DeathMsgId, msgblock)
	effect = pev(id,pev_effects)
	if(effect & 128)	set_pev(id,pev_effects,effect-128)
	
	new len
	if(get_weaponname(weapon,weaponname,31))
	{
		if(~GrenadeWeapon & 1<<weapon) len = 7
		else weaponname = "grenade"
	}
	else if(weapon == 2)	weaponname = "tracktrain"
	else	weaponname = "world"
	
	emessage_begin(MSG_ALL, DeathMsgId)
	ewrite_byte(attacker)
	ewrite_byte(id)
	ewrite_byte(body == HIT_HEAD ? 1:0)
	ewrite_string(weaponname[len])
	emessage_end()
}

Funkcja KillPlayer jest stąd polecam poczytać

[ferdias]

Już se sam poradziłem ale dziękuje.