Potrzebuje Pluginu

Siema !

Jestem nowy i potrzebuje pluginu ;

1.Plugin który pokazuje przez kogo zostales oslepiony gdy ktos rzuci Falsh i kogo oslepiles , ale tyko ze SWEGO TEAM`U

2.Gdy admin zrobi ss`y to automatycznie ban sam się daje z powodem wrzuc ss`y na Twoja Strona.pl


Dzięki z góry !

Team Flash Snitch Kogo oslepiles

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define PLUGIN "Team Flash Snitch"
#define VERSION "1.0"
#define AUTHOR "Sn!ff3r"

#define ID 3322

new msg_saytext
new g_flasher

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    msg_saytext = get_user_msgid("SayText")
    
    register_event("ScreenFade", "ScreenFade", "be", "4=255", "5=255", "6=255", "7>199") 
    register_event("23", "TEMPENTITY", "a", "1=5", "6=25", "7=6") 
    
    register_forward(FM_SetModel, "SetModel") 
}


public SetModel(ent, model[]) 
{    
    if(equal(model, "models/w_flashbang.mdl")) 
    {    
        static owner
        owner = pev(ent, pev_owner)
        if(owner)         
        {
            set_task(1.52,"get_flasher", ID + owner)
        }
    }
} 

public TEMPENTITY()
{    
    set_task(0.05, "reset_flasher") 
    return PLUGIN_CONTINUE
} 

public reset_flasher()
{ 
    g_flasher = 0
}

public get_flasher(id)
{ 
    g_flasher = (id - ID)
}

public ScreenFade(id) 
{    
    if(is_user_alive(id))
    {
        if(id != g_flasher && get_user_team(id) == get_user_team(g_flasher))
        {
            static name[33], message[128]
                        
            get_user_name(g_flasher, name, 32)            
            formatex(message, 127, "^x04Zostales oslepiony przez ^x03%s", name)
            print_that(id, message)            
            
            get_user_name(id, name, 32)            
            formatex(message, 127, "^x04Oslepiles ^x03%s", name)
            print_that(g_flasher, message)
        }
    }    
} 

stock print_that(id, text[])
{
    message_begin(MSG_ONE_UNRELIABLE, msg_saytext, {0,0,0}, id)
    write_byte(id)
    write_string(text)
    message_end()
}

Instalacja Standardowa

Użytkownik thomas edytował ten post 20.08.2011 21:40

1.
 flash_tfs.sma   1,81 KB  55 Ilość pobrań
  flash_tfs.amxx
 flash_tfs.amxx   3,16 KB  5 Ilość pobrań


2. Admin_Screen edit by caxixi - AMXX.pl: Support AMX Mod X