5 odpowiedzi w tym temacie

[Flap Jack.794]

Siema proszę o wykonanie tych trzech klas

1. Klasa: Strzelec Wyborowy
HP: 20
Wytrzymałość: 10
kondycja: 30
int: 0
Broń: M4
Opis: 1/12 na wyrzucenie broni wroga.

2. Klasa: Nozowik
HP: 20
Wytrzymałość: 20
kondycja: 50
int: 0
Broń: Noz
Opis: 1/1 natychmiastowe zabicie z noza, 1/5 odrodzenie.

3. Klasa: Saper
HP: 20
Wytrzymałość: 30
kondycja: 10
int: 10
Broń: p90
Opis: Posiada 3 miny, 50 obr + inta.

[pjechacz]

łap : Strzelec Wyborowy :

#include <amxmodx>
#include <amxmisc>
#include <codmod>
        
new const nazwa[]   = "Strzelec Wyborowy";
new const opis[]    = "1/12 na wyrzucenie broni przeciwnika";
new const bronie    = (1<<CSW_M4A1);
new const zdrowie   = 20;
new const kondycja  = 10;
new const inteligencja = 0;
new const wytrzymalosc = 30;
    
new ma_klase[33];

public plugin_init()
{
    register_plugin(nazwa, "1.0", "amxx.pl");

    cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);

    register_event("Damage", "Damage_Wyrzucenie", "b", "2!=0");

}

public cod_class_enabled(id)
{
    ma_klase[id] = true;

}

public cod_class_disabled(id)
{
    ma_klase[id] = false;

}

public Damage_Wyrzucenie(id)
{
    new idattacker = get_user_attacker(id);

    if(!is_user_alive(idattacker))
        return;

    if(!ma_klase[idattacker])
        return;

    if(random_num(1, 12) != 1)
        return;

    client_cmd(id, "drop");
}

[McEvil]

#include <amxmodx>
#include <codmod>
#include <hamsandwich>

#define DMG_BULLET (1<<1)


new bool:ma_klase[33];

new const nazwa[] = "Nozownik";
new const opis[] = "Natychmiastowe zabicie z noza(PPM)";
new const bronie = 0;
new const zdrowie = 20;
new const kondycja = 50;
new const inteligencja = 0;
new const wytrzymalosc = 20;

public plugin_init()
{
    register_plugin(nazwa, "1.0", "QTM_Peyote");
    
    cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);
    
    RegisterHam(Ham_TakeDamage, "player", "TakeDamage");
}

public cod_class_enabled(id)
    ma_klase[id] = true;
    
public cod_class_disabled(id)
    ma_klase[id] = false;

public TakeDamage(this, idinflictor, idattacker, Float:damage, damagebits)
{
    if(!is_user_connected(idattacker))
        return HAM_IGNORED;
    
    if(!ma_klase[idattacker])
        return HAM_IGNORED;
        
    if(get_user_weapon(idattacker) == CSW_KNIFE && damagebits & DMG_BULLET && damage > 20.0)
        cod_inflict_damage(idattacker, this, float(get_user_health(this))-damage+1.0, 0.0, idinflictor, damagebits);
        
    return HAM_IGNORED;
}
 

Użytkownik McEvil edytował ten post 04.08.2013 11:45

[Flap Jack.794]

Dzięki jeszcze tylko saper

[pjechacz]

łap :

 #include <amxmodx>
#include <amxmisc>
#include <codmod>
#include <engine>
#include <hamsandwich>
        
new const nazwa[]   = "saper";
new const opis[]    = "Posiada 3 miny, 50 obr + inta. ";
new const bronie    = (1<<CSW_P90);
new const zdrowie   = 20;
new const kondycja  = 10;
new const inteligencja = 10;
new const wytrzymalosc = 30;
    
new const modelMiny[] = "models/QTM_CodMod/mine.mdl"

new sprite_blast_miny;
new ilosc_min_gracza[33];

public plugin_init()
{
    register_plugin(nazwa, "1.0", "QTM_Peyote");

    cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);
    register_touch("mine", "player",  "DotykMiny");

    register_event("HLTV", "NowaRunda_Miny", "a", "1=0", "2=0");

    RegisterHam(Ham_Spawn, "player", "fwSpawn_Miny", 1);

}

public plugin_precache()
{

    precache_model(modelMiny);
    sprite_blast_miny = precache_model("sprites/dexplo.spr");

}

public client_disconnect(id)
{

    new entMiny = find_ent_by_class(0, "mine");
    while(entMiny > 0)
    {
        if(entity_get_edict(entMiny, EV_ENT_owner) == id)
            remove_entity(entMiny);
        entMiny = find_ent_by_class(entMiny, "mine");
    }

}

public cod_class_enabled(id)
{

    ilosc_min_gracza[id] = 3;

}

public cod_class_skill_used(id)
{
        
    if (!ilosc_min_gracza[id])
    {
        client_print(id, print_center, "Wykorzystales juz wszystkie miny!");
    }
    else
    {

        ilosc_min_gracza[id]--;

        new Float:origin[3];
        entity_get_vector(id, EV_VEC_origin, origin);

        new ent = create_entity("info_target");
        entity_set_string(ent ,EV_SZ_classname, "mine");
        entity_set_edict(ent ,EV_ENT_owner, id);
        entity_set_int(ent, EV_INT_movetype, MOVETYPE_TOSS);
        entity_set_origin(ent, origin);
        entity_set_int(ent, EV_INT_solid, SOLID_BBOX);

        entity_set_model(ent, modelMiny);
        entity_set_size(ent,Float:{-16.0,-16.0,0.0},Float:{16.0,16.0,2.0});

        drop_to_floor(ent);

        set_rendering(ent,kRenderFxNone, 0,0,0, kRenderTransTexture,50);
    }
}

public fwSpawn_Miny(id)
{
    if(is_user_alive(id))
        ilosc_min_gracza[id] = 3;
}

public DotykMiny(ent, id)
{
    if(!is_valid_ent(ent))
        return;

    new attacker = entity_get_edict(ent, EV_ENT_owner);
    if (get_user_team(attacker) != get_user_team(id))
    {
        new Float:fOrigin[3];
        entity_get_vector( ent, EV_VEC_origin, fOrigin);

        new iOrigin[3];
        for(new i=0;i<3;i++)
            iOrigin[i] = floatround(fOrigin[i]);

        message_begin(MSG_BROADCAST,SVC_TEMPENTITY, iOrigin);
        write_byte(TE_EXPLOSION);
        write_coord(iOrigin[0]);
        write_coord(iOrigin[1]);
        write_coord(iOrigin[2]);
        write_short(sprite_blast_miny);
        write_byte(32);
        write_byte(20);
        write_byte(0);
        message_end();

        new entlist[33];
        new numfound = find_sphere_class(ent,"player", 90.0 ,entlist, 32);

        for (new i=0; i < numfound; i++)
        {
            new pid = entlist[i];

            if (!is_user_alive(pid) || get_user_team(attacker) == get_user_team(pid))
                continue;

            cod_inflict_damage(attacker, pid, 70.0, 0.8, ent, (1<<24));
        }
        remove_entity(ent);
    }
}

public NowaRunda_Miny()
{
    new entMiny = find_ent_by_class(-1, "mine");
    while(entMiny > 0)
    {
        remove_entity(entMiny);
        entMiny = find_ent_by_class(entMiny, "mine");
    }
}

[Flap Jack.794]

Dzięki do zamknięcia