2 odpowiedzi w tym temacie

[Lonely]

I want to get the team all the player information (name, Kills, Deaths).Then sort it.How to do this?
I want to make a nice scoreboard.
I want to use AMX MOD X to achieve.

[Klakier]

Use for example bubble sort

public SORT(id)
{
    if (!is_user_connected(id))
        return
    
    const SIZE = 1024
    static msg[SIZE + 1], len; len = 0
    
    new players[32], pnum, player, sortT[16], sortCT[16], counterT, counterCT
    get_players(players, pnum)
    for (new i = 0; i < pnum; i++)
    {
        player = players[i]
        switch(get_user_team(player))
        {
            case 1:
            {
                sortT[counterT] = player
                counterT++
            }
            case 2:
            {
                sortCT[counterCT] = player
                counterCT++
            }
        }
    }
    
    bubble_sort_by_kills(sortT, counterT)
    bubble_sort_by_kills(sortCT, counterCT)
    
    len += formatex(msg[len], SIZE - len, " .: NICK :. ... KILLS | DEATHS ")
    
    // T's
    len += formatex(msg[len], SIZE - len, "_____________Terrorists (TT) _____________^n")
    for (new t = 0; t < counterT; t++)
    {
        player = sortT[t]
        len += formatex(msg[len], SIZE - len, "[ %s ... %i ... %i ]^n",
        player_name[player], g_kills[player], g_deaths[player])
    }
    
    // CT's
    len += formatex(msg[len], SIZE - len, "^n_____________C-Terrorists (CT) ______________^n")
    for (new ct = 0; ct < counterCT; ct++)
    {
        player = sortCT[ct]
        len += formatex(msg[len], SIZE - len, "[ %s ... %i ... %i ]^n",
        player_name[player], g_kills[player], g_deaths[player])
    }
    
    set_hudmessage(25, 125, 225, 0.3, 0.3, 0, 6.0, 1.1, 0.0, 0.0, 1)
    ShowSyncHudMsg(id, CreateHudSyncObj(), msg)
    
}
bubble_sort_by_kills(list[16], count) {
    if(count < 2)
        return
    
    static temp, a, b
    for (a = 0; a < count; a++)
    {
        for (b = a + 1; b < count; b++)
        {
            if (g_kills[list[a]] < g_kills[list[b]])
            {
                temp = list[a]
                list[a] = list[b]
                list[b] = temp
            }
        }
    }
}

Here you are