Problem z pluginem "noreconnect"

Mam problem z pluginem 'noreconnect'

Mianowicie wszystko działa ok, ale w logach widać błąd:

L 09/27/2008 - 10:26:19: [AMXX] Run time error 4 (plugin "no_reconnect.amxx") - debug not enabled!
L 09/27/2008 - 10:26:19: [AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes).

Może wie ktoś jaka jest tego przyczyna? Albo ma jakiś sprawdzony plugin na zablokowanie reconnecta, super by było jak by można było jeszcze immunitet ustawić

Z góry dzięki za pomoc

saint69, zmień wpis w plugins.ini na

no_reconnect.amxx debug

uper by było jak by można było jeszcze immunitet ustawić

Dodaj flagę

a

Do users.ini ;-)

kur3k, z debugiem już próbowałem i po włączeniu mam teraz:

L 09/27/2008 - 13:10:49: [AMXX] Displaying debug trace (plugin "no_reconnect.amxx")
L 09/27/2008 - 13:10:49: [AMXX] Run time error 4: index out of bounds
L 09/27/2008 - 13:10:49: [AMXX] [0] no_reconnect.sma::client_connect (line 46)

a co do flagi to chociaż mam to i tak immunitetu nie mam

co dalej? jak pozbyć się tego błędu?

saint69, Kopsnij sma tego plugina

/* AMX Mod X script.
*
* No reconnect
* © Copyright 2002, SYZo
* This file is provided as is (no warranties).
*
* amx_minreconnecttime 20 (in seconds)
*
* *******************************************************************************
*
* Ported By KingPin( [email protected] ). I take no responsibility
* for this file in any way. Use at your own risk. No warranties of any kind.
*
* *******************************************************************************
* Updated Feb 14 2006
*
*/

#include <amxmodx>
#include <engine>
#define MAX_PLAYERS 32

#define PLUGIN "No reconnect"
#define VERSION "2.11"
#define AUTHOR "SYZo"

new pip[MAX_PLAYERS][22]
new Float:minreconnecttime

public delayed_kick(user[]) {
server_cmd("kick #%d",user[0])
}

public clean_blackip(ind[]) {
pip[ind[0]][0] = 0
}

public client_connect(id) {
if (!is_user_bot(id)) {
minreconnecttime = get_cvar_float("amx_minreconnecttime")
new userip[21+1]
new uname[33+1]
get_user_ip(id, userip, 21, 0)
get_user_name(id, uname, 33)
for(new i = 1; i <= MAX_PLAYERS; i++) {
if (equal(userip, pip[i], 21)) {
new userid[1]
userid[0] = get_user_userid(id)
new authid[32]
get_user_authid(id,authid,32)
log_amx("^"%s<%s><%d><%s><>^"", uname, userip, get_user_userid(id), authid)
if (!(get_user_flags(id)&ADMIN_IMMUNITY)) {
new text[128]
format(text, 128, "Noob %s zostal kickniety za uzycie reconnectu", uname)
set_hudmessage(255, 0, 0, 0.05, 0.70, 0, 5.0, 6.0, 6.0, 0.15, 3)
show_hudmessage(0,"%s",text)
client_cmd(id,"echo [INFO] Uzyles komendy RECONNECT = zlamales regulamin = kick", minreconnecttime)
set_task(1.0,"delayed_kick",0,userid,1)
}
return PLUGIN_CONTINUE
}
}
}
return PLUGIN_CONTINUE
}

public client_disconnect(id) {
if (!is_user_bot(id)) {
for(new i = 1; i <= MAX_PLAYERS; i++) {
if(pip[i][0] == 0) {
new userip[21+1]
get_user_ip(id, userip, 21, 0)
copy(pip[i], 21, userip)
new userid[1]
userid[0] = i
set_task(minreconnecttime, "clean_blackip", 0, userid[0], 1)
return PLUGIN_CONTINUE
}
}
}
return PLUGIN_CONTINUE
}

public plugin_init() {
register_plugin(PLUGIN, VERSION, AUTHOR)
register_cvar("amx_minreconnecttime","20")
return PLUGIN_CONTINUE
}

Ja tez zauwazylem taki bład.... lipton

to teraz niech ktoś go rozwiąże

a jest jakiś inny plugin który uniemożliwia reconnect? bo z tego co szukałem to wszędzie jest tylko ten

Zobaczcie to (nie pamiętam co w nim zmieniałem, ale działa ):

/* AMX Mod X script. 
* 
* No reconnect
* (c) Copyright 2002, SYZo
* This file is provided as is (no warranties). 
*
* amx_minreconnecttime 20 (in seconds)
*
*  *******************************************************************************
*   
*	Ported By KingPin( [email protected] ). I take no responsibility 
*	for this file in any way. Use at your own risk. No warranties of any kind. 
*
*  *******************************************************************************
*   Updated Feb 14 2006
* 
*/ 

#include <amxmodx> 
#include <engine> 
//#define MAX_PLAYERS 32

#define PLUGIN "No reconnect"
#define VERSION "2.11"
#define AUTHOR "SYZo" 

new pip[33][22]
new Float:minreconnecttime

public delayed_kick(user[]) {
    server_cmd("kick #%d",user[0])
}

public clean_blackip(ind[]) {
    pip[ind[0]][0] = 0
}

public client_putinserver(id) {
  if (!is_user_bot(id)) {
    minreconnecttime = get_cvar_float("amx_minreconnecttime")
    new userip[21+1]
    new uname[33+1]
    get_user_ip(id, userip, 21, 0)
    get_user_name(id, uname, 33)
    for(new i = 1; i <= get_maxplayers(); i++) {
      if (equal(userip, pip[i], 21)) {
        new userid[1]
        userid[0] = get_user_userid(id)
        new authid[32]
        get_user_authid(id,authid,32)
        log_amx("^"%s<%s><%d><%s><>^"", uname, userip, get_user_userid(id), authid)
        if (!(get_user_flags(id)&ADMIN_KICK)) {
            new text[128]
            format(text, 128, "Player %s kicked after usage reconnect command", uname)
            set_hudmessage(255, 0, 0, 0.05, 0.70, 0, 5.0, 6.0, 6.0, 0.15, 3)
            show_hudmessage(0,"%s",text)
            client_cmd(id,"echo [AMXX] You used command RECONNECT within %.0f sec, please reconnect after %.0f sec", minreconnecttime, minreconnecttime)
            set_task(1.0,"delayed_kick",0,userid,1)
        }
        return PLUGIN_CONTINUE
      }
    }
  }
  return PLUGIN_CONTINUE
}

public client_disconnect(id) {
  if (!is_user_bot(id)) {
    for(new i = 1; i <= get_maxplayers(); i++) {
      if(pip[i][0] == 0) {
        new userip[21+1]
        get_user_ip(id, userip, 21, 0)
        copy(pip[i], 21, userip)
        new userid[1]
        userid[0] = i
        set_task(minreconnecttime, "clean_blackip", 0, userid[0], 1)
        return PLUGIN_CONTINUE
      }
    }
  }
  return PLUGIN_CONTINUE
}

public plugin_init() { 
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_cvar("amx_minreconnecttime","30")
    return PLUGIN_CONTINUE 
}

wygląda na to, że działa wielkie dzięki Pavulon,

to jeszcze tak przy okazji jedna sprawa a właściwie dwie:

1) dałoby się żeby immunitet był na inną flagę niż A?

2) dałoby się żeby zamiast wiadomości w konsoli wyświetlała się ona jakoś w podobie REASON przy banie?

(1) Jest admin_kick a nie admin_immunity

if (!(get_user_flags(id)&ADMIN_KICK)) {

ale można zmienić.
(2) zamiast której wiadomości, tej ?

client_cmd(id,"echo [AMXX] You used command RECONNECT within %.0f sec, please reconnect after %.0f sec", minreconnecttime, minreconnecttime)

Jej nie da się zmienić bo kick jest przed wejściem do gry.

Pavulon a jakbyś wywalił zbędnego taska do kicka i dał go w funkcji od razu a jak reason dałbyś to co kolega chciał?

Aaa chodzi o to żeby ta wiadomość była w okienku [Kicked] ? Bo ja myślałem że o HUD'a chodzi Jak to to mogę

[ Dodano: 02-10-2008, 16:03 ]
Immunitet na flagę "b"
Powód nie w consoli a w okienku od kick'a

/* AMX Mod X script.
*
* No reconnect
* (c) Copyright 2002, SYZo
* This file is provided as is (no warranties).
*
* amx_minreconnecttime 20 (in seconds)
*
*  *******************************************************************************
*   
*    Ported By KingPin( [email protected] ). I take no responsibility
*    for this file in any way. Use at your own risk. No warranties of any kind.
*
*  *******************************************************************************
*   Updated Feb 14 2006
*
*/

#include <amxmodx>
#include <engine>
//#define MAX_PLAYERS 32

#define PLUGIN "No reconnect"
#define VERSION "2.11"
#define AUTHOR "SYZo"

new pip[33][22]
new Float:minreconnecttime

public clean_blackip(ind[])
{
	pip[ind[0]][0] = 0
}

public client_putinserver(id)
{
	if (!is_user_bot(id)) {
		minreconnecttime = get_cvar_float("amx_minreconnecttime")
		new userip[21+1]
		new uname[33+1]
		get_user_ip(id, userip, 21, 0)
		get_user_name(id, uname, 33)
		for(new i = 1; i <= get_maxplayers(); i++) {
			if (equal(userip, pip[i], 21)) {
				new authid[32]
				get_user_authid(id,authid,32)
				log_amx("^"%s<%s><%d><%s><>^"", uname, userip, get_user_userid(id), authid)
				if (!(get_user_flags(id)&ADMIN_RESERVATION)) {
					new text[128]
					format(text, 128, "Player %s kicked after usage reconnect command", uname)
					set_hudmessage(255, 0, 0, 0.05, 0.70, 0, 5.0, 6.0, 6.0, 0.15, 3)
					show_hudmessage(0,"%s",text)
					new reason[128]
					format(reason,127,"You used command RECONNECT within %.0f sec, please reconnect after %.0f sec", minreconnecttime, minreconnecttime)
					server_cmd("kick #%d ^"%s^"", get_user_userid(id) , reason)
				}
				return PLUGIN_CONTINUE
			}
		}
	}
	return PLUGIN_CONTINUE
}

public client_disconnect(id) {
	if (!is_user_bot(id)) {
		for(new i = 1; i <= get_maxplayers(); i++) {
			if(pip[i][0] == 0) {
				new userip[21+1]
				get_user_ip(id, userip, 21, 0)
				copy(pip[i], 21, userip)
				new userid[1]
				userid[0] = i
				set_task(minreconnecttime, "clean_blackip", 0, userid[0], 1)
				return PLUGIN_CONTINUE
			}
		}
	}
	return PLUGIN_CONTINUE
}

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_cvar("amx_minreconnecttime","30")
	return PLUGIN_CONTINUE
}

działa pięknie, wielkie dzięki chłopaki a zwłaszcza Pavulon,