1 odpowiedź w tym temacie

[sznur3k]

Potrzebuję pluginu w którym za zabicie wroga dostajemy punkt "złota" starałem się zrobić to sam ale nie potrafię,nie wiem może jakiś tępy jestem.

Jak potrzebne są szczegóły to proszę:

1 zabicie = 1 pkt. Złota
podłożenie paki = 3pkt. Złota
hud z posiadanymi punktami złota

jakiś savexp na to

 

a jeżeli można to sklep w którym można kupić:
30pkt expa za 100złota
130pkt expa za 450złota

300pkt expa za 900 złota
losowy item za 40złota

 

oczywiście może być bez sklepu ale jak ktoś zrobi to jeszcze lepiej.

[BiolHem]

Spoiler

/*
CHANGELOG:
* 1.0.0 - pierwsza dzialajaca wersja
* 1.0.1 - usuniecie bugu: kopiowanie monet z jednego nicku na drugi
* 1.0.2 - dodanie: natywow
* 1.0.3 - dodanie: typu zapisu
* 1.0.4 - usuniecie bugu: dostawanie monet za wpisanie kill (Podziekowania dla Szybcioor za wykrycie i dla Goliath za zalatanie :])
* 1.0.5 - dodanie: nowe eventy za ktore zdobywa sie monety
* 1.0.6 - dodanie: cvaru - wlacznie/wylaczenie monet za TeamKill
* 1.0.7 - usuniecie bugu: brak monet za zabicie
* 1.0.8 - usuniecie bugu: brak monet za uratowanie/zabicie hosta
* 1.1.0 - usuniecie bugu: zbyt maly rozmiar tablicy
- usuniecie bugu: problem z pobieraniem cvaru cod_savetype 
- optymalizacja kodu
*/
 
#include <amxmodx>
#include <amxmisc>
#include <nvault>
 
#define PLUGIN "System Monet"
#define AUTHOR "kisiel96"
#define VERSION "1.1.0"
 
#define TASK_SHOW_COINS 666
#define VIP ADMIN_LEVEL_G
 
enum events { kill = 0, kill_hs, defused, planted, rescue_hostage, kill_hostage }
 
new player_auth[33][64];
new player_coins[33];
new bool:player_vip[33];
 
new sync_hud_obj;
 
new pcvar_coins[events];
new pcvar_coins_vip[events];
new cvar_coins[events];
new cvar_coins_vip[events];
 
new pcvar_coins_ff;
new cvar_savetype;
new coins_ff;
new vault;
 
public plugin_init()
{ 
register_plugin(PLUGIN, VERSION, AUTHOR);
 
register_event("DeathMsg", "DeathMsg", "a");
register_event("ResetHUD", "ResetHUD", "abe");
register_logevent("HostageRescued", 3, "1=triggered", "2=Rescued_A_Hostage");
register_logevent("HostageKilled", 3, "1=triggered", "2=Killed_A_Hostage");
 
sync_hud_obj = CreateHudSyncObj();
 
pcvar_coins_ff =  register_cvar("cod_coins_friendlyfire", "0");
 
pcvar_coins[kill] =  register_cvar("cod_coins_kill", "1");
pcvar_coins_vip[kill]  =  register_cvar("cod_coins_kill_vip", "2");
pcvar_coins[kill_hs]  =  register_cvar("cod_coins_kill_hs", "3");
pcvar_coins_vip[kill_hs]  =  register_cvar("cod_coins_kill_hs_vip", "6");
 
pcvar_coins[planted] =  register_cvar("cod_coins_planted", "1");
pcvar_coins_vip[planted] =  register_cvar("cod_coins_planted_vip", "2");
pcvar_coins[defused]  =  register_cvar("cod_coins_defused", "1");
pcvar_coins_vip[defused]  =  register_cvar("cod_coins_defused_vip", "2");
 
pcvar_coins[rescue_hostage] =  register_cvar("cod_coins_rescue_hostage", "1");
pcvar_coins_vip[rescue_hostage] =  register_cvar("cod_coins_rescue_hostage_vip", "2");
pcvar_coins[kill_hostage] =  register_cvar("cod_coins_kill_hostage", "2");
pcvar_coins_vip[kill_hostage]  =  register_cvar("cod_coins_kill_hostage_vip", "1");
 
cvar_savetype  =  get_cvar_num("cod_savetype");
 
vault = nvault_open("monety");
if(vault == INVALID_HANDLE)
set_fail_state("Nie mozna otworzyc pliku");
}
 
public plugin_natives()
{
register_native("cod_get_user_coins", "GetCoins", 1);
register_native("cod_set_user_coins", "SetCoins", 1);
} 
 
public client_authorized(id)
{
RemoveCoins(id);
 
switch(cvar_savetype)
{
case 1: get_user_name(id, player_auth[id], 63);
case 2: get_user_authid(id, player_auth[id], 63);
case 3: get_user_ip(id, player_auth[id], 63);
}
 
if(get_user_flags(id) & VIP)
player_vip[id] = true;
else 
player_vip[id] = false;
 
LoadCoins(id);
}
 
public client_connect(id)
LoadCoins(id);
 
public client_disconnect(id)
{
SaveCoins(id);
RemoveCoins(id)
}
 
public plugin_end()
nvault_close(vault);
 
// /-----------\ //
// |RESET MONET| //
// \-----------/ //
 
public RemoveCoins(id)
{
player_coins[id] = 0;
player_vip[id] = false;
}
 
// /--------------\ //
// |ZLICZNIE MONET| //
// \--------------/ //
 
public DeathMsg()
{
new kid = read_data(1);
new vid = read_data(2);
new hs = read_data(3);
 
if(kid == vid)
return;
 
coins_ff = get_pcvar_num(pcvar_coins_ff) 
 
if(coins_ff == 0 && get_user_team(kid) == get_user_team(vid))
return;
 
cvar_coins[kill] = get_pcvar_num(pcvar_coins[kill]);
cvar_coins_vip[kill] = get_pcvar_num(pcvar_coins_vip[kill]);
cvar_coins[kill_hs] = get_pcvar_num(pcvar_coins[kill_hs]);
cvar_coins_vip[kill_hs] = get_pcvar_num(pcvar_coins_vip[kill_hs]);
 
if(player_vip[kid])
{
if(hs)
player_coins[kid] += cvar_coins_vip[kill_hs];
else
player_coins[kid] += cvar_coins_vip[kill];
}
else
{
if(hs)
player_coins[kid] += cvar_coins[kill_hs];
else
player_coins[kid] += cvar_coins[kill];
}
}
 
public bomb_planted(planter) 
{
cvar_coins[planted] = get_pcvar_num(pcvar_coins[planted]);
cvar_coins_vip[planted] = get_pcvar_num(pcvar_coins_vip[planted]);
 
if(player_vip[planter])
player_coins[planter] += cvar_coins_vip[planted];
else
player_coins[planter] += cvar_coins[planted];
}
 
public bomb_defused(defuser)
{
cvar_coins[defused] = get_pcvar_num(pcvar_coins[defused]);
cvar_coins_vip[defused] = get_pcvar_num(pcvar_coins_vip[defused]); 
 
if(player_vip[defuser])
player_coins[defuser] += cvar_coins_vip[defused];
else
player_coins[defuser] += cvar_coins[defused];
}
 
public HostageRescued(id)
{
new loguser[80], name[32];
read_logargv(0, loguser, 79);
parse_loguser(loguser, name, 31);
 
new id = get_user_index(name);
 
cvar_coins[rescue_hostage] = get_pcvar_num(pcvar_coins[rescue_hostage]);
cvar_coins_vip[rescue_hostage] = get_pcvar_num(pcvar_coins_vip[rescue_hostage]);
 
if(player_vip[id])
player_coins[id] += cvar_coins_vip[rescue_hostage];
else
player_coins[id] += cvar_coins[rescue_hostage];
 
return PLUGIN_CONTINUE
} 
 
public HostageKilled(id) 
{
new loguser[80], name[32];
read_logargv(0, loguser, 79);
parse_loguser(loguser, name, 31);
 
new id = get_user_index(name);
 
cvar_coins[kill_hostage] = get_pcvar_num(pcvar_coins[kill_hostage]);
cvar_coins_vip[kill_hostage] = get_pcvar_num(pcvar_coins_vip[kill_hostage]);
 
if(player_vip[id])
player_coins[id] -= cvar_coins_vip[kill_hostage];
else
player_coins[id] -= cvar_coins[kill_hostage];
}
 
// /---\ //
// |HUD| //
// \---/ //
 
public ShowCoins(id)
{
id -= TASK_SHOW_COINS;
 
if(!is_user_alive(id))
{
remove_task(id + TASK_SHOW_COINS);
return;
}
 
set_hudmessage(0, 255, 0, 0.02, 0.23, 0, 0.0, 0.3, 0.0, 0.0);
ShowSyncHudMsg(id, sync_hud_obj, "^n^n^n^n^n^n^n[Zloto: %i]", player_coins[id]);
}
 
public ResetHUD(id)
{
if(!task_exists(id+TASK_SHOW_COINS))
set_task(0.1, "ShowCoins", id + TASK_SHOW_COINS, _, _, "b");
}
 
// /------\ //
// |NATYWY| //
// \------/ //
 
public SetCoins(id, wartosc)
{
player_coins[id] = wartosc
}
 
public GetCoins(id)
return player_coins[id];
 
// /------\ //
// |NVAULT| //
// \------/ //
 
public SaveCoins(id)
{
new vaultkey[64], vaultdata[256];
formatex(vaultkey, 63, "%s-player_coins", player_auth[id]);
formatex(vaultdata, 255, "%d#", player_coins[id]);
nvault_set(vault, vaultkey, vaultdata);
 
return PLUGIN_CONTINUE
}
 
public LoadCoins(id)
{
new vaultkey[64], vaultdata[256];
formatex(vaultkey, 63, "%s-player_coins", player_auth[id]);
formatex(vaultdata, 255, "%d#", player_coins[id]);
nvault_get(vault, vaultkey, vaultdata,255);
 
replace_all(vaultdata, 255, "#", " ");
 
new temp_player_coins[33];
parse(vaultdata, temp_player_coins, 32);
 
player_coins[id] = str_to_num(temp_player_coins);
 
return PLUGIN_CONTINUE
} 

Przerobiłem ten temat:

http://amxx.pl/topic...3-system-monet/

Tam amsz cvary instalacje itp

Użytkownik BiolHem edytował ten post 05.07.2013 18:40